summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAlexis Ballier <aballier@gentoo.org>2018-06-28 19:22:51 +0200
committerAlexis Ballier <aballier@gentoo.org>2018-06-28 19:23:01 +0200
commitd762929994593b955bb5bfe80e97ebfb542c136e (patch)
treedcbc376718d29dc1f032b60d51731f54d5b129ce /media-libs
parentmedia-libs/libaom: update patches for live ebuild (diff)
downloadgentoo-d762929994593b955bb5bfe80e97ebfb542c136e.tar.gz
gentoo-d762929994593b955bb5bfe80e97ebfb542c136e.tar.bz2
gentoo-d762929994593b955bb5bfe80e97ebfb542c136e.zip
media-libs/libaom: bump to 1.0.0 tag.
Closes: https://bugs.gentoo.org/659222 Package-Manager: Portage-2.3.41, Repoman-2.3.9
Diffstat (limited to 'media-libs')
-rw-r--r--media-libs/libaom/Manifest1
-rw-r--r--media-libs/libaom/libaom-1.0.0.ebuild83
-rw-r--r--media-libs/libaom/libaom-9999.ebuild13
3 files changed, 93 insertions, 4 deletions
diff --git a/media-libs/libaom/Manifest b/media-libs/libaom/Manifest
index 5bb1c4d1908..7946a3d1c3c 100644
--- a/media-libs/libaom/Manifest
+++ b/media-libs/libaom/Manifest
@@ -1 +1,2 @@
DIST libaom-0_pre20180421.tar.xz 1927112 BLAKE2B 3e70917e58ea4871c640f9df1da17f50dd7b1b1c41b99a2411bc68f11ae4acd76f358d1aaab17ba240dfa104fca1d5ebea057a0ba5666741658943dad10601ef SHA512 169872495a210192ae4f97d4d630b00d2219aa085999d9d90136274ec2dcf60d5001c91b5d920ee5b14b76cf02a9a067a3bf57a152bee9e9bc5a524c9205642b
+DIST libaom-1.0.0.tar.gz 2775454 BLAKE2B 09b891d365804f0c086785a00760af3191b40fc66fc752294e915b54454171fb47d3d1b037fb6d276727772ceec3177d78c14f90a2b01e28250d2de735bf02ec SHA512 131512ef286cb138047bb56dea54196f9a8d2b0d9f3d7689299f185338e5c03ee658b0cfe017a099f1a6be351a3a7157204dea70d2645a1d0a9249fd582c3fa4
diff --git a/media-libs/libaom/libaom-1.0.0.ebuild b/media-libs/libaom/libaom-1.0.0.ebuild
new file mode 100644
index 00000000000..7b41eb397c2
--- /dev/null
+++ b/media-libs/libaom/libaom-1.0.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-multilib
+
+if [[ ${PV} == *9999* ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://aomedia.googlesource.com/aom"
+else
+ if [[ ${PV} == *pre* ]]; then
+ SRC_URI="mirror://gentoo/${P}.tar.xz"
+ S="${WORKDIR}/${PN}"
+ else
+ SRC_URI="https://aomedia.googlesource.com/aom/+archive/v${PV}.tar.gz -> ${P}.tar.gz"
+ S="${WORKDIR}"
+ fi
+ KEYWORDS="~amd64 ~hppa ~ia64 ~x86"
+fi
+
+DESCRIPTION="Alliance for Open Media AV1 Codec SDK"
+HOMEPAGE="https://aomedia.org"
+
+LICENSE="BSD-2"
+SLOT="0/0"
+IUSE="doc examples"
+IUSE="${IUSE} cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_ssse3 cpu_flags_x86_sse4_1 cpu_flags_x86_avx cpu_flags_x86_avx2"
+IUSE="${IUSE} cpu_flags_arm_neon"
+
+RDEPEND=""
+DEPEND="abi_x86_32? ( dev-lang/yasm )
+ abi_x86_64? ( dev-lang/yasm )
+ abi_x86_x32? ( dev-lang/yasm )
+ x86-fbsd? ( dev-lang/yasm )
+ amd64-fbsd? ( dev-lang/yasm )
+ doc? ( app-doc/doxygen )
+"
+
+REQUIRED_USE="
+ cpu_flags_x86_sse2? ( cpu_flags_x86_mmx )
+ cpu_flags_x86_ssse3? ( cpu_flags_x86_sse2 )
+"
+
+PATCHES=( "${FILESDIR}/libdirpc2.patch" "${FILESDIR}/pthread_lib2.patch" )
+
+src_prepare() {
+ sed -e 's/lib"/lib${LIB_SUFFIX}"/' -i CMakeLists.txt || die
+ cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+ local mycmakeargs=(
+ -DENABLE_DOCS=$(multilib_native_usex doc ON OFF)
+ -DENABLE_EXAMPLES=$(multilib_native_usex examples ON OFF)
+ -DENABLE_NASM=OFF
+ -DENABLE_TOOLS=ON
+ -DENABLE_WERROR=OFF
+
+ -DENABLE_NEON=$(usex cpu_flags_arm_neon ON OFF)
+ -DENABLE_NEON_ASM=$(usex cpu_flags_arm_neon ON OFF)
+ # ENABLE_DSPR2 / ENABLE_MSA for mips
+ -DENABLE_MMX=$(usex cpu_flags_x86_mmx ON OFF)
+ -DENABLE_SSE=$(usex cpu_flags_x86_sse ON OFF)
+ -DENABLE_SSE2=$(usex cpu_flags_x86_sse2 ON OFF)
+ -DENABLE_SSE3=$(usex cpu_flags_x86_sse3 ON OFF)
+ -DENABLE_SSSE3=$(usex cpu_flags_x86_ssse3 ON OFF)
+ -DENABLE_SSE4_1=$(usex cpu_flags_x86_sse4_1 ON OFF)
+ -DENABLE_AVX=$(usex cpu_flags_x86_avx ON OFF)
+ -DENABLE_AVX2=$(usex cpu_flags_x86_avx2 ON OFF)
+
+ -DBUILD_SHARED_LIBS=ON
+ )
+ cmake-utils_src_configure
+ rm aom.pc # ensure it is rebuilt with proper libdir
+}
+
+multilib_src_install() {
+ cmake-utils_src_install
+ if multilib_is_native_abi && use doc ; then
+ docinto html
+ dodoc docs/html/*
+ fi
+}
diff --git a/media-libs/libaom/libaom-9999.ebuild b/media-libs/libaom/libaom-9999.ebuild
index 29e0528f563..7b41eb397c2 100644
--- a/media-libs/libaom/libaom-9999.ebuild
+++ b/media-libs/libaom/libaom-9999.ebuild
@@ -7,10 +7,15 @@ inherit cmake-multilib
if [[ ${PV} == *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://aomedia.googlesource.com/aom"
-elif [[ ${PV} == *pre* ]]; then
- SRC_URI="mirror://gentoo/${P}.tar.xz"
- KEYWORDS="~amd64"
- S="${WORKDIR}/${PN}"
+else
+ if [[ ${PV} == *pre* ]]; then
+ SRC_URI="mirror://gentoo/${P}.tar.xz"
+ S="${WORKDIR}/${PN}"
+ else
+ SRC_URI="https://aomedia.googlesource.com/aom/+archive/v${PV}.tar.gz -> ${P}.tar.gz"
+ S="${WORKDIR}"
+ fi
+ KEYWORDS="~amd64 ~hppa ~ia64 ~x86"
fi
DESCRIPTION="Alliance for Open Media AV1 Codec SDK"