summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAustin English <wizardedit@gentoo.org>2016-09-07 17:15:41 -0500
committerAustin English <wizardedit@gentoo.org>2016-09-07 17:16:14 -0500
commit5b8de23ab638c51fbc2c80d2a108218ba67c5bd3 (patch)
treeb82685dc0f399bb4908d61e81bd9372760b36851 /games-board/gambit
parentgames-board/gmchess: remove deprecated games eclass (diff)
downloadgentoo-5b8de23ab638c51fbc2c80d2a108218ba67c5bd3.tar.gz
gentoo-5b8de23ab638c51fbc2c80d2a108218ba67c5bd3.tar.bz2
gentoo-5b8de23ab638c51fbc2c80d2a108218ba67c5bd3.zip
games-board/gambit: remove deprecated games eclass
Also update to EAPI 6 Gentoo-Bug: https://bugs.gentoo.org/574082 Package-Manager: portage-2.3.0
Diffstat (limited to 'games-board/gambit')
-rw-r--r--games-board/gambit/gambit-1.0.3-r1.ebuild55
1 files changed, 55 insertions, 0 deletions
diff --git a/games-board/gambit/gambit-1.0.3-r1.ebuild b/games-board/gambit/gambit-1.0.3-r1.ebuild
new file mode 100644
index 00000000000..fd41ce5e56c
--- /dev/null
+++ b/games-board/gambit/gambit-1.0.3-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+CMAKE_IN_SOURCE_BUILD=true
+inherit cmake-utils
+
+MY_P="${P^}"
+
+DESCRIPTION="Qt-based chess application + engine \"gupta\""
+HOMEPAGE="https://sourceforge.net/projects/gambitchess/"
+SRC_URI="mirror://sourceforge/project/${PN}chess/${MY_P}/${MY_P}-src.tar.bz2"
+
+LICENSE="CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="dev-qt/qtcore:4
+ dev-qt/qtgui:4
+ dev-qt/qtopengl:4
+ media-libs/mesa
+ x11-libs/libX11"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}-src"
+
+src_configure() {
+ local mycmakeargs=(
+ -DCONFIG_ENABLE_UPDATE_CHECKER=OFF
+ -DCONFIG_GUPTA_ENGINE_DIRECTORY=/usr/bin
+ -DCONFIG_RESOURCE_PATH_PREFIX=/usr/share/${PN}/
+ )
+
+ cmake-utils_src_configure
+}
+
+src_compile() {
+ cmake-utils_src_compile
+ emake -C engine/gupta VERBOSE=1 STRIP=/bin/true CFLAGS_RELEASE= release
+}
+
+src_install() {
+ insinto /usr/share/${PN}
+ doins -r data/*
+
+ doicon artwork/icons/${PN}/${PN}.svg
+ make_desktop_entry ${PN}chess ${PN^} ${PN} Game
+ dodoc doc/contributors.txt
+
+ dobin engine/gupta/gupta
+ dobin ${PN}chess
+}