summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
-rw-r--r--media-sound/gnome-music/Manifest1
-rw-r--r--media-sound/gnome-music/gnome-music-3.36.4.1.ebuild81
2 files changed, 82 insertions, 0 deletions
diff --git a/media-sound/gnome-music/Manifest b/media-sound/gnome-music/Manifest
index 5b5148452c9..f28ece89766 100644
--- a/media-sound/gnome-music/Manifest
+++ b/media-sound/gnome-music/Manifest
@@ -1 +1,2 @@
DIST gnome-music-3.34.6.tar.xz 1415360 BLAKE2B 0b8f3a2b17242f41f3a77a9eeb60cf1f10cac57d983de6e7f44ba1a243526e0831ee2ad5baec17b726bbbe9df52e26b79dedc2b2abe4dba87c59cc4fcd4a083f SHA512 76561adf8c6ce4342825eb976de11c98c2aa66cb08075dbe46d8c7787daf7fc77763d55c2fe475dd9c75536adc98f8afbdd90bfb2b64791d05cdf11e3ed00b03
+DIST gnome-music-3.36.4.1.tar.xz 979064 BLAKE2B e744bee915a48a5d2366350cda7ebb0c43382f46de07d9203d95675cad45d825f2d93cc07be7865eceb5be3554ab478ecf84c52d9b8f5defc198b4f1b6638926 SHA512 8b6b4a8a44158a724de82855ba781dd6ceb53a30a35160f477721a385a841697f9a7c97cdba9a5bcc5b36834d55c034eb4c892907d550205dc5b7f7af56133ca
diff --git a/media-sound/gnome-music/gnome-music-3.36.4.1.ebuild b/media-sound/gnome-music/gnome-music-3.36.4.1.ebuild
new file mode 100644
index 00000000000..333450fc479
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-3.36.4.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="${PYTHON_DEPS}
+ >=dev-libs/glib-2.50:2
+ >=net-libs/gnome-online-accounts-3.35.90[introspection]
+ >=dev-libs/gobject-introspection-1.54:=
+ >=x11-libs/gtk+-3.24.7:3[introspection]
+ >=dev-libs/libdazzle-3.28.0[introspection]
+ >=media-libs/libmediaart-1.9.1:2.0[introspection]
+ net-libs/libsoup:2.4[introspection]
+ >=app-misc/tracker-2.3.0:=[introspection(+)]
+ $(python_gen_cond_dep '
+ >=dev-python/pygobject-3.29.1:3[cairo,${PYTHON_MULTI_USEDEP}]
+ >=dev-python/pycairo-1.14.0[${PYTHON_MULTI_USEDEP}]
+ ')
+ >=media-libs/grilo-0.3.12:0.3[introspection]
+ >=media-plugins/grilo-plugins-0.3.10:0.3
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${DEPEND}
+ || (
+ >=app-misc/tracker-miners-2.2.0[gstreamer]
+ >=app-misc/tracker-miners-2.2.0[ffmpeg]
+ )
+ x11-libs/libnotify[introspection]
+ media-libs/gstreamer:1.0[introspection]
+ media-libs/gst-plugins-base:1.0[introspection]
+ media-plugins/gst-plugins-meta:1.0
+ media-plugins/grilo-plugins:0.3[tracker]
+ x11-misc/xdg-user-dirs
+"
+BDEPEND="
+ dev-libs/libxml2:2
+ dev-util/itstool
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+"
+
+RESTRICT="test" # only does desktop and appdata validation, and latter needs network to validate screenshot from https
+
+pkg_setup() {
+ python_setup
+}
+
+src_prepare() {
+ sed -e '/sys.path.insert/d' -i "${S}"/gnome-music.in || die "python fixup sed failed"
+ xdg_src_prepare
+}
+
+src_install() {
+ meson_src_install
+ python_fix_shebang "${D}"/usr/bin/gnome-music
+ python_optimize
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}