media-libs/grilo: bump to 0.3.3, fix up test dependencies

Upstream commented out the python tests a while ago in 2015 via an
exit(0) call in testrunner.py, but we kept depending on pygobject both
slots (for gi.repository AND "import glib" usage in the python tests).
Remove the unnecessary deps and replace it with only any python provider,
as tests still want to launch testrunner.py via $PYTHON, for which we
want to set up the variable still, but all the pygobject stuff can go away
for now.
The python code before exit(0) should work with any python interpreter
version, so this extends it to accept all cpython implementations too.

2 files changed, 89 insertions, 0 deletions

diff --git a/media-libs/grilo/Manifest b/media-libs/grilo/Manifest
index 2de51cdb4004..78e60cbb49e8 100644
--- a/media-libs/grilo/Manifest
+++ b/media-libs/grilo/Manifest
@@ -1,2 +1,3 @@
 DIST grilo-0.2.15.tar.xz 627196 SHA256 6f5d2583250a68e76d281edaa08adb880d5a78ed46f9ecd22ae4715f1dd66815 SHA512 ac0a76d9075e5383fe1a56277b23986a8ec8e86f01f3f782ac7dc79539904712c22295c679243604b619f24088a1210622e0699b5601678264bd7651012ded3e WHIRLPOOL 6ea64142e1a4923d0ea3554ec3591f2c3dd6d30fdeaccde9a2a8e48d3e62ff1cd38b23a9eb39aa4c79c3a93c800e7dbfb4ad3a278e92d5ac57cb2e374a18f793
 DIST grilo-0.3.2.tar.xz 638876 SHA256 f26f684a5d76aea8dbce136750bc67d2170b36575f109292fbb78ae99ec87f5b SHA512 190571d320265dd04a2b0728e0af59cc544d0e7de2f6db0599984fa58e694a007f2f7c090c67b4637b40f6d4462b357d204eea1c8c3a67180651d7d71186c93e WHIRLPOOL b3cb2ed4bbcfc762757bbf514104fe7019636ac67badc5ab72c955edf9c21edefe30c61ad39bdee509ff53847d08efc03577cb5c5f5661f24200b55aeda2caa9
+DIST grilo-0.3.3.tar.xz 641440 SHA256 5c874222c7bdf42490cd56765a593c41407247706bb1f24a1bd5d007aa38a0e3 SHA512 5ea94903c7ce0360eec0bb72c0a6c211a83da087538bac1274e8521360364bd852d0f63a27f85119d75541d323f0fbc89b21a577109cc3ee4faa6e33b105be5f WHIRLPOOL aba3474b3753582bd645cd0ca34051601fb3b15a2d6b4db58beb997b1ad1518fb3a2c79901604646b8edb4a84e2b620bb0b8f1861a5df0c3169d47e07ba93d5c
diff --git a/media-libs/grilo/grilo-0.3.3.ebuild b/media-libs/grilo/grilo-0.3.3.ebuild
new file mode 100644
index 000000000000..0e726409d3e6
--- /dev/null
+++ b/media-libs/grilo/grilo-0.3.3.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+VALA_MIN_API_VERSION="0.28"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3/0" # subslot is libgrilo-0.3 soname suffix
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk examples +introspection +network playlist test vala"
+REQUIRED_USE="test? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	dev-libs/libxml2:2
+	net-libs/liboauth
+	gtk? ( >=x11-libs/gtk+-3:3 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9:= )
+	network? ( >=net-libs/libsoup-2.41.3:2.4 )
+	playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.10
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+	test? (
+		${PYTHON_DEPS}
+		media-plugins/grilo-plugins:${SLOT%/*} )
+"
+# eautoreconf requires gnome-common
+
+pkg_setup() {
+	# Python tests are currently commented out, but this is done via in exit(0) in testrunner.py
+	# thus it still needs $PYTHON set up, which python-any-r1_pkg_setup will do for us
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	sed -e "s:GETTEXT_PACKAGE=grilo$:GETTEXT_PACKAGE=grilo-${SLOT%/*}:" \
+		-i configure.ac configure || die "sed configure.ac configure failed"
+
+	# Don't build examples
+	sed -e '/SUBDIRS/s/examples//' \
+		-i Makefile.am -i Makefile.in || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# --enable-debug only changes CFLAGS, useless for us
+	gnome2_src_configure \
+		--disable-static \
+		--disable-debug \
+		$(use_enable gtk test-ui) \
+		$(use_enable introspection) \
+		$(use_enable network grl-net) \
+		$(use_enable playlist grl-pls) \
+		$(use_enable test tests) \
+		$(use_enable vala)
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+	# Upstream made this conditional on gtk-doc build...
+	DOC_MODULE_VERSION=${SLOT%/*} \
+	emake -C doc install DESTDIR="${ED}"
+
+	if use examples; then
+		# Install example code
+		insinto /usr/share/doc/${PF}/examples
+		doins "${S}"/examples/*.c
+	fi
+}