summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorBetaRays <BetaRays@protonmail.com>2018-07-17 20:26:30 +0200
committerMichał Górny <mgorny@gentoo.org>2018-07-20 23:02:12 +0200
commit3c4ac4212024c0d9040b08d01653328df253e146 (patch)
tree1233e45e851bdc309eb22e0daabab3e40424f3ab /games-engines/love/love-0.10.2.ebuild
parentgames-action/trosh: Update love dependency (diff)
downloadgentoo-3c4ac4212024c0d9040b08d01653328df253e146.tar.gz
gentoo-3c4ac4212024c0d9040b08d01653328df253e146.tar.bz2
gentoo-3c4ac4212024c0d9040b08d01653328df253e146.zip
games-engines/love: bump to 0.10.2
Closes: https://bugs.gentoo.org/640802 Package-Manager: Portage-2.3.40, Repoman-2.3.9
Diffstat (limited to 'games-engines/love/love-0.10.2.ebuild')
-rw-r--r--games-engines/love/love-0.10.2.ebuild75
1 files changed, 75 insertions, 0 deletions
diff --git a/games-engines/love/love-0.10.2.ebuild b/games-engines/love/love-0.10.2.ebuild
new file mode 100644
index 00000000000..9ac920cc9cd
--- /dev/null
+++ b/games-engines/love/love-0.10.2.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2-utils xdg-utils
+
+if [[ ${PV} == 9999* ]]; then
+ inherit mercurial
+ EHG_REPO_URI="https://bitbucket.org/rude/${PN}"
+ SRC_URI=""
+ KEYWORDS=""
+else
+ SRC_URI="https://www.bitbucket.org/rude/${PN}/downloads/${P}-linux-src.tar.gz"
+ KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="A framework for 2D games in Lua"
+HOMEPAGE="http://love2d.org/"
+
+LICENSE="ZLIB"
+SLOT="0.10"
+IUSE="+luajit"
+
+RDEPEND="sys-libs/zlib
+ dev-games/physfs
+ !luajit? ( dev-lang/lua:0[deprecated] )
+ luajit? ( dev-lang/luajit:2 )
+ media-libs/freetype
+ media-libs/libmodplug
+ media-libs/libsdl2[joystick,opengl]
+ media-libs/libogg
+ media-libs/libtheora
+ media-libs/libvorbis
+ media-libs/openal
+ media-sound/mpg123
+ virtual/opengl"
+DEPEND="${RDEPEND}"
+
+DOCS=( "readme.md" "changes.txt" )
+
+src_prepare() {
+ default
+ if [[ ${PV} == 9999* ]]; then
+ ./platform/unix/automagic || die
+ fi
+}
+
+src_configure() {
+ econf --with-lua=$(usex luajit luajit lua)
+}
+
+src_install() {
+ default
+
+ find "${D}" -name '*.la' -delete || die
+ if [[ ${SLOT} != 0 ]]
+ then
+ mv "${ED}/usr/bin/${PN}" "${ED}/usr/bin/${PN}-${SLOT}" || die
+ mv "${ED}"/usr/share/applications/love{,"-$SLOT"}.desktop || die
+ sed -i -e "/^Name=/s/$/ ($SLOT)/" -e "s|/usr/bin/love|/usr/bin/love-$SLOT|" "${ED}/usr/share/applications/love-$SLOT.desktop" || die
+ rm -r "${ED}"/usr/{lib64/liblove.so,share/{mime/,pixmaps/,icons/,man/}} || die
+ fi
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ xdg_desktop_database_update
+ xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ xdg_desktop_database_update
+ xdg_mimeinfo_database_update
+}