summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMart Raudsepp <leio@gentoo.org>2019-02-22 19:19:14 +0200
committerMart Raudsepp <leio@gentoo.org>2019-02-22 20:02:37 +0200
commit6a6f11ede87b506422198ab51026eaf9ff362f64 (patch)
tree2f679b1029c730106238139fd270e30c4ca36cb9 /mail-client
parentgnome-extra/gnome-calendar-3.26: dep fixes, USE=gtk-doc support (diff)
downloadgentoo-6a6f11ede87b506422198ab51026eaf9ff362f64.tar.gz
gentoo-6a6f11ede87b506422198ab51026eaf9ff362f64.tar.bz2
gentoo-6a6f11ede87b506422198ab51026eaf9ff362f64.zip
mail-client/evolution: bump to 3.30.5
Closes: https://bugs.gentoo.org/678064 Package-Manager: Portage-2.3.52, Repoman-2.3.12 Signed-off-by: Mart Raudsepp <leio@gentoo.org>
Diffstat (limited to 'mail-client')
-rw-r--r--mail-client/evolution/Manifest1
-rw-r--r--mail-client/evolution/evolution-3.26.6.ebuild3
-rw-r--r--mail-client/evolution/evolution-3.30.5.ebuild153
3 files changed, 156 insertions, 1 deletions
diff --git a/mail-client/evolution/Manifest b/mail-client/evolution/Manifest
index 5aebada0129..46415d2e0b6 100644
--- a/mail-client/evolution/Manifest
+++ b/mail-client/evolution/Manifest
@@ -1,2 +1,3 @@
DIST evolution-3.24.6.tar.xz 12153692 BLAKE2B ced20d9e08f6b9aac65be6f5ecd5beb861feec40dddc4411b1bdc6519e249de8db8b3319450808d7a31b80386f9830f351b7edacb3c6fcd28fe5fdfe343329f7 SHA512 da5c9062791996735e52575894763597cc957cb17bc0abe46a966f0e3e6706550ce534ae03b2c444d142547119f3a59aec6ee17e0302a002d8437da166ef7178
DIST evolution-3.26.6.tar.xz 12036120 BLAKE2B b0828f172935ce75bad6e2fa9859b65e96f8b8369d8f2c4b836ef9dd992168dcdca256df4aa0577117819f8d21da3976b338fb66b75f0e2511b7f1d23712befa SHA512 34a6f3ec12c6330c2b742281030f641a0998293663d3c2ac4151eef24067ff95403fec37550be2d8d22e43e334b4349f1ece40b75cc23b1dfcec88a9a694363f
+DIST evolution-3.30.5.tar.xz 11995960 BLAKE2B 4a2ac539e88467148dd3be2bf2607be55ea39dfb0ceb89183a6f4fa3ee66c1973690c4e540a7405743c202aa777ad9aa147600390e909ffc93cb2dae1ebb62d9 SHA512 1d776fdb0da4166d9346ad4cd05d7ee050e0bf3ac1edc1f7d3fb4ba8909e35429e8d076a5b6e223f3fc94e2a8ad6337205c1d648220a3fdf593bae64d9c975d1
diff --git a/mail-client/evolution/evolution-3.26.6.ebuild b/mail-client/evolution/evolution-3.26.6.ebuild
index 439aa36d847..7ffea1371ae 100644
--- a/mail-client/evolution/evolution-3.26.6.ebuild
+++ b/mail-client/evolution/evolution-3.26.6.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
@@ -72,6 +72,7 @@ DEPEND="${COMMON_DEPEND}
app-text/docbook-xml-dtd:4.1.2
dev-util/gdbus-codegen
dev-util/glib-utils
+ dev-util/itstool
gtk-doc? ( dev-util/gtk-doc )
>=dev-util/intltool-0.40.0
>=sys-devel/gettext-0.18.3
diff --git a/mail-client/evolution/evolution-3.30.5.ebuild b/mail-client/evolution/evolution-3.30.5.ebuild
new file mode 100644
index 00000000000..f46ab547f59
--- /dev/null
+++ b/mail-client/evolution/evolution-3.30.5.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2 flag-o-matic readme.gentoo-r1
+
+DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) CC-BY-SA-3.0 FDL-1.3+ OPENLDAP"
+SLOT="2.0"
+
+IUSE="archive +bogofilter geolocation gtk-doc highlight ldap spamassassin spell ssl +weather ytnef"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
+
+# glade-3 support is for maintainers only per configure.ac
+# pst is not mature enough and changes API/ABI frequently
+# dconf explicitely needed for backup plugin
+# gnome-desktop support is optional with --enable-gnome-desktop
+# automagic libunity dep
+COMMON_DEPEND="
+ >=app-crypt/gcr-3.4:=[gtk]
+ >=app-text/enchant-1.6.0:0
+ >=dev-libs/glib-2.46:2[dbus]
+ >=dev-libs/libxml2-2.7.3:2
+ >=gnome-base/gnome-desktop-2.91.3:3=
+ >=gnome-base/gsettings-desktop-schemas-2.91.92
+ >=gnome-extra/evolution-data-server-${PV}:=[gtk,weather?]
+ >=media-libs/libcanberra-0.25[gtk3]
+ >=net-libs/libsoup-2.42:2.4
+ >=net-libs/webkit-gtk-2.16.0:4
+ >=x11-libs/cairo-1.9.15:=[glib]
+ >=x11-libs/gdk-pixbuf-2.24:2
+ >=x11-libs/gtk+-3.22:3
+ >=x11-libs/libnotify-0.7:=
+ >=x11-misc/shared-mime-info-0.22
+
+ >=app-text/iso-codes-0.49
+ dev-libs/atk
+ gnome-base/dconf
+ >=dev-libs/libical-3.0.2:=
+ x11-libs/libSM
+ x11-libs/libICE
+
+ archive? ( >=app-arch/gnome-autoar-0.1.1[gtk] )
+ geolocation? (
+ >=media-libs/libchamplain-0.12:0.12[gtk]
+ >=media-libs/clutter-1.0.0:1.0
+ >=media-libs/clutter-gtk-0.90:1.0
+ >=sci-geosciences/geocode-glib-3.10.0
+ x11-libs/mx:1.0 )
+ ldap? ( >=net-nds/openldap-2:= )
+ spell? ( app-text/gtkspell:3 )
+ ssl? (
+ >=dev-libs/nspr-4.6.1:=
+ >=dev-libs/nss-3.11:= )
+ weather? ( >=dev-libs/libgweather-3.10:2= )
+ ytnef? ( net-mail/ytnef )
+"
+DEPEND="${COMMON_DEPEND}
+ app-text/docbook-xml-dtd:4.1.2
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ dev-util/itstool
+ gtk-doc? ( dev-util/gtk-doc
+ app-text/docbook-xml-dtd:4.3 )
+ >=dev-util/intltool-0.40.0
+ >=sys-devel/gettext-0.18.3
+ virtual/pkgconfig
+"
+RDEPEND="${COMMON_DEPEND}
+ bogofilter? ( mail-filter/bogofilter )
+ highlight? ( app-text/highlight )
+ spamassassin? ( mail-filter/spamassassin )
+ !gnome-extra/evolution-exchange
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="To change the default browser if you are not using GNOME, edit
+~/.local/share/applications/mimeapps.list so it includes the
+following content:
+
+[Default Applications]
+x-scheme-handler/http=firefox.desktop
+x-scheme-handler/https=firefox.desktop
+
+(replace firefox.desktop with the name of the appropriate .desktop
+file from /usr/share/applications if you use a different browser)."
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake-utils_src_prepare call, if that works
+
+src_prepare() {
+ cmake-utils_src_prepare
+ gnome2_src_prepare
+}
+
+src_configure() {
+ # Use NSS/NSPR only if 'ssl' is enabled.
+ local mycmakeargs=(
+ -DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+ -DENABLE_SCHEMAS_COMPILE=OFF
+ -DENABLE_GTK_DOC=$(usex gtk-doc)
+ -DWITH_OPENLDAP=$(usex ldap)
+ -DENABLE_SMIME=$(usex ssl)
+ -DENABLE_GNOME_DESKTOP=ON
+ -DWITH_ENCHANT_VERSION=1
+ -DENABLE_CANBERRA=ON
+ -DENABLE_AUTOAR=$(usex archive)
+ -DWITH_HELP=ON
+ -DENABLE_YTNEF=OFF
+ -DWITH_BOGOFILTER=$(usex bogofilter)
+ -DWITH_SPAMASSASSIN=$(usex spamassassin)
+ -DENABLE_GTKSPELL=$(usex spell)
+ -DENABLE_TEXT_HIGHLIGHT=$(usex highlight)
+ -DENABLE_WEATHER=$(usex weather)
+ -DENABLE_CONTACT_MAPS=$(usex geolocation)
+ -DENABLE_YTNEF=$(usex ytnef)
+ -DENABLE_PST_IMPORT=OFF
+ -DWITH_GLADE_CATALOG=OFF
+ )
+
+ cmake-utils_src_configure
+}
+
+src_compile() {
+ cmake-utils_src_compile
+}
+
+src_test() {
+ cmake-utils_src_test
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ # Problems with prelink:
+ # https://bugzilla.gnome.org/show_bug.cgi?id=731680
+ # https://bugzilla.gnome.org/show_bug.cgi?id=732148
+ # https://bugzilla.redhat.com/show_bug.cgi?id=1114538
+ echo PRELINK_PATH_MASK=/usr/bin/evolution > ${T}/99${PN}
+ doenvd "${T}"/99${PN}
+
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ gnome2_pkg_postinst
+ readme.gentoo_print_elog
+}