1 files changed, 49 insertions, 0 deletions
diff --git a/app-arch/pixz/pixz-1.0.3.ebuild b/app-arch/pixz/pixz-1.0.3.ebuild
new file mode 100644
index 000000000000..03ad203c76d6
--- /dev/null
+++ b/app-arch/pixz/pixz-1.0.3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit toolchain-funcs flag-o-matic autotools
+
+DESCRIPTION="Parallel Indexed XZ compressor"
+HOMEPAGE="https://github.com/vasi/pixz"
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="static"
+
+LIB_DEPEND=">=app-arch/libarchive-2.8:=[static-libs(+)]
+	>=app-arch/xz-utils-5[static-libs(+)]"
+RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )"
+DEPEND="${RDEPEND}
+	static? ( ${LIB_DEPEND} )
+	app-text/asciidoc"
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/vasi/${PN}.git"
+	inherit git-r3
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/vasi/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	append-flags -std=gnu99
+	econf
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" OPT=""
+}
+
+src_install() {
+	dobin src/pixz
+	doman src/pixz.1
+	dodoc README.md TODO
+}