summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJeroen Roovers <jer@gentoo.org>2018-10-06 12:22:46 +0200
committerJeroen Roovers <jer@gentoo.org>2018-10-06 12:25:09 +0200
commita0a6dcbe1a5668bd29d2668fe959a065d566aaf2 (patch)
treea3b859e183684573eeafb13638e31fd63c67027c /x11-terms/guake/guake-3.4.0-r1.ebuild
parentapp-arch/zstd: Mark ~hppa too. (diff)
downloadgentoo-a0a6dcbe1a5668bd29d2668fe959a065d566aaf2.tar.gz
gentoo-a0a6dcbe1a5668bd29d2668fe959a065d566aaf2.tar.bz2
gentoo-a0a6dcbe1a5668bd29d2668fe959a065d566aaf2.zip
x11-terms/guake: Fix dependencies, runtime
Bug: https://bugs.gentoo.org/667878 Package-Manager: Portage-2.3.50, Repoman-2.3.11 Signed-off-by: Jeroen Roovers <jer@gentoo.org>
Diffstat (limited to 'x11-terms/guake/guake-3.4.0-r1.ebuild')
-rw-r--r--x11-terms/guake/guake-3.4.0-r1.ebuild63
1 files changed, 63 insertions, 0 deletions
diff --git a/x11-terms/guake/guake-3.4.0-r1.ebuild b/x11-terms/guake/guake-3.4.0-r1.ebuild
new file mode 100644
index 00000000000..a9aeb41ea1c
--- /dev/null
+++ b/x11-terms/guake/guake-3.4.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{5,6} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 gnome2-utils xdg-utils
+
+DESCRIPTION="Drop-down terminal for GNOME"
+HOMEPAGE="https://github.com/Guake/guake https://pypi.org/project/Guake"
+SRC_URI="mirror://pypi/G/${PN^}/${P^}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="utempter"
+
+RDEPEND="
+ dev-libs/glib[${PYTHON_USEDEP}]
+ dev-libs/keybinder:3[introspection]
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ dev-python/pbr[${PYTHON_USEDEP}]
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ x11-libs/libnotify[introspection]
+ x11-libs/vte:2.91[introspection]
+ utempter? ( sys-libs/libutempter )
+"
+DEPEND="
+ ${RDEPEND}
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ gnome-base/gsettings-desktop-schemas
+ sys-devel/gettext
+ sys-devel/make
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.3.2-paths.patch
+ "${FILESDIR}"/${PN}-3.4.0-paths.patch
+)
+S=${WORKDIR}/${P^}
+
+python_compile_all() {
+ emake prepare-install prefix=/usr
+ emake generate-paths prefix=/usr DATA_DIR='$(datadir)/guake' DEV_SCHEMA_DIR='$(gsettingsschemadir)'
+ default
+}
+
+python_install_all() {
+ emake install-schemas install-locale prefix=/usr DESTDIR="${D}"
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ gnome2_schemas_update
+ xdg_desktop_database_update
+}
+
+pkg_postrm() {
+ gnome2_schemas_update
+ xdg_desktop_database_update
+}