summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSergei Trofimovich <slyfox@gentoo.org>2020-07-05 18:26:14 +0100
committerSergei Trofimovich <slyfox@gentoo.org>2020-07-05 18:26:25 +0100
commit600127764509dacd2921b94db82ca20432f9fd5a (patch)
tree60eb00b2553aa16cf7206a34cb92620b219e2ff6 /games-emulation
parentgames-emulation/dolphin: update to EAPI=7 (diff)
downloadgentoo-600127764509dacd2921b94db82ca20432f9fd5a.tar.gz
gentoo-600127764509dacd2921b94db82ca20432f9fd5a.tar.bz2
gentoo-600127764509dacd2921b94db82ca20432f9fd5a.zip
games-emulation/dolphin: make 5.0_p20200705 snapshot release
Package-Manager: Portage-2.3.103, Repoman-2.3.23 Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
Diffstat (limited to 'games-emulation')
-rw-r--r--games-emulation/dolphin/Manifest1
-rw-r--r--games-emulation/dolphin/dolphin-5.0_p20200705.ebuild182
-rw-r--r--games-emulation/dolphin/dolphin-9999.ebuild4
3 files changed, 186 insertions, 1 deletions
diff --git a/games-emulation/dolphin/Manifest b/games-emulation/dolphin/Manifest
index 94f826d6911d..9062bef840b6 100644
--- a/games-emulation/dolphin/Manifest
+++ b/games-emulation/dolphin/Manifest
@@ -1 +1,2 @@
DIST dolphin-5.0.tar.gz 38246344 BLAKE2B 540eb5d0d3f2250d0b562caaef113bcae66ea47c3b6c2884f5612f36f990592d2c83ad0348cb83d71f5329414580f6cbf07081bdef2661bd277ee2f7613dc661 SHA512 8de76f811abfb82e19502336734e86ba600c11d9fa95bcf7f70a2a525165d07ead826854c39377602aab7856a057af9ba91bff458cf2dd008712527290489d3a
+DIST dolphin-5.0_p20200705.tar.gz 41580877 BLAKE2B 78fce8cb10543857633d66789999b0ebb8f195e10652b9316f3346d5c84797dea96a31f509f86cb9470b4b9677ca58c4a865494121277cd0bc7dcc93932da9f4 SHA512 8b1aed8c98ff7205d7b1716aea3faad0bfa3d1ff3fe3a616431a421ae62592a57887e18295276b7a0fee52d19e641b72d5dc00e071cefea7fbe40adc9f3f01a1
diff --git a/games-emulation/dolphin/dolphin-5.0_p20200705.ebuild b/games-emulation/dolphin/dolphin-5.0_p20200705.ebuild
new file mode 100644
index 000000000000..2c2a6b61d4a0
--- /dev/null
+++ b/games-emulation/dolphin/dolphin-5.0_p20200705.ebuild
@@ -0,0 +1,182 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLOCALES="ar ca cs da de el en es fa fr hr hu it ja ko ms nb nl pl pt pt_BR ro ru sr sv tr zh_CN zh_TW"
+PLOCALE_BACKUP="en"
+
+inherit cmake desktop xdg-utils l10n pax-utils
+
+if [[ ${PV} == *9999 ]]
+then
+ EGIT_REPO_URI="https://github.com/dolphin-emu/dolphin"
+ inherit git-r3
+else
+ inherit vcs-snapshot
+ commit=0dbe8fb2eaa608a6540df3d269648a596c29cf4b
+ SRC_URI="https://github.com/dolphin-emu/dolphin/archive/${commit}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Gamecube and Wii game emulator"
+HOMEPAGE="https://www.dolphin-emu.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="alsa bluetooth discord-presence doc +evdev ffmpeg log lto profile pulseaudio +qt5 systemd upnp"
+
+RDEPEND="
+ dev-libs/hidapi:0=
+ dev-libs/libfmt:0=
+ dev-libs/lzo:2=
+ dev-libs/pugixml:0=
+ media-libs/libpng:0=
+ media-libs/libsfml
+ media-libs/mesa[egl]
+ net-libs/enet:1.3
+ net-libs/mbedtls:0=
+ net-misc/curl:0=
+ sys-libs/readline:0=
+ sys-libs/zlib:0=
+ x11-libs/libXext
+ x11-libs/libXi
+ x11-libs/libXrandr
+ virtual/libusb:1
+ virtual/opengl
+ alsa? ( media-libs/alsa-lib )
+ bluetooth? ( net-wireless/bluez )
+ evdev? (
+ dev-libs/libevdev
+ virtual/udev
+ )
+ ffmpeg? ( media-video/ffmpeg:= )
+ profile? ( dev-util/oprofile )
+ pulseaudio? ( media-sound/pulseaudio )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ )
+ systemd? ( sys-apps/systemd:0= )
+ upnp? ( net-libs/miniupnpc )
+"
+DEPEND="${RDEPEND}
+ app-arch/zip
+ media-libs/freetype
+ sys-devel/gettext
+ virtual/pkgconfig"
+
+# vulkan-loader required for vulkan backend which can be selected
+# at runtime.
+RDEPEND="${RDEPEND}
+ media-libs/vulkan-loader"
+
+src_prepare() {
+ cmake_src_prepare
+
+ # Remove all the bundled libraries that support system-installed
+ # preference. See CMakeLists.txt for conditional 'add_subdirectory' calls.
+ local KEEP_SOURCES=(
+ Bochs_disasm
+ FreeSurround
+
+ # vulkan's API is not backwards-compatible:
+ # new release dropped VK_PRESENT_MODE_RANGE_SIZE_KHR
+ # but dolphin still relies on it, bug #729832
+ Vulkan
+
+ cpp-optparse
+ # no support for for using system library
+ glslang
+ imgui
+ # FIXME: xxhash can't be found by cmake
+ xxhash
+ # no support for for using system library
+ minizip
+ # soundtouch uses shorts, not floats
+ soundtouch
+ cubeb
+ discord-rpc
+ # Their build set up solely relies on the build in gtest.
+ gtest
+ # gentoo's version requires exception support.
+ # dolphin disables exceptions and fails the build.
+ picojson
+ # No code to detect shared library.
+ zstd
+ )
+ local s
+ for s in "${KEEP_SOURCES[@]}"; do
+ mv -v "Externals/${s}" . || die
+ done
+ einfo "removing sources: $(echo Externals/*)"
+ rm -r Externals/* || die "Failed to delete Externals dir."
+ for s in "${KEEP_SOURCES[@]}"; do
+ mv -v "${s}" "Externals/" || die
+ done
+
+ remove_locale() {
+ # Ensure preservation of the backup locale when no valid LINGUA is set
+ if [[ "${PLOCALE_BACKUP}" == "${1}" ]] && [[ "${PLOCALE_BACKUP}" == "$(l10n_get_locales)" ]]; then
+ return
+ else
+ rm "Languages/po/${1}.po" || die
+ fi
+ }
+
+ l10n_find_plocales_changes "Languages/po/" "" '.po'
+ l10n_for_each_disabled_locale_do remove_locale
+}
+
+src_configure() {
+ local mycmakeargs=(
+ # Use ccache only when user did set FEATURES=ccache (or similar)
+ # not when ccache binary is present in system (automagic).
+ -DCCACHE_BIN=CCACHE_BIN-NOTFOUND
+ -DENABLE_ALSA=$(usex alsa)
+ -DENABLE_BLUEZ=$(usex bluetooth)
+ -DENABLE_EVDEV=$(usex evdev)
+ -DENCODE_FRAMEDUMPS=$(usex ffmpeg)
+ -DENABLE_LLVM=OFF
+ -DENABLE_LTO=$(usex lto)
+ -DENABLE_PULSEAUDIO=$(usex pulseaudio)
+ -DENABLE_QT=$(usex qt5)
+ -DENABLE_SDL=OFF # not supported: #666558
+ -DFASTLOG=$(usex log)
+ -DOPROFILING=$(usex profile)
+ -DUSE_DISCORD_PRESENCE=$(usex discord-presence)
+ -DUSE_SHARED_ENET=ON
+ -DUSE_UPNP=$(usex upnp)
+
+ # Undo cmake-utils.eclass's defaults.
+ # All dolphin's libraries are private
+ # and rely on circular dependency resolution.
+ -DBUILD_SHARED_LIBS=OFF
+ )
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ dodoc Readme.md
+ if use doc; then
+ dodoc -r docs/ActionReplay docs/DSP docs/WiiMote
+ fi
+
+ doicon -s 48 Data/dolphin-emu.png
+ doicon -s scalable Data/dolphin-emu.svg
+ doicon Data/dolphin-emu.svg
+}
+
+pkg_postinst() {
+ # Add pax markings for hardened systems
+ pax-mark -m "${EPREFIX}"/usr/games/bin/"${PN}"-emu
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+}
diff --git a/games-emulation/dolphin/dolphin-9999.ebuild b/games-emulation/dolphin/dolphin-9999.ebuild
index 706fa7cec8de..2c2a6b61d4a0 100644
--- a/games-emulation/dolphin/dolphin-9999.ebuild
+++ b/games-emulation/dolphin/dolphin-9999.ebuild
@@ -13,7 +13,9 @@ then
EGIT_REPO_URI="https://github.com/dolphin-emu/dolphin"
inherit git-r3
else
- SRC_URI="https://github.com/${PN}-emu/${PN}/archive/${PV}.zip -> ${P}.zip"
+ inherit vcs-snapshot
+ commit=0dbe8fb2eaa608a6540df3d269648a596c29cf4b
+ SRC_URI="https://github.com/dolphin-emu/dolphin/archive/${commit}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64"
fi