media-libs/libaacs: Bump to version 0.10.0

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/media-libs/libaacs/libaacs-0.10.0.ebuild b/media-libs/libaacs/libaacs-0.10.0.ebuild
new file mode 100644
index 000000000000..721e0ec2e382
--- /dev/null
+++ b/media-libs/libaacs/libaacs-0.10.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="Open implementation of the Advanced Access Content System (AACS) specification"
+HOMEPAGE="https://www.videolan.org/developers/libaacs.html"
+SRC_URI="https://downloads.videolan.org/pub/videolan/libaacs/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="static-libs"
+
+RDEPEND=">=dev-libs/libgcrypt-1.5.3:0=[${MULTILIB_USEDEP}]
+	>=dev-libs/libgpg-error-1.12[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/flex
+	virtual/yacc
+"
+
+DOCS=( ChangeLog KEYDB.cfg README.txt )
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-optimizations
+		--enable-shared
+		$(use_enable static-libs static)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name "*.la" -delete || die
+}