media-video/yle-dl: 2020-06-28 release

 - upstream is dropping support for php backend.

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/media-video/yle-dl/yle-dl-20200628.ebuild b/media-video/yle-dl/yle-dl-20200628.ebuild
new file mode 100644
index 000000000000..645801818b99
--- /dev/null
+++ b/media-video/yle-dl/yle-dl-20200628.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Download media files from Yle Areena"
+HOMEPAGE="https://aajanki.github.io/yle-dl/ https://github.com/aajanki/yle-dl"
+SRC_URI="https://github.com/aajanki/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Requires an active internet connection during tests,
+# FEATURES="-network-sandbox" to test.
+RESTRICT="test"
+
+RDEPEND="${PYTHON_DEPS}
+	media-video/ffmpeg
+	net-misc/wget
+	>=dev-python/attrs-18.1.0[${PYTHON_USEDEP}]
+	>=dev-python/configargparse-0.13.0[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/mini-amf[${PYTHON_USEDEP}]
+	dev-python/progress[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]"
+DEPEND="test? (
+		${RDEPEND}
+		media-video/ffmpeg[gnutls]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+BDEPEND="${PYTHON_DEPS}"
+
+distutils_enable_tests setup.py
+
+DOCS=( COPYING ChangeLog README.fi README.md yledl.conf.sample )
+
+src_install() {
+	docompress -x "/usr/share/doc/${PF}/yledl.conf.sample"
+	distutils-r1_src_install
+}
+
+pkg_postinst() {
+	elog "Sample configuration file has been installed to "
+	elog " /usr/share/doc/yle-dl-${PV}/yledl.conf.sample"
+	elog ""
+	elog "Optional download engines: "
+	optfeature "youtube-dl download engine" net-misc/youtube-dl
+}