summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorBernard Cafarelli <voyageur@gentoo.org>2019-12-05 19:36:19 +0100
committerBernard Cafarelli <voyageur@gentoo.org>2019-12-05 19:36:28 +0100
commit951e437d99bf20ef383978a1e62dd277db062fc7 (patch)
tree274d5281660f0afe6d6183078346019bea18690c /games-board/gnubg
parentmedia-gfx/displaycal: drop old (diff)
downloadgentoo-951e437d99bf20ef383978a1e62dd277db062fc7.tar.gz
gentoo-951e437d99bf20ef383978a1e62dd277db062fc7.tar.bz2
gentoo-951e437d99bf20ef383978a1e62dd277db062fc7.zip
games-board/gnubg: 1.06.002 bump
Switch to GNU homepage, support python3 and disabling python Package-Manager: Portage-2.3.80, Repoman-2.3.19 Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
Diffstat (limited to 'games-board/gnubg')
-rw-r--r--games-board/gnubg/Manifest1
-rw-r--r--games-board/gnubg/gnubg-1.06.002.ebuild96
2 files changed, 97 insertions, 0 deletions
diff --git a/games-board/gnubg/Manifest b/games-board/gnubg/Manifest
index 99b16a8f1db..e892648669c 100644
--- a/games-board/gnubg/Manifest
+++ b/games-board/gnubg/Manifest
@@ -1 +1,2 @@
DIST gnubg-release-1.05.000-sources.tar.gz 15030177 BLAKE2B a53c7d1d242083631a18f8c3eaa4d006fbbda8b6aef8240c1cc27a98b284cebd31ad2787ddd6e360a96bb365851c611971d47f686b2d8a42dfa35ff6a240eb02 SHA512 1d8080c362cb32a3828b6913823d0eb42b0befac7a9fbd6d5ee3346e7515f6150876ac3b8bd59d5fd0c0de2a03187441165bb82eff0ffa1fb84e385dcea58590
+DIST gnubg-release-1.06.002-sources.tar.gz 13163681 BLAKE2B 1b631af8b268c722624012f86318844376bb21158f231d807cbfbb101ecef03ed90f7f253121844dd4221dc8026af5619fe9f62aff64e20d6c2b84450f9705d0 SHA512 77594209032a0d81deb802da249d7f40812127dd1e080413eda75015f324fec9592b1b51772403f501b21e39d3dd371931d82b43c24f614a7d16c5234d271948
diff --git a/games-board/gnubg/gnubg-1.06.002.ebuild b/games-board/gnubg/gnubg-1.06.002.ebuild
new file mode 100644
index 00000000000..810ad7e6051
--- /dev/null
+++ b/games-board/gnubg/gnubg-1.06.002.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+inherit desktop python-single-r1 xdg
+
+DESCRIPTION="GNU BackGammon"
+HOMEPAGE="https://www.gnu.org/software/gnubg/"
+SRC_URI="ftp://ftp.gnu.org/gnu/gnubg/${PN}-release-${PV}-sources.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="cpu_flags_x86_avx gtk opengl python sqlite cpu_flags_x86_sse cpu_flags_x86_sse2 threads"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-db/sqlite:3
+ dev-libs/glib:2
+ dev-libs/gmp:0
+ dev-libs/libxml2
+ media-fonts/dejavu
+ media-libs/freetype:2
+ media-libs/libcanberra
+ media-libs/libpng:0
+ sys-libs/readline:0
+ x11-libs/cairo
+ x11-libs/pango
+ gtk? ( x11-libs/gtk+:2 )
+ opengl? (
+ x11-libs/gtk+:2
+ x11-libs/gtkglext
+ virtual/glu
+ )
+ python? ( ${PYTHON_DEPS} )
+ virtual/libintl"
+DEPEND="${RDEPEND}
+ sys-devel/gettext
+ virtual/pkgconfig"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+
+ # use ${T} instead of /tmp for constructing credits (bug #298275)
+ sed -i -e 's:/tmp:${T}:' credits.sh || die
+ sed -i -e 's/fonts //' Makefile.in || die # handle font install ourself to fix bug #335774
+ sed -i \
+ -e '/^localedir / s#=.*$#= @localedir@#' \
+ -e '/^gnulocaledir / s#=.*$#= @localedir@#' \
+ po/Makefile.in.in || die
+ sed -i \
+ -e '/^gnubgiconsdir / s#=.*#= /usr/share#' \
+ -e '/^gnubgpixmapsdir / s#=.*#= /usr/share/pixmaps#' \
+ pixmaps/Makefile.in || die
+ sed -i \
+ -e '1i#include <config.h>' \
+ copying.c || die #551896
+}
+
+src_configure() {
+ local simd=no
+ local gtk_arg=--without-gtk
+
+ if use gtk || use opengl ; then
+ gtk_arg=--with-gtk
+ fi
+ use cpu_flags_x86_sse && simd=sse
+ use cpu_flags_x86_sse2 && simd=sse2
+ use cpu_flags_x86_avx && simd=avx
+ econf \
+ --localedir=/usr/share/locale \
+ --docdir=/usr/share/doc/${PF}/html \
+ --disable-cputest \
+ --enable-simd=${simd} \
+ ${gtk_arg} \
+ $(use_enable threads) \
+ $(usex python --with-python=${EPYTHON} --without-python) \
+ $(use_with sqlite sqlite) \
+ $(use_with opengl board3d)
+}
+
+src_install() {
+ default
+ insinto /usr/share/${PN}
+ doins ${PN}.weights *bd
+ dodir /usr/share/${PN}/fonts
+ dosym ../../fonts/dejavu/DejaVuSans.ttf /usr/share/${PN}/fonts/Vera.ttf
+ dosym ../../fonts/dejavu/DejaVuSans-Bold.ttf /usr/share/${PN}/fonts/VeraBd.ttf
+ dosym ../../fonts/dejavu/DejaVuSerif-Bold.ttf /usr/share/${PN}/fonts/VeraSeBd.ttf
+ make_desktop_entry "gnubg -w" "GNU Backgammon"
+}