2 files changed, 69 insertions, 0 deletions
diff --git a/app-admin/consul/Manifest b/app-admin/consul/Manifest
index 031db5c3d9f3..cd23fb98eabd 100644
--- a/app-admin/consul/Manifest
+++ b/app-admin/consul/Manifest
@@ -1 +1,2 @@
 DIST consul-0.8.4.tar.gz 6614287 SHA256 d5573d6e70d490c8b8109722c2019b5a2b35eff703b92d6276997846361cff1b SHA512 4bbb167a603f1d20940330bd9615ba0f50e0113e1d96ce47773f5d2813635f76dd1aec8f43dae4c8c547cec8a891eb0726eeeda7bd7c5b1d495029b359378e68 WHIRLPOOL e270367c69fe74f25c89ef9e8c7f71307d3b8e48b4210e43e48907f1f5a73f11f45aa2b212f70c24463e35d800b861ccd34e2c82de863fc6e7da9cd3eda5214c
+DIST consul-0.9.3.tar.gz 7278357 SHA256 69b76432203e046a8025ce13f7cc041b2308d72f07f240a57f2ba5d580fcff70 SHA512 a1c9cdd3e197afbf088bd1866af15c1864cb8d042dc65d2fcc0d9070b8bf2f9380cf2ceadaff6d5bba7ecd379d53f4b8191e1ae6832f1b2c82f21c62f07d8b0f WHIRLPOOL 9e5ac311761bc786c986d4b0cdb4ba541a46f57cffd8cac4de96292293518cd8e8f3743bcb0740b245ae5a30f9f157987078874503bd6b0685a9f3c88c92ffba
diff --git a/app-admin/consul/consul-0.9.3.ebuild b/app-admin/consul/consul-0.9.3.ebuild
new file mode 100644
index 000000000000..1eae049ea45d
--- /dev/null
+++ b/app-admin/consul/consul-0.9.3.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-vcs-snapshot systemd user
+
+KEYWORDS="~amd64"
+EGO_PN="github.com/hashicorp/consul"
+DESCRIPTION="A tool for service discovery, monitoring and configuration"
+HOMEPAGE="http://www.consul.io"
+SRC_URI="https://github.com/hashicorp/consul/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MPL-2.0"
+IUSE=""
+
+RESTRICT="test"
+
+DEPEND="dev-go/gox
+	>=dev-lang/go-1.9:=
+	>=dev-go/go-tools-0_pre20160121"
+RDEPEND=""
+
+pkg_setup() {
+	enewgroup consul
+	enewuser consul -1 -1 /var/lib/${PN} consul
+}
+
+src_prepare() {
+	default
+
+	sed -e 's:^\(GIT_DESCRIBE=\).*:\1v'${PV}':' \
+		-e 's:^\(GIT_COMMIT=\).*:\1:' \
+		-e 's:^\(GIT_DIRTY=\).*:\1:' \
+		-e 's:go get -u -v $(GOTOOLS)::' \
+		-e 's:vendorfmt dev-build:dev-build:' \
+		-i "${S}/src/${EGO_PN}/GNUmakefile" || die
+}
+
+src_compile() {
+	# The dev target sets causes build.sh to set appropriate XC_OS
+	# and XC_ARCH, and skips generation of an unused zip file,
+	# avoiding a dependency on app-arch/zip.
+	GOPATH="${S}" \
+		emake -C "${S}/src/${EGO_PN}" dev
+}
+
+src_install() {
+	local x
+
+	dobin "${S}/bin/${PN}"
+
+	keepdir /etc/consul.d
+	insinto /etc/consul.d
+	doins "${FILESDIR}/"*.json.example
+
+	for x in /var/{lib,log}/${PN}; do
+		keepdir "${x}"
+		fowners consul:consul "${x}"
+	done
+
+	newinitd "${FILESDIR}/consul.initd" "${PN}"
+	newconfd "${FILESDIR}/consul.confd" "${PN}"
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	systemd_dounit "${FILESDIR}/consul.service"
+}