summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
-rw-r--r--dev-games/tiled/Manifest1
-rw-r--r--dev-games/tiled/tiled-1.2.5.ebuild62
2 files changed, 63 insertions, 0 deletions
diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index 90bd0c686c28..2f007a19d173 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
DIST tiled-1.2.4.tar.gz 16875074 BLAKE2B 19d9e000949a889af90f48c31862aab8d00cbd968d518bc48e58775763ff2b293d5e82f10b8ec45dda936bf81b177f88aa4962900c7b70b01ce514fabf717c46 SHA512 a16fcb3fcceb11397cc981f10a558215264cf2c340639fbc001d384cfd9bc138c05ed40894a03d103af8a7d629c0be9fa6d5a4058fd9c563806920efef8e2cb7
+DIST tiled-1.2.5.tar.gz 16878267 BLAKE2B 75d7ba6f715963cc5209181664052aa276dead8311e8fb99561c8375c4fce3400b60f71f4bce3213e1198e3217812e8debdedc72c87dff3f553e391ed1e9438d SHA512 2b0009a8aa785d4289d6759369ff579e62e4fb969090ee6ba2b3fae4dd42d4e9562bd6d2a74ae372c07d9bbfd108390c79a48b49e05f0881e87497f6a727cb3a
diff --git a/dev-games/tiled/tiled-1.2.5.ebuild b/dev-games/tiled/tiled-1.2.5.ebuild
new file mode 100644
index 000000000000..56763ea7c4f4
--- /dev/null
+++ b/dev-games/tiled/tiled-1.2.5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_6 )
+inherit gnome2-utils multilib python-single-r1 qmake-utils xdg-utils
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="https://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+ >=dev-qt/qtcore-5.9:5
+ >=dev-qt/qtgui-5.9:5
+ >=dev-qt/qtnetwork-5.9:5
+ >=dev-qt/qtwidgets-5.9:5
+ sys-libs/zlib
+ python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/linguist-tools:5"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+ eqmake5 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+ emake INSTALL_ROOT="${D}" install
+
+ einstalldocs
+
+ if use examples ; then
+ docompress -x /usr/share/doc/${PF}/examples
+ dodoc -r examples
+ fi
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ xdg_desktop_database_update
+ xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+ xdg_desktop_database_update
+ xdg_mimeinfo_database_update
+}