summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMike Frysinger <vapier@gentoo.org>2015-12-16 17:49:26 -0500
committerMike Frysinger <vapier@gentoo.org>2015-12-16 17:52:38 -0500
commit397ebbd25aa13b7e2e54b247c230d4e7c29acfdf (patch)
tree7bd3acec693e7caf58d1c0a8246083bb72fc421d /sys-devel/automake/automake-1.10.3-r2.ebuild
parentsys-devel/automake-wrapper: drop versions <10 (diff)
downloadgentoo-397ebbd25aa13b7e2e54b247c230d4e7c29acfdf.tar.gz
gentoo-397ebbd25aa13b7e2e54b247c230d4e7c29acfdf.tar.bz2
gentoo-397ebbd25aa13b7e2e54b247c230d4e7c29acfdf.zip
sys-devel/automake: fix version warning w/newer perl
Diffstat (limited to 'sys-devel/automake/automake-1.10.3-r2.ebuild')
-rw-r--r--sys-devel/automake/automake-1.10.3-r2.ebuild83
1 files changed, 83 insertions, 0 deletions
diff --git a/sys-devel/automake/automake-1.10.3-r2.ebuild b/sys-devel/automake/automake-1.10.3-r2.ebuild
new file mode 100644
index 00000000000..de41a4fa3bb
--- /dev/null
+++ b/sys-devel/automake/automake-1.10.3-r2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+inherit eutils
+
+DESCRIPTION="Used to generate Makefile.in from Makefile.am"
+HOMEPAGE="https://www.gnu.org/software/automake/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+# Use Gentoo versioning for slotting.
+SLOT="${PV:0:4}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+RDEPEND="dev-lang/perl
+ >=sys-devel/automake-wrapper-10
+ >=sys-devel/autoconf-2.69
+ sys-devel/gnuconfig"
+DEPEND="${RDEPEND}
+ sys-apps/help2man"
+
+src_prepare() {
+ export WANT_AUTOCONF=2.5
+ epatch "${FILESDIR}"/${PN}-1.10-perl-5.16.patch #424453
+ epatch "${FILESDIR}"/${PN}-1.13-perl-escape-curly-bracket.patch
+ chmod a+rx tests/*.test
+}
+
+src_configure() {
+ econf --docdir=/usr/share/doc/${PF}
+}
+
+# slot the info pages. do this w/out munging the source so we don't have
+# to depend on texinfo to regen things. #464146 (among others)
+slot_info_pages() {
+ pushd "${D}"/usr/share/info >/dev/null
+ rm -f dir
+
+ # Rewrite all the references to other pages.
+ # before: * aclocal-invocation: (automake)aclocal Invocation. Generating aclocal.m4.
+ # after: * aclocal-invocation v1.13: (automake-1.13)aclocal Invocation. Generating aclocal.m4.
+ local p pages=( *.info ) args=()
+ for p in "${pages[@]/%.info}" ; do
+ args+=(
+ -e "/START-INFO-DIR-ENTRY/,/END-INFO-DIR-ENTRY/s|: (${p})| v${SLOT}&|"
+ -e "s:(${p}):(${p}-${SLOT}):g"
+ )
+ done
+ sed -i "${args[@]}" * || die
+
+ # Rewrite all the file references, and rename them in the process.
+ local f d
+ for f in * ; do
+ d=${f/.info/-${SLOT}.info}
+ mv "${f}" "${d}" || die
+ sed -i -e "s:${f}:${d}:g" * || die
+ done
+
+ popd >/dev/null
+}
+
+src_install() {
+ default
+ slot_info_pages
+
+ # SLOT the docs and junk
+ local x
+ for x in aclocal automake ; do
+ help2man "perl -Ilib ${x}" > ${x}-${SLOT}.1
+ doman ${x}-${SLOT}.1
+ rm -f "${D}"/usr/bin/${x}
+ done
+
+ # remove all config.guess and config.sub files replacing them
+ # w/a symlink to a specific gnuconfig version
+ for x in guess sub ; do
+ dosym ../gnuconfig/config.${x} /usr/share/${PN}-${SLOT}/config.${x}
+ done
+}