1 files changed, 49 insertions, 0 deletions
diff --git a/app-eselect/eselect-gnome-shell-extensions/eselect-gnome-shell-extensions-20180306-r1.ebuild b/app-eselect/eselect-gnome-shell-extensions/eselect-gnome-shell-extensions-20180306-r1.ebuild
new file mode 100644
index 000000000000..68a007afe5dc
--- /dev/null
+++ b/app-eselect/eselect-gnome-shell-extensions/eselect-gnome-shell-extensions-20180306-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Manages system defaults for GNOME Shell extensions"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="https://dev.gentoo.org/~leio/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 arm64 ~loong ~ppc64 ~riscv x86"
+
+# gnome-shell schemas are used in pkg_postinst
+DEPEND="
+	app-admin/eselect
+	>=dev-libs/glib-2.26:2
+	gnome-base/gsettings-desktop-schemas
+	gnome-base/gnome-shell"
+RDEPEND="${DEPEND}
+	dev-lang/perl
+	dev-perl/JSON"
+
+src_install() {
+	insinto /usr/share/eselect/modules
+	doins gnome-shell-extensions.eselect
+
+	keepdir /etc/eselect/gnome-shell-extensions
+	# The actual gschema override file will be created in pkg_postinst.
+	dosym ../../../../etc/eselect/gnome-shell-extensions/${PN}.gschema.override \
+		/usr/share/glib-2.0/schemas/${PN}.gschema.override
+}
+
+pkg_postinst() {
+	einfo "Updating list of installed extensions"
+
+	eselect gnome-shell-extensions update || die
+	local keyname="disabled-extensions"
+	has_version ">=gnome-base/gnome-shell-3.1.90" && keyname="enabled-extensions"
+
+	elog
+	elog "eselect gnome-shell-extensions manages the system default value of"
+	elog "the org.gnome.shell ${keyname} key. To override the default"
+	elog "for an individual user, use the gsettings command, e.g."
+	elog "\$ gsettings set org.gnome.shell ${keyname} \"['foo', 'bar']\""
+	elog "To undo per-user changes and use the system default, do"
+	elog "\$ gsettings reset org.gnome.shell ${keyname}"
+	elog
+}