summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2019-09-11 12:08:12 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2019-09-12 09:30:35 +0200
commit78d7f867dc4fa787c5b5f44de86cd2cc043d3d45 (patch)
tree02f4ea207e9cad8f4321d7633a9f18bf7682fc5d /dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild
parentdev-qt/qt-docs: 5.12.5_p201908230013 version bump (diff)
downloadgentoo-78d7f867dc4fa787c5b5f44de86cd2cc043d3d45.tar.gz
gentoo-78d7f867dc4fa787c5b5f44de86cd2cc043d3d45.tar.bz2
gentoo-78d7f867dc4fa787c5b5f44de86cd2cc043d3d45.zip
dev-qt: Add Qt 5.12.5
Package-Manager: Portage-2.3.75, Repoman-2.3.17 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild')
-rw-r--r--dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild60
1 files changed, 60 insertions, 0 deletions
diff --git a/dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild b/dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild
new file mode 100644
index 000000000000..a8f3a81d4048
--- /dev/null
+++ b/dev-qt/qtnetwork/qtnetwork-5.12.5.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Network abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+fi
+
+IUSE="bindist connman libproxy networkmanager sctp +ssl"
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}
+ sys-libs/zlib:=
+ connman? ( ~dev-qt/qtdbus-${PV} )
+ libproxy? ( net-libs/libproxy )
+ networkmanager? ( ~dev-qt/qtdbus-${PV} )
+ sctp? ( kernel_linux? ( net-misc/lksctp-tools ) )
+ ssl? ( dev-libs/openssl:0=[bindist=] )
+"
+RDEPEND="${DEPEND}
+ connman? ( net-misc/connman )
+ networkmanager? ( net-misc/networkmanager )
+"
+
+QT5_TARGET_SUBDIRS=(
+ src/network
+ src/plugins/bearer/generic
+)
+
+QT5_GENTOO_CONFIG=(
+ libproxy:libproxy:
+ ssl::SSL
+ ssl::OPENSSL
+ ssl:openssl-linked:LINKED_OPENSSL
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+ :network
+)
+
+pkg_setup() {
+ use connman && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/connman)
+ use networkmanager && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/networkmanager)
+}
+
+src_configure() {
+ local myconf=(
+ $(usex connman -dbus-linked '')
+ $(qt_use libproxy)
+ $(usex networkmanager -dbus-linked '')
+ $(qt_use sctp)
+ $(usex ssl -openssl-linked '')
+ )
+ qt5-build_src_configure
+}