1 files changed, 69 insertions, 0 deletions
diff --git a/app-i18n/opencc/opencc-1.1.4.ebuild b/app-i18n/opencc/opencc-1.1.4.ebuild
new file mode 100644
index 000000000000..9c8761e44dc2
--- /dev/null
+++ b/app-i18n/opencc/opencc-1.1.4.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2010-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake python-any-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/BYVoid/OpenCC"
+fi
+
+DESCRIPTION="Library for conversion between Traditional and Simplified Chinese characters"
+HOMEPAGE="https://github.com/BYVoid/OpenCC"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/BYVoid/OpenCC/archive/ver.${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0/1.1"
+KEYWORDS="amd64 arm64 ~hppa ~loong ppc ppc64 ~riscv sparc x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="${PYTHON_DEPS}
+	doc? ( app-text/doxygen )"
+DEPEND="dev-cpp/tclap
+	dev-libs/darts
+	dev-libs/marisa:0=
+	dev-libs/rapidjson
+	test? (
+		dev-cpp/gtest
+		!hppa? ( !sparc? ( dev-cpp/benchmark ) )
+	)"
+RDEPEND="dev-libs/marisa:0="
+
+if [[ "${PV}" != "9999" ]]; then
+	S="${WORKDIR}/OpenCC-ver.${PV}"
+fi
+
+DOCS=(AUTHORS NEWS.md README.md)
+
+src_prepare() {
+	rm -r deps || die
+
+	cmake_src_prepare
+
+	sed -e "s:\${DIR_SHARE_OPENCC}/doc:share/doc/${PF}:" -i doc/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc ON OFF)
+		-DENABLE_BENCHMARK=$(if use test && has_version -d dev-cpp/benchmark; then echo ON; else echo OFF; fi)
+		-DENABLE_GTEST=$(usex test ON OFF)
+		-DUSE_SYSTEM_DARTS=ON
+		-DUSE_SYSTEM_GOOGLE_BENCHMARK=ON
+		-DUSE_SYSTEM_GTEST=ON
+		-DUSE_SYSTEM_MARISA=ON
+		-DUSE_SYSTEM_RAPIDJSON=ON
+		-DUSE_SYSTEM_TCLAP=ON
+	)
+
+	cmake_src_configure
+}