summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJames Le Cuirot <chewi@gentoo.org>2020-04-25 16:36:59 +0100
committerJames Le Cuirot <chewi@gentoo.org>2020-04-25 16:48:23 +0100
commitb6ba553e726506205668460edba8a6895996c595 (patch)
treee267566e6cbac67e1e53c4a28bfc43b58689c988 /games-board/pychess/pychess-1.0.0.ebuild
parentdev-python/websockets: New package required by pychess (diff)
downloadgentoo-b6ba553e726506205668460edba8a6895996c595.tar.gz
gentoo-b6ba553e726506205668460edba8a6895996c595.tar.bz2
gentoo-b6ba553e726506205668460edba8a6895996c595.zip
games-board/pychess: Version bump to 1.0.0
I can't add Python 3.8 until gst-python has been bumped, which should happen soon. Bug: https://bugs.gentoo.org/718310 Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: James Le Cuirot <chewi@gentoo.org>
Diffstat (limited to 'games-board/pychess/pychess-1.0.0.ebuild')
-rw-r--r--games-board/pychess/pychess-1.0.0.ebuild56
1 files changed, 56 insertions, 0 deletions
diff --git a/games-board/pychess/pychess-1.0.0.ebuild b/games-board/pychess/pychess-1.0.0.ebuild
new file mode 100644
index 00000000000..39436e26bda
--- /dev/null
+++ b/games-board/pychess/pychess-1.0.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_7 )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_REQ_USE="sqlite"
+
+inherit xdg distutils-r1
+
+DESCRIPTION="A chess client for GNOME"
+HOMEPAGE="https://github.com/pychess/pychess"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gstreamer"
+
+DEPEND="
+ $(python_gen_cond_dep '
+ dev-python/pexpect[${PYTHON_USEDEP}]
+ dev-python/psutil[${PYTHON_USEDEP}]
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP},sqlite]
+ dev-python/websockets[${PYTHON_USEDEP}]
+ ')
+ gnome-base/librsvg:2
+ x11-libs/gtksourceview:3.0
+ x11-libs/pango
+ x11-themes/adwaita-icon-theme
+ gstreamer? (
+ $(python_gen_cond_dep '
+ dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+ ')
+ media-libs/gstreamer:1.0
+ media-libs/gst-plugins-base:1.0
+ )
+"
+
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-setup-no-display.patch
+ "${FILESDIR}"/${PN}-gtk-compat.patch
+)
+
+src_install() {
+ distutils-r1_src_install
+
+ mv -v "${ED}"/usr/share/{appdata,metainfo} || die
+ gunzip -v "${ED}"/usr/share/man/man1/${PN}.1.gz || die
+}