summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2021-03-13 13:14:09 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2021-03-13 13:17:02 +0100
commit361f9c9d31ddde38a8a9434d9ed3e316fc712880 (patch)
tree7eee86f1fce55e89fff80a38c1daad57bc21ebb5 /kde-frameworks/kwallet/kwallet-5.80.0.ebuild
parentkde-frameworks/ktextwidgets: 5.80.0 version bump (diff)
downloadgentoo-361f9c9d31ddde38a8a9434d9ed3e316fc712880.tar.gz
gentoo-361f9c9d31ddde38a8a9434d9ed3e316fc712880.tar.bz2
gentoo-361f9c9d31ddde38a8a9434d9ed3e316fc712880.zip
kde-frameworks/kwallet: 5.80.0 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'kde-frameworks/kwallet/kwallet-5.80.0.ebuild')
-rw-r--r--kde-frameworks/kwallet/kwallet-5.80.0.ebuild54
1 files changed, 54 insertions, 0 deletions
diff --git a/kde-frameworks/kwallet/kwallet-5.80.0.ebuild b/kde-frameworks/kwallet/kwallet-5.80.0.ebuild
new file mode 100644
index 00000000000..6ca3378209d
--- /dev/null
+++ b/kde-frameworks/kwallet/kwallet-5.80.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.2
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Framework providing desktop-wide storage for passwords"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="gpg +man"
+
+BDEPEND="
+ man? ( >=kde-frameworks/kdoctools-${PVCUT}:5 )
+"
+DEPEND="
+ dev-libs/libgcrypt:0=
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ =kde-frameworks/kconfig-${PVCUT}*:5
+ =kde-frameworks/kconfigwidgets-${PVCUT}*:5
+ =kde-frameworks/kcoreaddons-${PVCUT}*:5
+ =kde-frameworks/kdbusaddons-${PVCUT}*:5
+ =kde-frameworks/ki18n-${PVCUT}*:5
+ =kde-frameworks/knotifications-${PVCUT}*:5
+ =kde-frameworks/kservice-${PVCUT}*:5
+ =kde-frameworks/kwidgetsaddons-${PVCUT}*:5
+ =kde-frameworks/kwindowsystem-${PVCUT}*:5
+ gpg? ( >=app-crypt/gpgme-1.7.1[cxx,qt5] )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package gpg Gpgmepp)
+ $(cmake_use_find_package man KF5DocTools)
+ )
+
+ ecm_src_configure
+}
+
+pkg_postinst() {
+ if [[ -z "${REPLACING_VERSIONS}" ]]; then
+ elog "Optional dependencies:"
+ optfeature "Auto-unlocking after account login" kde-plasma/kwallet-pam
+ optfeature "KWallet management" kde-apps/kwalletmanager:5
+ elog "For more information, read https://wiki.gentoo.org/wiki/KDE#KWallet"
+ fi
+ ecm_pkg_postinst
+}