summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorNicolas Bock <nicolasbock@gentoo.org>2017-07-31 09:06:07 +0200
committerNicolas Bock <nicolasbock@gentoo.org>2017-10-03 06:23:50 -0600
commit61652454337f2855c07015a79cdbb3cdf918dc8f (patch)
tree9049e7f0ecb4dbab76e24c246449f28025a12493 /mail-client/neomutt/neomutt-20170912.ebuild
parentdev-lang/xsb: consider ac_tool_prefix when applying gcc flags (diff)
downloadgentoo-61652454337f2855c07015a79cdbb3cdf918dc8f.tar.gz
gentoo-61652454337f2855c07015a79cdbb3cdf918dc8f.tar.bz2
gentoo-61652454337f2855c07015a79cdbb3cdf918dc8f.zip
mail-client/neomutt: Add new package
The neomutt package provides an alternative to the mutt package. It can be installed at the same time as mutt. Package-Manager: Portage-2.3.8, Repoman-2.3.1
Diffstat (limited to 'mail-client/neomutt/neomutt-20170912.ebuild')
-rw-r--r--mail-client/neomutt/neomutt-20170912.ebuild115
1 files changed, 115 insertions, 0 deletions
diff --git a/mail-client/neomutt/neomutt-20170912.ebuild b/mail-client/neomutt/neomutt-20170912.ebuild
new file mode 100644
index 00000000000..404b40f4688
--- /dev/null
+++ b/mail-client/neomutt/neomutt-20170912.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic
+
+SRC_URI="https://github.com/${PN}/${PN}/archive/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+DESCRIPTION="A small but very powerful text-based mail client"
+HOMEPAGE="https://www.neomutt.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="berkdb crypt debug doc gdbm gnutls gpg idn kerberos kyotocabinet
+ libressl lmdb nls notmuch qdbm sasl selinux slang smime ssl +symlink
+ tokyocabinet"
+
+CDEPEND="
+ app-misc/mime-types
+ berkdb? ( >=sys-libs/db-4:= )
+ gdbm? ( sys-libs/gdbm )
+ kyotocabinet? ( dev-db/kyotocabinet )
+ lmdb? ( dev-db/lmdb )
+ nls? ( virtual/libintl )
+ qdbm? ( dev-db/qdbm )
+ tokyocabinet? ( dev-db/tokyocabinet )
+ gnutls? ( >=net-libs/gnutls-1.0.17 )
+ gpg? ( >=app-crypt/gpgme-0.9.0 )
+ idn? ( net-dns/libidn )
+ kerberos? ( virtual/krb5 )
+ notmuch? ( net-mail/notmuch )
+ sasl? ( >=dev-libs/cyrus-sasl-2 )
+ !slang? ( sys-libs/ncurses:0 )
+ slang? ( sys-libs/slang )
+ ssl? (
+ !libressl? ( >=dev-libs/openssl-0.9.6:0 )
+ libressl? ( dev-libs/libressl )
+ )
+"
+DEPEND="${CDEPEND}
+ net-mail/mailbase
+ doc? (
+ dev-libs/libxml2
+ dev-libs/libxslt
+ app-text/docbook-xsl-stylesheets
+ || ( www-client/lynx www-client/w3m www-client/elinks )
+ )"
+RDEPEND="${CDEPEND}
+ selinux? ( sec-policy/selinux-mutt )
+"
+
+S="${WORKDIR}/${PN}-${P}"
+
+src_prepare() {
+ eapply "${FILESDIR}/0001-Rename-mutt-to-neomutt-${PV}.patch"
+ eapply_user
+ AT_M4DIR="m4" eautoreconf
+}
+
+src_configure() {
+ local myconf=(
+ "$(use_enable crypt pgp)"
+ "$(use_enable debug)"
+ "$(use_enable doc)"
+ "$(use_enable gpg gpgme)"
+ "$(use_enable nls)"
+ "$(use_enable smime)"
+ "$(use_enable notmuch)"
+ "$(use_with idn)"
+ "$(use_with kerberos gss)"
+ "$(use_with sasl)"
+ "$(use_with tokyocabinet)"
+ "$(use_with kyotocabinet)"
+ "$(use_with qdbm)"
+ "$(use_with gdbm)"
+ "$(use_with berkdb bdb)"
+ "$(use_with lmdb)"
+ "--with-$(usex slang slang curses)"
+ "--sysconfdir=${EPREFIX}/etc/${PN}"
+ "--with-docdir=${EPREFIX}/usr/share/doc/${PF}"
+ )
+
+ if use gnutls; then
+ myconf+=( "--with-gnutls" )
+ elif use ssl; then
+ myconf+=( "--with-ssl" )
+ fi
+
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+
+ # A newer file is provided by app-misc/mime-types. So we link it.
+ rm "${ED}"/etc/${PN}/mime.types || die
+ dosym "${EPREFIX}/etc/mime.types" /etc/${PN}/mime.types
+
+ ## A man-page is always handy, so fake one
+ if use !doc; then
+ emake -C doc muttrc.man
+ # make the fake slightly better, bug #413405
+ sed -e 's#@docdir@/manual.txt#http://www.neomutt.org/guide#' \
+ -e 's#in @docdir@,#at http://www.neomutt.org/,#' \
+ -e "s#@sysconfdir@#${EPREFIX}/etc/${PN}#" \
+ -e "s#@bindir@#${EPREFIX}/usr/bin#" \
+ doc/mutt.man > neomutt.1 || die
+ cp doc/muttrc.man neomuttrc.5 || die
+ doman neomutt.1 neomuttrc.5
+ fi
+
+ dodoc COPYRIGHT LICENSE* ChangeLog* README*
+}