1 files changed, 57 insertions, 0 deletions
diff --git a/games-action/violetland/violetland-0.4.3-r1.ebuild b/games-action/violetland/violetland-0.4.3-r1.ebuild
new file mode 100644
index 000000000000..a3b711ae9e6a
--- /dev/null
+++ b/games-action/violetland/violetland-0.4.3-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils multilib toolchain-funcs flag-o-matic cmake-utils
+
+DESCRIPTION="Help a girl named Violet in the struggle with hordes of monsters"
+HOMEPAGE="https://code.google.com/p/violetland/"
+SRC_URI="https://github.com/ooxi/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-libs/boost[threads(+)]
+	media-libs/libsdl[sound,video]
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer[vorbis]
+	media-libs/sdl-ttf
+	virtual/glu
+	virtual/opengl"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-boost150.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/README_EN.TXT/d" \
+		-e "/README_RU.TXT/d" \
+		CMakeLists.txt || die "sed failed"
+}
+
+src_configure() {
+	mycmakeargs=(
+		"-DCMAKE_INSTALL_PREFIX=/usr"
+		"-DDATA_INSTALL_DIR=/usr/share/${PN}"
+		)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	DOCS="README_EN.TXT CHANGELOG" cmake-utils_src_install
+	newicon icon-light.png ${PN}.png
+	make_desktop_entry ${PN} VioletLand
+}