summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2018-11-28 10:34:58 +0100
committerLars Wendler <polynomial-c@gentoo.org>2018-11-28 10:35:47 +0100
commit02718c49ad240bfbc2e35252798210c4c949e504 (patch)
tree520eafb661106da9fbef3327d19943bb65189875 /sys-apps/fwupd
parentdev-libs/libxmlb: Bump to version 0.1.5 (diff)
downloadgentoo-02718c49ad240bfbc2e35252798210c4c949e504.tar.gz
gentoo-02718c49ad240bfbc2e35252798210c4c949e504.tar.bz2
gentoo-02718c49ad240bfbc2e35252798210c4c949e504.zip
sys-apps/fwupd: Bump to version 1.2.1
Package-Manager: Portage-2.3.52, Repoman-2.3.12 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Diffstat (limited to 'sys-apps/fwupd')
-rw-r--r--sys-apps/fwupd/Manifest1
-rw-r--r--sys-apps/fwupd/fwupd-1.2.1.ebuild124
2 files changed, 125 insertions, 0 deletions
diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index eff9798f8f59..5f7d7e1dc366 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,3 +1,4 @@
DIST fwupd-1.1.3.tar.gz 1731079 BLAKE2B 7de39c00d96b9bed29e7ee04c46f71ed033c53e2b132bfd220b932217ab3bb5c6b0bc24adc594cf2f27c483e22e7366aa90172db93757fcb48894b9573269bca SHA512 7f0899cfeb5119c35d7eacdafdc3367de1d2da29942d0099983a05f633ae95a28e16c00b46ad405f1ac60e679cf6bd5dcad2869c2bd48f936ea2c29a3c235c27
DIST fwupd-1.1.4.tar.gz 1729782 BLAKE2B af8a1046d6ab9098ee7b09bc1c9677b2256909fdb6cef3e1632e920f962246b94ae7b8c8c4cb5c90088845d836c27cb98c7b8c05bad8f6a213029c220856e602 SHA512 7c14efd044f575c600ee4734c6721b8990603296a8ef2ec7643691e1b47598c12afd31e0c25a0dae69719e2c375fc1f18a6073f20b3c1b91400a046de52e8a28
DIST fwupd-1.2.0.tar.gz 1746711 BLAKE2B 7611f0d501f897392cba0f6ca877265c634d723b9804e640b7824b35773c16117e574dd7eb336c626de6dcd7360112acac2aa5da828c28aff7954b0935bec60d SHA512 88e543cb06522b4af2d62addea77ab0d2a119409e0c36c5034bc4c035c73fdfd8565723a3993f04510491645174064d0bb9b2937553ced8528f29257d9a902e9
+DIST fwupd-1.2.1.tar.gz 1754253 BLAKE2B 96938766758db32b00437e29c1b93870411687f7535102703faf4a09189dc4e90fd232794812d964895c12b0f63c86d0023ff1abcf9848059f04c12812158db9 SHA512 ce86c7b5e5c1a45a561f6fc195c3db861e29f9cd435df9e41a41ade94e2f9891508b0e32906df09fe074d383b5d7b6ac824201949f67e2c86c6c905eae550d78
diff --git a/sys-apps/fwupd/fwupd-1.2.1.ebuild b/sys-apps/fwupd/fwupd-1.2.1.ebuild
new file mode 100644
index 000000000000..7f9b147acd16
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.2.1.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+
+inherit meson python-single-r1 vala xdg-utils
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="colorhug dell doc +gpg +man nvme pkcs7 redfish systemd test thunderbolt uefi"
+REQUIRED_USE="
+ ${PYTHON_REQUIRED_USE}
+ dell? ( uefi )
+"
+
+RDEPEND="
+ ${PYTHON_DEPS}
+ app-arch/gcab
+ app-arch/libarchive:=
+ dev-db/sqlite
+ >=dev-libs/glib-2.45.8:2
+ dev-libs/json-glib
+ dev-libs/libgpg-error
+ dev-libs/libgudev:=
+ >=dev-libs/libgusb-0.2.9[introspection]
+ >=dev-libs/libxmlb-0.1.5
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+ >=net-libs/libsoup-2.51.92:2.4[introspection]
+ >=sys-auth/polkit-0.103
+ virtual/libelf:0=
+ colorhug? ( >=x11-misc/colord-1.2.12:0= )
+ dell? (
+ sys-libs/efivar
+ >=sys-libs/libsmbios-2.4.0
+ )
+ gpg? (
+ app-crypt/gpgme
+ dev-libs/libgpg-error
+ )
+ nvme? ( sys-libs/efivar )
+ pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
+ redfish? (
+ sys-libs/efivar
+ )
+ systemd? ( >=sys-apps/systemd-211 )
+ !systemd? ( >=sys-auth/consolekit-1.0.0 )
+ thunderbolt? ( sys-apps/thunderbolt-software-user-space )
+ uefi? (
+ media-libs/fontconfig
+ media-libs/freetype
+ sys-boot/gnu-efi
+ >=sys-libs/efivar-33
+ x11-libs/cairo
+ )
+"
+DEPEND="
+ ${RDEPEND}
+ $(vala_depend)
+ doc? ( dev-util/gtk-doc )
+ man? ( app-text/docbook-sgml-utils )
+ nvme? ( >=sys-kernel/linux-headers-4.4 )
+ test? ( net-libs/gnutls[tools] )
+"
+
+BDEPEND="
+ >=dev-util/meson-0.47.0
+ virtual/pkgconfig
+"
+
+# required for fwupd daemon to run.
+# NOT a build time dependency. The build system does not check for dbus.
+PDEPEND="sys-apps/dbus"
+
+src_prepare() {
+ default
+ sed -e "s/'--create'/'--absolute-name', '--create'/" \
+ -i data/tests/builder/meson.build || die
+ sed -e "/'-Werror',/d" \
+ -i plugins/uefi/efi/meson.build || die
+ vala_src_prepare
+}
+
+src_configure() {
+ xdg_environment_reset
+ local emesonargs=(
+ --localstatedir "${EPREFIX}"/var
+ -Dconsolekit="$(usex systemd false true)"
+ -Dgpg="$(usex gpg true false)"
+ -Dgtkdoc="$(usex doc true false)"
+ -Dman="$(usex man true false)"
+ -Dpkcs7="$(usex pkcs7 true false)"
+ -Dplugin_dell="$(usex dell true false)"
+ -Dplugin_nvme="$(usex nvme true false)"
+ -Dplugin_redfish="$(usex redfish true false)"
+ -Dplugin_synaptics="$(usex dell true false)"
+ -Dplugin_thunderbolt="$(usex thunderbolt true false)"
+ -Dplugin_uefi="$(usex uefi true false)"
+ -Dsystemd="$(usex systemd true false)"
+ -Dtests="$(usex test true false)"
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ doinitd "${FILESDIR}"/${PN}
+}
+
+pkg_postinst() {
+ elog "In case you are using openrc as init system"
+ elog "and you're upgrading from <fwupd-1.1.0, you"
+ elog "need to start the fwupd daemon via the openrc"
+ elog "init script that comes with this package."
+}