summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorYuri Konotopov <ykonotopov@gmail.com>2016-04-03 11:18:23 +0300
committerPatrice Clement <monsieurp@gentoo.org>2016-04-11 20:15:23 +0000
commitabb29c5d1934d87b942178eb464bdf2dc9c0700c (patch)
tree079f9dfad3a823b230c029470b1f19f04308c203 /net-dns/ddclient/ddclient-3.8.3.ebuild
parentmedia-libs/raspberrypi-userland: version bump (diff)
downloadgentoo-abb29c5d1934d87b942178eb464bdf2dc9c0700c.tar.gz
gentoo-abb29c5d1934d87b942178eb464bdf2dc9c0700c.tar.bz2
gentoo-abb29c5d1934d87b942178eb464bdf2dc9c0700c.zip
net-dns/ddclient-3.8.3: version bump
Gentoo-Bug: https://bugs.gentoo.org/558790 Closes: https://github.com/gentoo/gentoo/pull/1107 Signed-off-by: Patrice Clement <monsieurp@gentoo.org>
Diffstat (limited to 'net-dns/ddclient/ddclient-3.8.3.ebuild')
-rw-r--r--net-dns/ddclient/ddclient-3.8.3.ebuild50
1 files changed, 50 insertions, 0 deletions
diff --git a/net-dns/ddclient/ddclient-3.8.3.ebuild b/net-dns/ddclient/ddclient-3.8.3.ebuild
new file mode 100644
index 00000000000..d0c661197a5
--- /dev/null
+++ b/net-dns/ddclient/ddclient-3.8.3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+inherit systemd user
+
+DESCRIPTION="Perl updater client for dynamic DNS services"
+HOMEPAGE="http://ddclient.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~mips ~x86 ~x86-fbsd"
+IUSE="cloudflare hardened"
+
+RDEPEND=">=dev-lang/perl-5.1
+ virtual/perl-Digest-SHA
+ dev-perl/IO-Socket-SSL
+ cloudflare? ( dev-perl/JSON-Any )
+ hardened? ( sys-apps/iproute2 )
+"
+
+pkg_setup() {
+ enewgroup ${PN}
+ enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+ default
+
+ # Remove pid setting because we can't leave it user configurable and
+ # reliably setup the environment for the init script to stop ${PN}
+ ebegin "Removing PID setting from ${PN}.conf"
+ sed '/^pid/d' -i "sample-etc_${PN}.conf" || die
+ eend $?
+}
+
+src_install() {
+ dosbin ${PN}
+ dodoc Change* COPYRIGHT README* RELEASENOTE sample*
+
+ newinitd "${FILESDIR}/${PN}.initd-r4" ${PN}
+ systemd_dounit "${FILESDIR}"/${PN}.service
+
+ insopts -m 0600 -o ${PN} -g ${PN}
+ insinto /etc/${PN}
+ newins sample-etc_${PN}.conf ${PN}.conf
+ newins sample-etc_${PN}.conf ${PN}.conf.sample
+}