1 files changed, 45 insertions, 0 deletions
diff --git a/games-board/xgammon/xgammon-0.98-r1.ebuild b/games-board/xgammon/xgammon-0.98-r1.ebuild
new file mode 100644
index 000000000000..1c2aeed33cbd
--- /dev/null
+++ b/games-board/xgammon/xgammon-0.98-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit toolchain-funcs eutils
+
+DESCRIPTION="very nice backgammon game for X"
+HOMEPAGE="http://fawn.unibw-hamburg.de/steuer/xgammon/xgammon.html"
+SRC_URI="http://fawn.unibw-hamburg.de/steuer/xgammon/Downloads/${P}a.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+RDEPEND="x11-libs/libXaw"
+DEPEND="${RDEPEND}
+	app-text/rman
+	x11-misc/imake"
+
+S=${WORKDIR}/${P}a
+
+PATCHES=(
+	"${FILESDIR}/${P}-broken.patch"
+	"${FILESDIR}/${P}-config.patch"
+	"${FILESDIR}/gcc33.patch"
+)
+
+src_configure() {
+	xmkmf || die
+}
+
+src_compile() {
+	env PATH=".:${PATH}" emake \
+		EXTRA_LDOPTIONS="${LDFLAGS}" \
+		CDEBUGFLAGS="${CFLAGS}" \
+		CC=$(tc-getCC)
+}
+
+pkg_postinst() {
+	einfo "xgammon need helvetica fonts"
+	einfo "They can be loaded emerging media-fonts/font-adobe-100dpi"
+	einfo "or similar. Remember to restart X after loading fonts"
+}