summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndrey Grozin <grozin@gentoo.org>2018-05-20 15:44:14 +0700
committerAndrey Grozin <grozin@gentoo.org>2018-05-20 15:44:14 +0700
commit011b0a1ccc898788f7693466e0b5a339e2690d99 (patch)
tree1934d0fef783dcfd9d04c8de64aea9e1db13e8d8 /games-board/pysolfc/pysolfc-2.2.0.ebuild
parentdev-python/random2: initial import (diff)
downloadgentoo-011b0a1ccc898788f7693466e0b5a339e2690d99.tar.gz
gentoo-011b0a1ccc898788f7693466e0b5a339e2690d99.tar.bz2
gentoo-011b0a1ccc898788f7693466e0b5a339e2690d99.zip
games-board/pysolfc: bump to 2.2.0
Package-Manager: Portage-2.3.19, Repoman-2.3.6
Diffstat (limited to 'games-board/pysolfc/pysolfc-2.2.0.ebuild')
-rw-r--r--games-board/pysolfc/pysolfc-2.2.0.ebuild69
1 files changed, 69 insertions, 0 deletions
diff --git a/games-board/pysolfc/pysolfc-2.2.0.ebuild b/games-board/pysolfc/pysolfc-2.2.0.ebuild
new file mode 100644
index 00000000000..774ae85ef5b
--- /dev/null
+++ b/games-board/pysolfc/pysolfc-2.2.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6} )
+PYTHON_REQ_USE="tk"
+
+inherit eutils distutils-r1
+
+MY_PN=PySolFC
+
+DESCRIPTION="An exciting collection of more than 1000 solitaire card games"
+HOMEPAGE="http://pysolfc.sourceforge.net/"
+SRC_URI="https://github.com/shlomif/${MY_PN}/archive/${P}.tar.gz
+ extra-cardsets? ( mirror://sourceforge/${PN}/archive/${P}/${MY_PN}-Cardsets-2.0.tar.bz2 )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="extra-cardsets minimal +sound"
+
+S=${WORKDIR}/${MY_PN}-${P}
+
+DEPEND=""
+RDEPEND="${RDEPEND}
+ python_targets_python3_5? ( dev-python/random2[python_targets_python3_5] )
+ python_targets_python3_6? ( dev-python/random2[python_targets_python3_6] )
+ !minimal? ( dev-python/pillow[tk,${PYTHON_USEDEP}]
+ dev-tcltk/tktable )
+ sound? ( dev-python/pygame[${PYTHON_USEDEP}] )"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-gentoo.patch" #591904
+ "${FILESDIR}/${PN}-locales.patch"
+)
+
+python_prepare_all() {
+ sed -i \
+ -e "/pysol.desktop/d" \
+ -e "s:share/icons:share/pixmaps:" \
+ -e "s:data_dir =.*:data_dir = \'/usr/share/${PN}\':" \
+ setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ pushd html-src > /dev/null || die "html-src not found"
+ PYTHONPATH=../pysollib "${EPYTHON}" gen-html.py || die "gen-html failed"
+ mv images html/ || die "mv images failed"
+ popd > /dev/null
+}
+
+python_install_all() {
+ make_desktop_entry pysol.py "PySol Fan Club Edition" pysol02
+
+ if use extra-cardsets; then
+ insinto /usr/share/${PN}
+ doins -r "${WORKDIR}"/${MY_PN}-Cardsets-2.0/*
+ fi
+
+ dosym /usr/share/doc/${PF}/html /usr/share/${PN}/html
+
+ doman docs/*.6
+ DOCS=( README.md AUTHORS docs/README docs/README.SOURCE )
+ HTML_DOCS=( html-src/html/. )
+ distutils-r1_python_install_all
+}