summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-libs/libinput/libinput-1.15.0.ebuild')
-rw-r--r--dev-libs/libinput/libinput-1.15.0.ebuild79
1 files changed, 79 insertions, 0 deletions
diff --git a/dev-libs/libinput/libinput-1.15.0.ebuild b/dev-libs/libinput/libinput-1.15.0.ebuild
new file mode 100644
index 00000000000..7fee879ca56
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.15.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 2014-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom"
+# Tests require write access to udev rules directory which is a no-no for live system.
+# Other tests are just about logs, exported symbols and autotest of the test library.
+RESTRICT="test"
+
+BDEPEND="
+ virtual/pkgconfig
+ doc? (
+ $(python_gen_any_dep '
+ dev-python/commonmark[${PYTHON_USEDEP}]
+ dev-python/recommonmark[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ >=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+ ')
+ >=app-doc/doxygen-1.8.3
+ >=media-gfx/graphviz-2.38.0
+ )
+"
+# test? ( dev-util/valgrind )
+RDEPEND="
+ input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+ >=dev-libs/libevdev-1.3
+ >=sys-libs/mtdev-1.1
+ virtual/libudev:=
+ virtual/udev
+"
+DEPEND="${RDEPEND}"
+# test? ( >=dev-libs/check-0.9.10 )
+
+python_check_deps() {
+ has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+ has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+ has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+ has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+ # gui can be built but will not be installed
+ local emesonargs=(
+ -Ddebug-gui=false
+ $(meson_use doc documentation)
+ $(meson_use input_devices_wacom libwacom)
+ -Dtests=false # tests are restricted
+ -Dudev-dir="$(get_udevdir)"
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ if use doc ; then
+ docinto html
+ dodoc -r "${BUILD_DIR}"/Documentation/.
+ fi
+}
+
+pkg_postinst() {
+ udevadm hwdb --update --root="${ROOT}"
+}