gnome-base/nautilus: version bump 3.22.4 → 3.24.0

Package-Manager: Portage-2.3.6, Repoman-2.3.3

2 files changed, 107 insertions, 0 deletions

diff --git a/gnome-extra/gnome-boxes/Manifest b/gnome-extra/gnome-boxes/Manifest
index 18466b50b45d..89831245b77f 100644
--- a/gnome-extra/gnome-boxes/Manifest
+++ b/gnome-extra/gnome-boxes/Manifest
@@ -1 +1,2 @@
 DIST gnome-boxes-3.22.4.tar.xz 1704964 SHA256 585a1c292010ebb479cb60e02621d01d450f84cdad82a61b7ce58a0218e1cff2 SHA512 98e923c67d116ad5411734415b96ced5cd5f9f2a03335c8b00835a2eae47ea46dfe72f0aa5819d6ac9310cb80b5c6504a9ef7c8e4d8ef4c35495aa8fa74ee848 WHIRLPOOL c2fe23ae0a9b0051c7b117ed6b3965961d4de35e7c251f25a3b37e62e8ef4d9a5278817028598d9cd5ebb06d9218534426c3b4e74efda9f6226b44e1efb1cebc
+DIST gnome-boxes-3.24.0.tar.xz 1710652 SHA256 7495ea7184b6ef650033daf6941328b785b22e522e8142b9d190575d215dec49 SHA512 979d5c0f2cef052e2713508fc2fd46d64a3a325edd38dd0aa99f2e9700efd3f84916847b35487f9d7eb5e5e1c5f3b4b712b649fecf1523821c3488fa6b250026 WHIRLPOOL ca44d83ad85326293b14c9197c04b09966e1a917a24011df0f10f624412261f4799b9ef371beb81bc0258ff1d79f8707ab6c03c0558b7b3d0c79d13bfddbba90
diff --git a/gnome-extra/gnome-boxes/gnome-boxes-3.24.0.ebuild b/gnome-extra/gnome-boxes/gnome-boxes-3.24.0.ebuild
new file mode 100644
index 000000000000..a945e1f416a6
--- /dev/null
+++ b/gnome-extra/gnome-boxes/gnome-boxes-3.24.0.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.28"
+
+inherit gnome2 linux-info readme.gentoo-r1 vala
+
+DESCRIPTION="Simple GNOME 3 application to access remote or virtual systems"
+HOMEPAGE="https://wiki.gnome.org/Apps/Boxes"
+
+LICENSE="LGPL-2"
+SLOT="0"
+
+# We force 'bindist' due to licenses from gnome-boxes-nonfree
+IUSE="" #bindist
+
+KEYWORDS="~amd64" # qemu-kvm[spice] is 64bit-only
+
+# NOTE: sys-fs/* stuff is called via exec()
+# FIXME: ovirt is not available in tree
+# FIXME: use vala.eclass but only because of libgd not being able
+#        to use its pre-generated files so do not copy all the
+#        vala deps like live ebuild has.
+# FIXME: qemu probably needs to depend on spice[smartcard]
+#        directly with USE=spice
+RDEPEND="
+	>=app-arch/libarchive-3:=
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/gobject-introspection-0.9.6:=
+	>=dev-libs/libxml2-2.7.8:2
+	>=sys-libs/libosinfo-0.2.12
+	>=app-emulation/qemu-1.3.1[spice,smartcard,usbredir]
+	>=app-emulation/libvirt-0.9.3[libvirtd,qemu]
+	>=app-emulation/libvirt-glib-0.2.3
+	>=x11-libs/gtk+-3.19.8:3
+	>=net-libs/gtk-vnc-0.4.4[gtk3]
+	app-crypt/libsecret
+	app-emulation/spice[smartcard]
+	>=net-misc/spice-gtk-0.32[gtk3,smartcard,usbredir]
+	virtual/libusb:1
+
+	>=app-misc/tracker-0.16:0=[iso]
+
+	>=sys-apps/util-linux-2.20
+	>=net-libs/libsoup-2.38:2.4
+
+	sys-fs/mtools
+	>=virtual/libgudev-165:=
+"
+#	!bindist? ( gnome-extra/gnome-boxes-nonfree )
+
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	app-text/yelp-tools
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="Before running gnome-boxes, you will need to load the KVM modules.
+If you have an Intel Processor, run:
+# modprobe kvm-intel
+
+If you have an AMD Processor, run:
+# modprobe kvm-amd"
+
+pkg_pretend() {
+	linux-info_get_any_version
+
+	if linux_config_exists; then
+		if ! { linux_chkconfig_present KVM_AMD || \
+			linux_chkconfig_present KVM_INTEL; }; then
+			ewarn "You need KVM support in your kernel to use GNOME Boxes!"
+		fi
+	fi
+}
+
+src_prepare() {
+	# Do not change CFLAGS, wondering about VALA ones but appears to be
+	# needed as noted in configure comments below
+	sed 's/CFLAGS="$CFLAGS -O0 -ggdb3"//' -i configure{.ac,} || die
+
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# debug needed for splitdebug proper behavior (cardoe), bug #????
+	gnome2_src_configure \
+		--enable-debug \
+		--disable-strict-cc \
+		--disable-ovirt
+}
+
+src_install() {
+	gnome2_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}