summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorGeorge Kranis <gkranis@users.noreply.github.com>2016-01-10 11:22:34 +0200
committerMichael Palimaka <kensington@gentoo.org>2016-01-13 03:10:47 +1100
commit53ed41f7849121e27571d7e489487bc0d14eefa1 (patch)
treef0f5bb0111697a8ccae6cec5e54af6c99756f2e0 /sys-libs/libapparmor/libapparmor-2.10.ebuild
parentdev-java/tomcat-native: version bump (diff)
downloadgentoo-53ed41f7849121e27571d7e489487bc0d14eefa1.tar.gz
gentoo-53ed41f7849121e27571d7e489487bc0d14eefa1.tar.bz2
gentoo-53ed41f7849121e27571d7e489487bc0d14eefa1.zip
sys-libs/libapparmor: Bump to 2.10, expose private func in .so via patch
The patch is needed so that sys-apps/apparmor can dynamically build against it.
Diffstat (limited to 'sys-libs/libapparmor/libapparmor-2.10.ebuild')
-rw-r--r--sys-libs/libapparmor/libapparmor-2.10.ebuild85
1 files changed, 85 insertions, 0 deletions
diff --git a/sys-libs/libapparmor/libapparmor-2.10.ebuild b/sys-libs/libapparmor/libapparmor-2.10.ebuild
new file mode 100644
index 00000000000..49afee6cfdf
--- /dev/null
+++ b/sys-libs/libapparmor/libapparmor-2.10.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit autotools-utils distutils-r1 perl-module versionator
+
+DESCRIPTION="Library to support AppArmor userspace utilities"
+HOMEPAGE="http://apparmor.net/"
+SRC_URI="https://launchpad.net/apparmor/$(get_version_component_range 1-2)/${PV}/+download/apparmor-${PV}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +perl +python static-libs"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="perl? ( dev-lang/perl:= )
+ python? ( ${PYTHON_DEPS} )"
+
+DEPEND="${RDEPEND}
+ sys-devel/autoconf-archive
+ sys-devel/bison
+ sys-devel/flex
+ doc? ( dev-lang/perl )
+ perl? ( dev-lang/swig )
+ python? ( dev-lang/swig )"
+
+S=${WORKDIR}/apparmor-${PV}/libraries/${PN}
+
+src_prepare() {
+ rm -r m4 || die "failed to remove bundled macros"
+ epatch "${FILESDIR}"/${PN}-2.10-symbol_visibility.patch
+ autotools-utils_src_prepare
+ use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+ local myeconfargs=(
+ $(use_with perl) \
+ $(use_with python)
+ )
+
+ autotools-utils_src_configure
+}
+
+src_compile() {
+ autotools-utils_src_compile -C src
+ autotools-utils_src_compile -C include
+ use doc && autotools-utils_src_compile -C doc
+ use perl && autotools-utils_src_compile -C swig/perl
+
+ if use python ; then
+ pushd "${BUILD_DIR}"/swig/python > /dev/null
+ emake libapparmor_wrap.c
+ distutils-r1_src_compile
+ popd > /dev/null
+ fi
+}
+
+src_install() {
+ autotools-utils_src_install -C src
+ autotools-utils_src_install -C include
+ use doc && autotools-utils_src_install -C doc
+
+ if use perl ; then
+ autotools-utils_src_install -C swig/perl
+ perl_set_version
+ insinto "${VENDOR_ARCH}"
+ doins "${BUILD_DIR}"/swig/perl/LibAppArmor.pm
+ fi
+
+ if use python ; then
+ pushd "${BUILD_DIR}"/swig/python > /dev/null
+ distutils-r1_src_install
+ popd > /dev/null
+ fi
+}