summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'games-util/slade/slade-3.2.1-r1.ebuild')
-rw-r--r--games-util/slade/slade-3.2.1-r1.ebuild80
1 files changed, 80 insertions, 0 deletions
diff --git a/games-util/slade/slade-3.2.1-r1.ebuild b/games-util/slade/slade-3.2.1-r1.ebuild
new file mode 100644
index 00000000000..285ef98db6f
--- /dev/null
+++ b/games-util/slade/slade-3.2.1-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..3} )
+WX_GTK_VER="3.0-gtk3"
+
+inherit cmake lua-single wxwidgets
+
+MY_PV="${PV/beta/b}"
+DESCRIPTION="Modern editor for Doom-engine based games and source ports"
+HOMEPAGE="https://slade.mancubus.net/"
+SRC_URI="https://github.com/sirjuddington/${PN^^}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-2 MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="fluidsynth timidity webkit"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+DEPEND="
+ ${LUA_DEPS}
+ app-arch/bzip2:=
+ dev-libs/libfmt:=
+ >=media-libs/dumb-2:=
+ media-libs/freeimage[jpeg,png,tiff]
+ media-libs/glew:0=
+ media-libs/libsfml:=
+ media-sound/mpg123
+ net-misc/curl
+ sys-libs/zlib
+ x11-libs/wxGTK:${WX_GTK_VER}[opengl,webkit?,X]
+ fluidsynth? ( media-sound/fluidsynth:= )
+"
+
+RDEPEND="
+ ${DEPEND}
+ timidity? ( media-sound/timidity++ )
+"
+
+BDEPEND="
+ app-arch/p7zip
+ virtual/pkgconfig
+"
+
+S="${WORKDIR}/${PN^^}-${MY_PV}"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.2.0-bundled-libs.patch
+ "${FILESDIR}"/${PN}-3.2.0_beta2-fluidsynth-driver.patch
+)
+
+src_prepare() {
+ cmake_src_prepare
+
+ # Delete bundled libraries just in case.
+ rm -r thirdparty/dumb/ thirdparty/fmt/ || die
+
+}
+
+src_configure() {
+ local luav=$(lua_get_version)
+
+ local mycmakeargs=(
+ -DLua_FIND_VERSION_MAJOR=$(ver_cut 1 "${luav}")
+ -DLua_FIND_VERSION_MINOR=$(ver_cut 2 "${luav}")
+ -DLua_FIND_VERSION_COUNT=2
+ -DLua_FIND_VERSION_EXACT=ON
+ -DNO_COTIRE=ON
+ -DNO_FLUIDSYNTH=$(usex fluidsynth OFF ON)
+ -DNO_WEBVIEW=$(usex webkit OFF ON)
+ -DUSE_SFML_RENDERWINDOW=ON
+ -DUSE_SYSTEM_DUMB=ON
+ -DUSE_SYSTEM_FMT=ON
+ -DWX_GTK3=ON
+ )
+
+ setup-wxwidgets
+ cmake_src_configure
+}