summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorThomas Deutschmann <whissi@gentoo.org>2020-09-11 20:33:16 +0200
committerThomas Deutschmann <whissi@gentoo.org>2020-09-11 21:38:54 +0200
commit512e175785797a160a73754d0e17c87be2cc6fa5 (patch)
tree5792ea5fbd3b0a06fe122d5eb0e27e54dab3ecee /media-libs/jbig2dec/jbig2dec-0.19.ebuild
parentsys-apps/portage: Remove old version 3.0.5 (diff)
downloadgentoo-512e175785797a160a73754d0e17c87be2cc6fa5.tar.gz
gentoo-512e175785797a160a73754d0e17c87be2cc6fa5.tar.bz2
gentoo-512e175785797a160a73754d0e17c87be2cc6fa5.zip
media-libs/jbig2dec: bump to v0.19
Package-Manager: Portage-3.0.6, Repoman-3.0.1 Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>
Diffstat (limited to 'media-libs/jbig2dec/jbig2dec-0.19.ebuild')
-rw-r--r--media-libs/jbig2dec/jbig2dec-0.19.ebuild68
1 files changed, 68 insertions, 0 deletions
diff --git a/media-libs/jbig2dec/jbig2dec-0.19.ebuild b/media-libs/jbig2dec/jbig2dec-0.19.ebuild
new file mode 100644
index 00000000000..97c630ef522
--- /dev/null
+++ b/media-libs/jbig2dec/jbig2dec-0.19.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit autotools python-any-r1
+
+DESCRIPTION="A decoder implementation of the JBIG2 image compression format"
+HOMEPAGE="https://jbig2dec.com/"
+SRC_URI="https://github.com/ArtifexSoftware/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+ test? ( http://jbig2dec.sourceforge.net/ubc/jb2streams.zip )"
+
+LICENSE="AGPL-3"
+SLOT="0/$(ver_cut 1-2)" #698428
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="png static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+ test? (
+ app-arch/unzip
+ ${PYTHON_DEPS}
+ )
+"
+
+RDEPEND="png? ( media-libs/libpng:0= )"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGES README )
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+
+ if use test; then
+ mkdir "${WORKDIR}/ubc" || die
+ mv -v "${WORKDIR}"/*.jb2 "${WORKDIR}/ubc/" || die
+ mv -v "${WORKDIR}"/*.bmp "${WORKDIR}/ubc/" || die
+ fi
+
+ # We only need configure.ac and config_types.h.in
+ sed -i \
+ -e '/^# do we need automake?/,/^autoheader/d' \
+ -e '/echo " $AUTOM.*/,$d' \
+ autogen.sh \
+ || die "failed to modify autogen.sh"
+
+ ./autogen.sh || die
+
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ $(use_enable static-libs static) \
+ $(use_with png libpng)
+}
+
+src_install() {
+ default
+
+ find "${ED}" -name '*.la' -exec rm {} + || die
+}