proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 53 insertions, 0 deletions

diff --git a/games-board/gambit/gambit-1.0.1.ebuild b/games-board/gambit/gambit-1.0.1.ebuild
new file mode 100644
index 000000000000..9a55d662d015
--- /dev/null
+++ b/games-board/gambit/gambit-1.0.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+CMAKE_IN_SOURCE_BUILD=true
+inherit cmake-utils games
+
+DESCRIPTION="Qt-based chess application + engine \"gupta\""
+HOMEPAGE="http://sourceforge.net/projects/gambitchess/"
+SRC_URI="mirror://sourceforge/project/${PN}chess/${PN^}-${PV}/${PN^}-${PV}-src.tar.bz2"
+
+LICENSE="CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	dev-qt/qtopengl:4
+	media-libs/mesa
+	x11-libs/libX11"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"/${PN^}-${PV}-src
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFIG_ENABLE_UPDATE_CHECKER=OFF
+		-DCONFIG_GUPTA_ENGINE_DIRECTORY="${GAMES_BINDIR}"/
+		-DCONFIG_RESOURCE_PATH_PREFIX="${GAMES_DATADIR}"/${PN}/
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	emake -C engine/gupta VERBOSE=1 STRIP=/bin/true CFLAGS_RELEASE= release || die
+}
+
+src_install() {
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r data/* || die
+
+	doicon artwork/icons/${PN}/${PN}.svg
+	make_desktop_entry ${PN}chess ${PN^} ${PN} Game || die
+	dodoc doc/contributors.txt || die
+
+	dogamesbin engine/gupta/gupta || die
+	dogamesbin ${PN}chess || die
+}