summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2018-10-15 12:26:59 +0200
committerLars Wendler <polynomial-c@gentoo.org>2018-10-15 12:28:32 +0200
commitf6da1fde23d402e40089345f4f0f17bee48da34f (patch)
tree9ce1d898c0007b968a72d907ba5e6d164dcbbd85 /sys-apps
parentkde-apps/kmail: Fix src_prepare (diff)
downloadgentoo-f6da1fde23d402e40089345f4f0f17bee48da34f.tar.gz
gentoo-f6da1fde23d402e40089345f4f0f17bee48da34f.tar.bz2
gentoo-f6da1fde23d402e40089345f4f0f17bee48da34f.zip
sys-apps/fwupd: Bump to version 1.1.3
Added python-3.7 support. Closes: https://bugs.gentoo.org/668704 Closes: https://bugs.gentoo.org/661622 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org> Package-Manager: Portage-2.3.51, Repoman-2.3.11
Diffstat (limited to 'sys-apps')
-rw-r--r--sys-apps/fwupd/Manifest1
-rw-r--r--sys-apps/fwupd/fwupd-1.1.3.ebuild125
2 files changed, 126 insertions, 0 deletions
diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 699d78da29c..99cdcea0d81 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,2 +1,3 @@
DIST fwupd-1.1.1.tar.gz 1669430 BLAKE2B 92073f1e3b6c6b68da48de792d58d218c0b0bfce2a3765c257253d6fb93974dccadc2ae71ab6275d0e9ad6775642eba1e2613ad2a3f11cd4d4225affdedc7561 SHA512 b825b565b6c85bbf703352eb0aff40de8e348c96537316373de718faf82bbdd425ba1b8091d1ab4b5403f2fbe46ceda45a502a5fea4ad3bd51e6cc5a2aad6ddc
DIST fwupd-1.1.2.tar.gz 1690384 BLAKE2B 988c27dbc522b27f03c94072aa85930f77d5b115aea93e485e9da853cea4f37a44aa6f8af542b24e5cd2f1ba65f4ede52e2f15dc2a366d2fa27370d8bda76164 SHA512 f9ca8d34608ee7b7fd2047c9897a898a8680da096db2fb123e698c9b5443d4285d91d67aa1fb928f3c653e9a6d3646a0228a0a630f9262b80e47525591b5659e
+DIST fwupd-1.1.3.tar.gz 1731079 BLAKE2B 7de39c00d96b9bed29e7ee04c46f71ed033c53e2b132bfd220b932217ab3bb5c6b0bc24adc594cf2f27c483e22e7366aa90172db93757fcb48894b9573269bca SHA512 7f0899cfeb5119c35d7eacdafdc3367de1d2da29942d0099983a05f633ae95a28e16c00b46ad405f1ac60e679cf6bd5dcad2869c2bd48f936ea2c29a3c235c27
diff --git a/sys-apps/fwupd/fwupd-1.1.3.ebuild b/sys-apps/fwupd/fwupd-1.1.3.ebuild
new file mode 100644
index 00000000000..50ed19c9932
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.1.3.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# Package requires newer meson than eclass provides
+MESON_AUTO_DEPEND="no"
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+
+inherit meson python-single-r1 vala xdg-utils
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="colorhug dell doc +gpg +man nvme pkcs7 redfish systemd test thunderbolt uefi"
+REQUIRED_USE="
+ ${PYTHON_REQUIRED_USE}
+ dell? ( uefi )
+"
+
+RDEPEND="
+ ${PYTHON_DEPS}
+ app-arch/libarchive:=
+ dev-db/sqlite
+ >=dev-libs/appstream-glib-0.7.4:=[introspection]
+ >=dev-libs/glib-2.45.8:2
+ dev-libs/libgpg-error
+ dev-libs/libgudev:=
+ >=dev-libs/libgusb-0.2.9[introspection]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+ >=net-libs/libsoup-2.51.92:2.4[introspection]
+ >=sys-auth/polkit-0.103
+ virtual/libelf:0=
+ colorhug? ( >=x11-misc/colord-1.2.12:0= )
+ dell? (
+ sys-libs/efivar
+ >=sys-libs/libsmbios-2.4.0
+ )
+ gpg? (
+ app-crypt/gpgme
+ dev-libs/libgpg-error
+ )
+ nvme? ( sys-libs/efivar )
+ pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
+ redfish? (
+ dev-libs/json-glib
+ sys-libs/efivar
+ )
+ systemd? ( >=sys-apps/systemd-211 )
+ !systemd? ( >=sys-auth/consolekit-1.0.0 )
+ thunderbolt? ( sys-apps/thunderbolt-software-user-space )
+ uefi? (
+ media-libs/fontconfig
+ media-libs/freetype
+ sys-boot/gnu-efi
+ >=sys-libs/efivar-33
+ x11-libs/cairo
+ )
+"
+DEPEND="
+ ${RDEPEND}
+ app-arch/gcab
+ app-arch/libarchive
+ >=dev-util/meson-0.41.0
+ >=dev-util/ninja-1.7.2
+ virtual/pkgconfig
+ $(vala_depend)
+ doc? ( dev-util/gtk-doc )
+ man? ( app-text/docbook-sgml-utils )
+ nvme? ( >=sys-kernel/linux-headers-4.4 )
+ test? ( net-libs/gnutls[tools] )
+"
+
+# required for fwupd daemon to run.
+# NOT a build time dependency. The build system does not check for dbus.
+PDEPEND="sys-apps/dbus"
+
+src_prepare() {
+ default
+ sed -e "s/'--create'/'--absolute-name', '--create'/" \
+ -i data/tests/builder/meson.build || die
+ sed -e "/'-Werror',/d" \
+ -i plugins/uefi/efi/meson.build || die
+ vala_src_prepare
+}
+
+src_configure() {
+ xdg_environment_reset
+ local emesonargs=(
+ --localstatedir "${EPREFIX}"/var
+ -Dconsolekit="$(usex systemd false true)"
+ -Dgpg="$(usex gpg true false)"
+ -Dgtkdoc="$(usex doc true false)"
+ -Dman="$(usex man true false)"
+ -Dpkcs7="$(usex pkcs7 true false)"
+ -Dplugin_dell="$(usex dell true false)"
+ -Dplugin_nvme="$(usex nvme true false)"
+ -Dplugin_redfish="$(usex redfish true false)"
+ -Dplugin_synaptics="$(usex dell true false)"
+ -Dplugin_thunderbolt="$(usex thunderbolt true false)"
+ -Dplugin_uefi="$(usex uefi true false)"
+ -Dsystemd="$(usex systemd true false)"
+ -Dtests="$(usex test true false)"
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ doinitd "${FILESDIR}"/${PN}
+}
+
+pkg_postinst() {
+ elog "In case you are using openrc as init system"
+ elog "and you're upgrading from <fwupd-1.1.0, you"
+ elog "need to start the fwupd daemon via the openrc"
+ elog "init script that comes with this package."
+}