summaryrefslogtreecommitdiff
path: root/sys-fs
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2020-01-10 12:17:16 +0100
committerLars Wendler <polynomial-c@gentoo.org>2020-01-10 12:17:16 +0100
commita1bbd3dca502151895d86ca2f56ac01c8ef6cc8c (patch)
tree9438b0874d88b2bdc039dc8a4078ddbef42b90d9 /sys-fs
parentkde-misc/tellico: Drop unused patch (diff)
downloadgentoo-a1bbd3dca502151895d86ca2f56ac01c8ef6cc8c.tar.gz
gentoo-a1bbd3dca502151895d86ca2f56ac01c8ef6cc8c.tar.bz2
gentoo-a1bbd3dca502151895d86ca2f56ac01c8ef6cc8c.zip
sys-fs/btrfs-progs: Bump to version 5.4.1
Package-Manager: Portage-2.3.84, Repoman-2.3.20 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Diffstat (limited to 'sys-fs')
-rw-r--r--sys-fs/btrfs-progs/Manifest1
-rw-r--r--sys-fs/btrfs-progs/btrfs-progs-5.4.1.ebuild125
2 files changed, 126 insertions, 0 deletions
diff --git a/sys-fs/btrfs-progs/Manifest b/sys-fs/btrfs-progs/Manifest
index fcc95e64109..76748c4d689 100644
--- a/sys-fs/btrfs-progs/Manifest
+++ b/sys-fs/btrfs-progs/Manifest
@@ -1,4 +1,5 @@
DIST btrfs-progs-v4.19.tar.xz 2001340 BLAKE2B 117087adcb57e4ebf6a2e9c66bf0ad2b098108f7363fc3c015d73bf9afcda9d579831fe0e324125893cdb2510873d052522b15843c461e640a546900e535ce76 SHA512 e5abf637a9c811973422ca05a5530f6cd18263013d141277e2a70099cf8ab7e0eb8781df56368da4321c90f21d1022ad852b661adc4877e9a9ba5c60ccbefdee
DIST btrfs-progs-v4.4.1.tar.xz 1173248 BLAKE2B 8bf07a3bc3d24a3f641c2dc7a6353f186ebd98f7a633bdbc2689359e6204b3f1db76accee3e648634f319e26b57e6376c13fa31d39413908d0b2308e0ae28d0e SHA512 3086e2e0385d9e14edcfa25e1aee1ed98087dd5b91a66aa450786c932d79841b5c4ee3f9a40b8fdecee0ba1e386196b89679d28e58e4924ce66cd78c5e3c0d4a
DIST btrfs-progs-v5.3.1.tar.xz 2077644 BLAKE2B f2943fd2215cfc65095e361824deb862c1934bb734c0f3073d8d0a7cb40c606e9e8054e36ae467f6d67f3ed58120493b9515f6a1d0d1062f864dd44521d1bab1 SHA512 7e7ac18a1ced5a8e5db7c0651ac438a48242fb4ca045b944527ed07ac91e87397dbab62b99d67d782501a632f4178db605e81912dfa48ac831d07177f96876fa
+DIST btrfs-progs-v5.4.1.tar.xz 2107476 BLAKE2B 1ea58f49b0f8185e944010804e544643a2eafeea58fecb480b13095c362350c218f0602fbb43a96705a81befe88ec3e3abe35cc90d4732006479b059aa7fed32 SHA512 56381b37036aecea61b758fb4971abfeda24a387bb3a828f7d54eb068982a37763a8ebe2bcc6be61d6a8bc2057dddcd4754325b236e14d8ec02e58cf711f192f
DIST btrfs-progs-v5.4.tar.xz 2103432 BLAKE2B 8ed1321c61d73b66bd27b37a255056e601302dacdcf2dd3122d1b7c41e537ebd1aa5df51100e61458084ec15efd6a1aa478d13f424d45d33d7454d886214a994 SHA512 cc445b9e2b7c5a0adeaa0c467de797f240e4ee9b58c6ac51b9dad51bc0ba0c580fd265efebc04fa46dc23e5b3c4d6baf3ad0b8e2e82728cf34ef51973f028a90
diff --git a/sys-fs/btrfs-progs/btrfs-progs-5.4.1.ebuild b/sys-fs/btrfs-progs/btrfs-progs-5.4.1.ebuild
new file mode 100644
index 00000000000..43710cbc333
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-5.4.1.ebuild
@@ -0,0 +1,125 @@
+# Copyright 2008-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit bash-completion-r1 python-single-r1
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+ MY_PV="v${PV/_/-}"
+ [[ "${PV}" = *_rc* ]] || \
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+ SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz"
+ S="${WORKDIR}/${PN}-${MY_PV}"
+else
+ WANT_LIBTOOL=none
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git"
+ EGIT_BRANCH="devel"
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org"
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE="+convert doc python reiserfs static static-libs +zstd"
+
+RESTRICT=test # tries to mount repared filesystems
+
+RDEPEND="
+ dev-libs/lzo:2=
+ sys-apps/util-linux:0=[static-libs(+)?]
+ sys-libs/zlib:0=
+ convert? (
+ sys-fs/e2fsprogs:0=
+ sys-libs/e2fsprogs-libs:0=
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27
+ )
+ )
+ python? ( ${PYTHON_DEPS} )
+ zstd? ( app-arch/zstd:0= )
+"
+DEPEND="${RDEPEND}
+ convert? ( sys-apps/acl )
+ python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
+ static? (
+ dev-libs/lzo:2[static-libs(+)]
+ sys-apps/util-linux:0[static-libs(+)]
+ sys-libs/zlib:0[static-libs(+)]
+ convert? (
+ sys-fs/e2fsprogs:0[static-libs(+)]
+ sys-libs/e2fsprogs-libs:0[static-libs(+)]
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27[static-libs(+)]
+ )
+ )
+ zstd? ( app-arch/zstd:0[static-libs(+)] )
+ )
+"
+BDEPEND="
+ doc? (
+ || ( >=app-text/asciidoc-8.6.0 dev-ruby/asciidoctor )
+ app-text/docbook-xml-dtd:4.5
+ app-text/xmlto
+ )
+"
+
+if [[ ${PV} == 9999 ]]; then
+ DEPEND+=" sys-devel/gnuconfig"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == 9999 ]]; then
+ AT_M4DIR=m4 eautoreconf
+ mkdir config || die
+ local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
+ [[ -e ${automakedir} ]] || die "Could not locate automake directory"
+ ln -s "${automakedir}"/install-sh config/install-sh || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.guess config/config.guess || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.sub config/config.sub || die
+ fi
+}
+
+src_configure() {
+ local myeconfargs=(
+ --bindir="${EPREFIX}"/sbin
+ $(use_enable convert)
+ $(use_enable doc documentation)
+ $(use_enable elibc_glibc backtrace)
+ $(use_enable python)
+ $(use_enable static-libs static)
+ $(use_enable zstd)
+ --with-convert=ext2$(usex reiserfs ',reiserfs' '')
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake V=1 all $(usev static)
+}
+
+src_install() {
+ local makeargs=(
+ $(usex python install_python '')
+ $(usex static install-static '')
+ )
+ emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+ newbashcomp btrfs-completion btrfs
+ use python && python_optimize
+
+ # install prebuilt subset of manuals
+ use doc || doman Documentation/*.[58]
+}