summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAnthony G. Basile <blueness@gentoo.org>2019-03-27 14:52:40 -0400
committerAnthony G. Basile <blueness@gentoo.org>2019-03-27 14:52:51 -0400
commite0295f9ff9104d4ea968a8ad4618c961c195a348 (patch)
tree2119fe79bac1bb1c59ab69f8981f3a5f7937f84d /net-libs/mbedtls
parentdev-libs/iniparser: add myself as (co-)maintainer (diff)
downloadgentoo-e0295f9ff9104d4ea968a8ad4618c961c195a348.tar.gz
gentoo-e0295f9ff9104d4ea968a8ad4618c961c195a348.tar.bz2
gentoo-e0295f9ff9104d4ea968a8ad4618c961c195a348.zip
net-libs/mbedtls: version bump to 2.16.1 and 2.17.0
Signed-off-by: Anthony G. Basile <blueness@gentoo.org> Package-Manager: Portage-2.3.62, Repoman-2.3.11
Diffstat (limited to 'net-libs/mbedtls')
-rw-r--r--net-libs/mbedtls/Manifest2
-rw-r--r--net-libs/mbedtls/mbedtls-2.16.1.ebuild93
-rw-r--r--net-libs/mbedtls/mbedtls-2.17.0.ebuild93
3 files changed, 188 insertions, 0 deletions
diff --git a/net-libs/mbedtls/Manifest b/net-libs/mbedtls/Manifest
index 5940b631d19..969d6c47668 100644
--- a/net-libs/mbedtls/Manifest
+++ b/net-libs/mbedtls/Manifest
@@ -4,3 +4,5 @@ DIST mbedtls-2.13.1.tar.gz 2345612 BLAKE2B 0b78a04407076016fb7f74b635cd2fc86119a
DIST mbedtls-2.14.1.tar.gz 2374523 BLAKE2B bab8e2a6b988627ae634aa26d6bf778ee1b923c9e2b17b2fd62c889120ab0dd5a9362ce6c0b8817c97dc1bbcda892b3a9ea7113c73240345e6e7bc4470a047aa SHA512 e8c953f4335a0cbdf4e713b646fcc1ee5302953b4279c6f21c15a6a8216d805d113354c1448c8df3617dbdfcd4e8a82157cd5630c37662d0db6b02865d4bd8e0
DIST mbedtls-2.15.1.tar.gz 2662140 BLAKE2B 9b1f3f6e522445c187ebfe38a35bb934d72d638d1b0fa59852c7e0b1c1094302efd4328038a2e0c8427b2d08d791179d0b33ffd20e7809cd4ac9dac1b480866b SHA512 361bac49bc179c020855a59140a3e9e31ec9e89ebde9d630e9f3491cdfdf466c8dc2313276d6b257a7728784f5478bdcfd14d26e81f90d432bad2e9a94151fc2
DIST mbedtls-2.16.0.tar.gz 2412091 BLAKE2B 7fae9fa1ffa8ae7e7958af6fbac98299135e5b7c524ad3944f0ae7b5aa7f2574253950583a77bd1b9fa175b513032110565406b5d4a85c56c65c5c2e50e87928 SHA512 15e8df96c16b0b6f7b100ca76d85dae77f8e6a6644fc41262dc28e11440b9238e837193991ba5942864ed9f58542f96967c2d1e18a5ae270571f6d364bcc33b1
+DIST mbedtls-2.16.1.tar.gz 2426992 BLAKE2B 11915bc2feb27b16ad20c3079905081093dad100bba02b06ccf30ce708d3528445bc153ed81e6e11e7c8d15060a47bf6419252f934bd6950fe3a7867e0da6aa2 SHA512 d9333abd463350bfeceec4edd605e93326578ca646053b0c6f6c51567237273fa88f602b065706fdd699a2a06e667cc54ca3919bb71b2c4656fbc620b967bc01
+DIST mbedtls-2.17.0.tar.gz 2738368 BLAKE2B efcf2a6c84a85afdca0205bd9e8bcf039074c5e6f40e0814f835cf26c2d13dce87bd140aa0b803eea6a683e31b79680a3ea8ba72417e7ec26f206e0b027b014a SHA512 6ab52d116cb9f755871f2fd196ec1b352dbbe59f2ecedeb5551237e4e672da77205ef0c2f80ec746ba1fd94cab1995ab1729c8adb0f29d10f3c74a67f5327493
diff --git a/net-libs/mbedtls/mbedtls-2.16.1.ebuild b/net-libs/mbedtls/mbedtls-2.16.1.ebuild
new file mode 100644
index 00000000000..a5b2310cf89
--- /dev/null
+++ b/net-libs/mbedtls/mbedtls-2.16.1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils multilib-minimal
+
+DESCRIPTION="Cryptographic library for embedded systems"
+HOMEPAGE="https://tls.mbed.org/"
+SRC_URI="https://github.com/ARMmbed/mbedtls/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="Apache-2.0"
+SLOT="0/12" # slot for libmbedtls.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="cpu_flags_x86_sse2 doc havege libressl programs -static-libs test threads zlib"
+
+RDEPEND="
+ programs? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ )
+ zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+ doc? ( app-doc/doxygen media-gfx/graphviz )
+ test? ( dev-lang/perl )"
+
+enable_mbedtls_option() {
+ local myopt="$@"
+ # check that config.h syntax is the same at version bump
+ sed -i \
+ -e "s://#define ${myopt}:#define ${myopt}:" \
+ include/mbedtls/config.h || die
+}
+
+src_prepare() {
+ use cpu_flags_x86_sse2 && enable_mbedtls_option MBEDTLS_HAVE_SSE2
+ use zlib && enable_mbedtls_option MBEDTLS_ZLIB_SUPPORT
+ use havege && enable_mbedtls_option MBEDTLS_HAVEGE_C
+ use threads && enable_mbedtls_option MBEDTLS_THREADING_C
+ use threads && enable_mbedtls_option MBEDTLS_THREADING_PTHREAD
+
+ cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+ local mycmakeargs=(
+ -DENABLE_PROGRAMS=$(multilib_native_usex programs)
+ -DENABLE_ZLIB_SUPPORT=$(usex zlib)
+ -DUSE_STATIC_MBEDTLS_LIBRARY=$(usex static-libs)
+ -DENABLE_TESTING=$(usex test)
+ -DUSE_SHARED_MBEDTLS_LIBRARY=ON
+ -DINSTALL_MBEDTLS_HEADERS=ON
+ -DLIB_INSTALL_DIR="/usr/$(get_libdir)"
+ )
+
+ cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+ cmake-utils_src_compile
+ use doc && multilib_is_native_abi && emake apidoc
+}
+
+multilib_src_test() {
+ LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
+ cmake-utils_src_test
+}
+
+multilib_src_install() {
+ cmake-utils_src_install
+}
+
+multilib_src_install_all() {
+ use doc && HTML_DOCS=( apidoc )
+
+ einstalldocs
+
+ if use programs ; then
+ # avoid file collisions with sys-apps/coreutils
+ local p e
+ for p in "${ED%/}"/usr/bin/* ; do
+ if [[ -x "${p}" && ! -d "${p}" ]] ; then
+ mv "${p}" "${ED%/}"/usr/bin/mbedtls_${p##*/} || die
+ fi
+ done
+ for e in aes hash pkey ssl test ; do
+ docinto "${e}"
+ dodoc programs/"${e}"/*.c
+ dodoc programs/"${e}"/*.txt
+ done
+ fi
+}
diff --git a/net-libs/mbedtls/mbedtls-2.17.0.ebuild b/net-libs/mbedtls/mbedtls-2.17.0.ebuild
new file mode 100644
index 00000000000..a5b2310cf89
--- /dev/null
+++ b/net-libs/mbedtls/mbedtls-2.17.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils multilib-minimal
+
+DESCRIPTION="Cryptographic library for embedded systems"
+HOMEPAGE="https://tls.mbed.org/"
+SRC_URI="https://github.com/ARMmbed/mbedtls/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="Apache-2.0"
+SLOT="0/12" # slot for libmbedtls.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="cpu_flags_x86_sse2 doc havege libressl programs -static-libs test threads zlib"
+
+RDEPEND="
+ programs? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ )
+ zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+ doc? ( app-doc/doxygen media-gfx/graphviz )
+ test? ( dev-lang/perl )"
+
+enable_mbedtls_option() {
+ local myopt="$@"
+ # check that config.h syntax is the same at version bump
+ sed -i \
+ -e "s://#define ${myopt}:#define ${myopt}:" \
+ include/mbedtls/config.h || die
+}
+
+src_prepare() {
+ use cpu_flags_x86_sse2 && enable_mbedtls_option MBEDTLS_HAVE_SSE2
+ use zlib && enable_mbedtls_option MBEDTLS_ZLIB_SUPPORT
+ use havege && enable_mbedtls_option MBEDTLS_HAVEGE_C
+ use threads && enable_mbedtls_option MBEDTLS_THREADING_C
+ use threads && enable_mbedtls_option MBEDTLS_THREADING_PTHREAD
+
+ cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+ local mycmakeargs=(
+ -DENABLE_PROGRAMS=$(multilib_native_usex programs)
+ -DENABLE_ZLIB_SUPPORT=$(usex zlib)
+ -DUSE_STATIC_MBEDTLS_LIBRARY=$(usex static-libs)
+ -DENABLE_TESTING=$(usex test)
+ -DUSE_SHARED_MBEDTLS_LIBRARY=ON
+ -DINSTALL_MBEDTLS_HEADERS=ON
+ -DLIB_INSTALL_DIR="/usr/$(get_libdir)"
+ )
+
+ cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+ cmake-utils_src_compile
+ use doc && multilib_is_native_abi && emake apidoc
+}
+
+multilib_src_test() {
+ LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
+ cmake-utils_src_test
+}
+
+multilib_src_install() {
+ cmake-utils_src_install
+}
+
+multilib_src_install_all() {
+ use doc && HTML_DOCS=( apidoc )
+
+ einstalldocs
+
+ if use programs ; then
+ # avoid file collisions with sys-apps/coreutils
+ local p e
+ for p in "${ED%/}"/usr/bin/* ; do
+ if [[ -x "${p}" && ! -d "${p}" ]] ; then
+ mv "${p}" "${ED%/}"/usr/bin/mbedtls_${p##*/} || die
+ fi
+ done
+ for e in aes hash pkey ssl test ; do
+ docinto "${e}"
+ dodoc programs/"${e}"/*.c
+ dodoc programs/"${e}"/*.txt
+ done
+ fi
+}