summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2020-05-07 14:31:50 +0200
committerLars Wendler <polynomial-c@gentoo.org>2020-05-07 14:42:32 +0200
commit3c9253325516323e9e9b21ad738146783d625156 (patch)
tree7d9dcab7838b9b3510354410e1561d81b8d9779f /media-sound/qmmp
parentmedia-libs/libdvdread: Bump to version 6.1.0 (diff)
downloadgentoo-3c9253325516323e9e9b21ad738146783d625156.tar.gz
gentoo-3c9253325516323e9e9b21ad738146783d625156.tar.bz2
gentoo-3c9253325516323e9e9b21ad738146783d625156.zip
media-sound/qmmp: Bump to version 1.4.0
Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Diffstat (limited to 'media-sound/qmmp')
-rw-r--r--media-sound/qmmp/Manifest1
-rw-r--r--media-sound/qmmp/qmmp-1.4.0.ebuild164
2 files changed, 165 insertions, 0 deletions
diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index e637010bbd9..7c0c7100f1b 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1,3 +1,4 @@
DIST qmmp-1.3.2.tar.bz2 1221919 BLAKE2B 3081aa6b3ef4712ea064d5bb23e9ac7da5e102fde820c378438c13723bd007fe8e79ac351b0ad01ca0aa22c50f6b6773965ce418742cf1386d2ae1d7ba7b1758 SHA512 5c68d87650abf10d03dc8638df73a6694e470af1121a936bb983bcbcea04d95616ad8a55d87e8874b51b7424a890dad2c5353afe65db7029f6513a382e2144e4
DIST qmmp-1.3.6.tar.bz2 1250131 BLAKE2B ddcce7f55dddfb667c2a2005172c5b8de2f11babb8cd18114099416c1c916048e525262fb25c5e994d0b21b4fa23a308be973bf4cb731e64ee300849700a7d70 SHA512 83600b3116a62200d6751b4c6a526cd0af842b943d8d2979e16803ad788ee826a52a25ac0736f337a8fa739affcba361e6cfd1947c5135aef963d128dcb7e3b9
DIST qmmp-1.3.7.tar.bz2 1250192 BLAKE2B bb94234beefbe44606d8db8cc95bd712b4c766d498c1de0549414b728fd9eb88e238bcffde9a3bd74e75adf106b6bf4fcb120547a83892c0bca8da17bf18f2ee SHA512 a67185fcdc7419c8542e64fd54eea3302dcf44c5d8d0c3b739ce3115b00811733234807460d39585ee57b7e105a52285ee3aafa9f24d86d2af09e881ebf2e068
+DIST qmmp-1.4.0.tar.bz2 1293438 BLAKE2B 9da3a00a31dd0ad03f3405dbae65f55d7b4fbde2a3a030d2cbe8d11ac9b5660754e519aff19431dada792f2ebb02e40fa05e177ad6bedc37e3aa5d7e2a441642 SHA512 b4ae764c223e1ce28477e86493ba409429e191ff51ef11d9b7c4fa356f90e5ff7e390bc8d1dcaf7779b231d59bf668d64000ea196b4020a7255eeb009706643d
diff --git a/media-sound/qmmp/qmmp-1.4.0.ebuild b/media-sound/qmmp/qmmp-1.4.0.ebuild
new file mode 100644
index 00000000000..4c02d12db02
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.4.0.ebuild
@@ -0,0 +1,164 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg-utils
+[[ ${PV} = 9999 ]] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+ SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2
+ mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
+ KEYWORDS="~amd64 ~x86"
+else
+ QMMP_DEV_BRANCH="1.3"
+ ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game
+gnome jack ladspa lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
+pulseaudio qsui qtmedia scrobbler shout sid sndfile soxr stereo tray udisks +vorbis wavpack"
+
+REQUIRED_USE="
+ gnome? ( dbus )
+ shout? ( soxr vorbis )
+ udisks? ( dbus )
+"
+
+RDEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtsql:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ media-libs/taglib
+ x11-libs/libX11
+ aac? ( media-libs/faad2 )
+ alsa? ( media-libs/alsa-lib )
+ archive? ( app-arch/libarchive )
+ bs2b? ( media-libs/libbs2b )
+ cdda? (
+ dev-libs/libcdio:=
+ dev-libs/libcdio-paranoia
+ )
+ curl? ( net-misc/curl )
+ dbus? ( dev-qt/qtdbus:5 )
+ enca? ( app-i18n/enca )
+ ffmpeg? ( media-video/ffmpeg:= )
+ flac? ( media-libs/flac )
+ game? ( media-libs/game-music-emu )
+ jack? (
+ media-libs/libsamplerate
+ media-sound/jack-audio-connection-kit
+ )
+ ladspa? ( media-libs/ladspa-cmt )
+ mad? ( || (
+ media-libs/libmad
+ media-sound/mpg123
+ ) )
+ midi? ( media-sound/wildmidi )
+ mms? ( media-libs/libmms )
+ modplug? ( >=media-libs/libmodplug-0.8.4 )
+ mplayer? ( media-video/mplayer )
+ musepack? ( >=media-sound/musepack-tools-444 )
+ opus? ( media-libs/opusfile )
+ projectm? (
+ dev-qt/qtgui:5[-gles2-only]
+ dev-qt/qtopengl:5
+ media-libs/libprojectm:=
+ )
+ pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+ qtmedia? ( dev-qt/qtmultimedia:5 )
+ scrobbler? ( net-misc/curl )
+ shout? ( media-libs/libshout )
+ sid? ( >=media-libs/libsidplayfp-1.1.0 )
+ sndfile? ( media-libs/libsndfile )
+ soxr? ( media-libs/soxr )
+ udisks? ( sys-fs/udisks:2 )
+ vorbis? (
+ media-libs/libogg
+ media-libs/libvorbis
+ )
+ wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+ dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+ if has_version dev-libs/libcdio-paranoia; then
+ sed -i \
+ -e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+ src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+ fi
+
+ cmake_src_prepare
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DUSE_AAC="$(usex aac)"
+ -DUSE_ALSA="$(usex alsa)"
+ -DUSE_ANALYZER="$(usex analyzer)"
+ -DUSE_ARCHIVE="$(usex archive)"
+ -DUSE_BS2B="$(usex bs2b)"
+ -DUSE_CDA="$(usex cdda)"
+ -DUSE_COVER="$(usex cover)"
+ -DUSE_CROSSFADE="$(usex crossfade)"
+ -DUSE_CUE="$(usex cue)"
+ -DUSE_CURL="$(usex curl)"
+ -DUSE_KDENOTIFY="$(usex dbus)"
+ -DUSE_MPRIS="$(usex dbus)"
+ -DUSE_ENCA="$(usex enca)"
+ -DUSE_FFMPEG="$(usex ffmpeg)"
+ -DUSE_FILEWRITER="$(usex vorbis)"
+ -DUSE_FLAC="$(usex flac)"
+ -DUSE_GME="$(usex game)"
+ -DUSE_GNOMEHOTKEY="$(usex gnome)"
+ -DUSE_HAL=OFF
+ -DUSE_JACK="$(usex jack)"
+ -DUSE_LADSPA="$(usex ladspa)"
+ -DUSE_LYRICS="$(usex lyrics)"
+ -DUSE_MAD="$(usex mad)"
+ -DUSE_MIDI="$(usex midi)"
+ -DUSE_MMS="$(usex mms)"
+ -DUSE_MODPLUG="$(usex modplug)"
+ -DUSE_MPLAYER="$(usex mplayer)"
+ -DUSE_MPC="$(usex musepack)"
+ -DUSE_NOTIFIER="$(usex notifier)"
+ -DUSE_OPUS="$(usex opus)"
+ -DUSE_OSS="$(usex oss)"
+ -DUSE_PROJECTM="$(usex projectm)"
+ -DUSE_PULSE="$(usex pulseaudio)"
+ -DUSE_QSUI="$(usex qsui)"
+ -DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+ -DUSE_SCROBBLER="$(usex scrobbler)"
+ -DUSE_SHOUT="$(usex shout)"
+ -DUSE_SID="$(usex sid)"
+ -DUSE_SNDFILE="$(usex sndfile)"
+ -DUSE_SOXR="$(usex soxr)"
+ -DUSE_STEREO="$(usex stereo)"
+ -DUSE_STATICON="$(usex tray)"
+ -DUSE_UDISKS2="$(usex udisks)"
+ -DUSE_VORBIS="$(usex vorbis)"
+ -DUSE_WAVPACK="$(usex wavpack)"
+ )
+
+ cmake_src_configure
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+}