summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorband-a-prend <torokhov-s-a@yandex.ru>2020-11-05 18:48:48 +0300
committerJames Le Cuirot <chewi@gentoo.org>2020-11-17 22:39:50 +0000
commit2ed956a56216efa01840dd0d3a13798f98c82843 (patch)
treeaa40e0c9c3d1bfdab942e4576f5841778179230a /games-board/mah-jong/mah-jong-1.16.ebuild
parentapp-portage/layman: Add python3_9 to compat bug 745849 (diff)
downloadgentoo-2ed956a56216efa01840dd0d3a13798f98c82843.tar.gz
gentoo-2ed956a56216efa01840dd0d3a13798f98c82843.tar.bz2
gentoo-2ed956a56216efa01840dd0d3a13798f98c82843.zip
games-board/mah-jong: 1.16 version bump
Closes: https://bugs.gentoo.org/751040 Signed-off-by: Sergey Torokhov <torokhov-s-a@yandex.ru> Closes: https://github.com/gentoo/gentoo/pull/18139 Signed-off-by: James Le Cuirot <chewi@gentoo.org>
Diffstat (limited to 'games-board/mah-jong/mah-jong-1.16.ebuild')
-rw-r--r--games-board/mah-jong/mah-jong-1.16.ebuild55
1 files changed, 55 insertions, 0 deletions
diff --git a/games-board/mah-jong/mah-jong-1.16.ebuild b/games-board/mah-jong/mah-jong-1.16.ebuild
new file mode 100644
index 00000000000..0d457c6c2d3
--- /dev/null
+++ b/games-board/mah-jong/mah-jong-1.16.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs xdg
+
+MY_P="mj-${PV}-src"
+DESCRIPTION="A networked Mah Jong program, together with a computer player"
+HOMEPAGE="https://mahjong.julianbradfield.org/"
+SRC_URI="https://mahjong.julianbradfield.org/Source/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="x11-libs/gtk+:2"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-lang/perl
+ virtual/pkgconfig
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+ default
+ sed -i -e '/^.TH/ s/1/6/' xmj.man || die
+}
+
+src_compile() {
+ # TILESETPATH value is passed as "char*" into "gui.c"
+ emake \
+ CC="$(tc-getCC)" \
+ EXTRA_CFLAGS="${CFLAGS}" \
+ EXTRA_LDOPTIONS="${LDFLAGS}" \
+ CDEBUGFLAGS= \
+ TILESETPATH="\"${EPREFIX}/usr/share/${PN}/\""
+}
+
+src_install() {
+ emake \
+ DESTDIR="${ED}" \
+ BINDIR="/usr/bin" \
+ MANDIR="/usr/share/man/man6" \
+ MANSUFFIX=6 \
+ INSTPGMFLAGS= \
+ install install.man
+
+ insinto "/usr/share/${PN}"
+ doins -r fallbacktiles/ tiles-numbered/ tiles-small/
+ newicon tiles-v1/tongE.xpm "${PN}.xpm"
+ make_desktop_entry xmj Mah-Jong "${PN}"
+ dodoc CHANGES ChangeLog *.txt
+}