summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorDavid Seifert <soap@gentoo.org>2020-01-26 19:52:19 +0100
committerDavid Seifert <soap@gentoo.org>2020-01-26 19:52:19 +0100
commit8601fc63efe7f29b96fa6ce9545e994f6f1eba36 (patch)
treec0483fd25b5e0fbf2f133e3f0b7f9fbc593b2ed9 /sci-electronics/gerbv/gerbv-2.7.0.ebuild
parentdev-lua/lutok: update copyright start year (diff)
downloadgentoo-8601fc63efe7f29b96fa6ce9545e994f6f1eba36.tar.gz
gentoo-8601fc63efe7f29b96fa6ce9545e994f6f1eba36.tar.bz2
gentoo-8601fc63efe7f29b96fa6ce9545e994f6f1eba36.zip
sci-electronics/gerbv: Bump to 2.7.0
Bug: https://bugs.gentoo.org/686716 Package-Manager: Portage-2.3.85, Repoman-2.3.20 Signed-off-by: David Seifert <soap@gentoo.org>
Diffstat (limited to 'sci-electronics/gerbv/gerbv-2.7.0.ebuild')
-rw-r--r--sci-electronics/gerbv/gerbv-2.7.0.ebuild51
1 files changed, 51 insertions, 0 deletions
diff --git a/sci-electronics/gerbv/gerbv-2.7.0.ebuild b/sci-electronics/gerbv/gerbv-2.7.0.ebuild
new file mode 100644
index 00000000000..48379be8625
--- /dev/null
+++ b/sci-electronics/gerbv/gerbv-2.7.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools xdg
+
+DESCRIPTION="A RS-274X (Gerber) and NC drill (Excellon) file viewer"
+HOMEPAGE="http://gerbv.geda-project.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc examples unit-mm"
+RESTRICT="test"
+
+RDEPEND="
+ x11-libs/gtk+:2
+ x11-libs/cairo"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.7.0-fno-common-gcc10.patch )
+
+src_configure() {
+ econf \
+ --disable-static \
+ --disable-update-desktop-database \
+ $(use_enable unit-mm)
+}
+
+src_install() {
+ rm README-{git,release,win32}.txt || die
+ default
+ dodoc CONTRIBUTORS HACKING
+
+ rm doc/Doxyfile.nopreprocessing || die
+ if use doc; then
+ find doc -name 'Makefile*' -delete || die
+ dodoc -r doc/.
+ fi
+
+ if use examples; then
+ find example -name 'Makefile*' -delete || die
+ dodoc -r example/.
+ fi
+
+ # no static archives
+ find "${D}" -name '*.la' -delete || die
+}