1 files changed, 56 insertions, 0 deletions
diff --git a/dev-lang/vala/vala-0.42.4.ebuild b/dev-lang/vala/vala-0.42.4.ebuild
new file mode 100644
index 000000000000..1339fc0c6a54
--- /dev/null
+++ b/dev-lang/vala/vala-0.42.4.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_EAUTORECONF="yes"
+
+inherit gnome2
+
+DESCRIPTION="Compiler for the GObject type system"
+HOMEPAGE="https://wiki.gnome.org/Projects/Vala"
+
+LICENSE="LGPL-2.1"
+SLOT="0.42"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-linux"
+IUSE="test valadoc"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	>=dev-libs/vala-common-${PV}
+	valadoc? ( >=media-gfx/graphviz-2.16 )
+"
+DEPEND="${RDEPEND}
+	!${CATEGORY}/${PN}:0
+	dev-libs/libxslt
+	sys-devel/flex
+	virtual/pkgconfig
+	virtual/yacc
+	test? (
+		dev-libs/dbus-glib
+		>=dev-libs/glib-2.26:2
+		dev-libs/gobject-introspection )
+"
+
+PATCHES=(
+	# From master
+	"${FILESDIR}"/0.40-Allow-disabling-the-build-of-valadoc.patch
+	# Add missing bits to make valadoc parallel installable
+	"${FILESDIR}"/0.40-valadoc-doclets-data-parallel-installable.patch
+)
+
+src_configure() {
+	# https://bugs.gentoo.org/483134
+	export GIT_CEILING_DIRECTORIES="${WORKDIR}"
+
+	# weasyprint enables generation of PDF from HTML
+	gnome2_src_configure \
+		--disable-unversioned \
+		$(use_enable valadoc) \
+		VALAC=: \
+		WEASYPRINT=:
+}
+
+src_install() {
+	default
+	find "${D}" -name "*.la" -delete || die
+}