summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAlexandre Rostovtsev <tetromino@gentoo.org>2016-06-28 00:55:38 -0400
committerAlexandre Rostovtsev <tetromino@gentoo.org>2016-06-28 00:56:44 -0400
commitd5f44d5cbee76147bb07d4e4ea999e7cb0cc1291 (patch)
tree0e965d3528a8d1fce0fb7fe5414678d0fa26fdd6 /x11-terms/gnome-terminal/gnome-terminal-3.20.2.ebuild
parentx11-libs/vte: bump to 0.44.2 for gnome-3.20 (diff)
downloadgentoo-d5f44d5cbee76147bb07d4e4ea999e7cb0cc1291.tar.gz
gentoo-d5f44d5cbee76147bb07d4e4ea999e7cb0cc1291.tar.bz2
gentoo-d5f44d5cbee76147bb07d4e4ea999e7cb0cc1291.zip
x11-terms/gnome-terminal: bump to 3.20.2 for gnome-3.20
Support for dark themes has been restored upstream! Edit → Preferences → General → Theme variant = Dark Package-Manager: portage-2.3.0
Diffstat (limited to 'x11-terms/gnome-terminal/gnome-terminal-3.20.2.ebuild')
-rw-r--r--x11-terms/gnome-terminal/gnome-terminal-3.20.2.ebuild77
1 files changed, 77 insertions, 0 deletions
diff --git a/x11-terms/gnome-terminal/gnome-terminal-3.20.2.ebuild b/x11-terms/gnome-terminal/gnome-terminal-3.20.2.ebuild
new file mode 100644
index 00000000000..8318e2b2551
--- /dev/null
+++ b/x11-terms/gnome-terminal/gnome-terminal-3.20.2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+GNOME2_LA_PUNT="yes"
+
+inherit autotools eutils gnome2 readme.gentoo-r1
+
+DESCRIPTION="The Gnome Terminal"
+HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="debug +gnome-shell +nautilus vanilla"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux"
+
+# FIXME: automagic dependency on gtk+[X]
+RDEPEND="
+ >=dev-libs/glib-2.42:2[dbus]
+ >=x11-libs/gtk+-3.12:3[X]
+ >=x11-libs/vte-0.44.2:2.91
+ >=gnome-base/dconf-0.14
+ >=gnome-base/gsettings-desktop-schemas-0.1.0
+ sys-apps/util-linux
+ x11-libs/libSM
+ x11-libs/libICE
+ gnome-shell? ( gnome-base/gnome-shell )
+ nautilus? ( >=gnome-base/nautilus-3 )
+"
+# itstool required for help/* with non-en LINGUAS, see bug #549358
+# xmllint required for glib-compile-resources, see bug #549304
+DEPEND="${RDEPEND}
+ app-text/yelp-tools
+ dev-libs/libxml2
+ dev-util/desktop-file-utils
+ dev-util/gdbus-codegen
+ dev-util/itstool
+ >=dev-util/intltool-0.50
+ sys-devel/gettext
+ virtual/pkgconfig
+"
+
+DOC_CONTENTS="To get previous working directory inherited in new opened
+ tab you will need to add the following line to your ~/.bashrc:\n
+ . /etc/profile.d/vte.sh"
+
+src_prepare() {
+ if ! use vanilla; then
+ # OpenSuSE patches, https://bugzilla.gnome.org/show_bug.cgi?id=695371
+ # http://pkgs.fedoraproject.org/cgit/rpms/gnome-terminal.git/tree/gnome-terminal-transparency-notify.patch (first 3 parts)
+ eapply "${FILESDIR}"/${PN}-3.20.2-transparency.patch
+ eautoreconf
+ fi
+ gnome2_src_prepare
+}
+
+src_configure() {
+ gnome2_src_configure \
+ --disable-static \
+ --disable-migration \
+ $(use_enable debug) \
+ $(use_enable gnome-shell search-provider) \
+ $(use_with nautilus nautilus-extension) \
+ VALAC=$(type -P true)
+}
+
+src_install() {
+ DOCS="AUTHORS ChangeLog HACKING NEWS"
+ gnome2_src_install
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ gnome2_pkg_postinst
+ readme.gentoo_print_elog
+}