summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'gnome-base')
-rw-r--r--gnome-base/gdm/Manifest2
-rw-r--r--gnome-base/gdm/gdm-41.0.ebuild216
-rw-r--r--gnome-base/gnome-applets/Manifest1
-rw-r--r--gnome-base/gnome-applets/gnome-applets-3.36.4.ebuild56
-rw-r--r--gnome-base/gnome-applets/gnome-applets-3.40.0-r2.ebuild (renamed from gnome-base/gnome-applets/gnome-applets-3.40.0-r1.ebuild)7
-rw-r--r--gnome-base/gnome-applets/gnome-applets-3.40.0.ebuild53
-rw-r--r--gnome-base/gnome-desktop/gnome-desktop-40.4.ebuild2
-rw-r--r--gnome-base/gnome-flashback/Manifest1
-rw-r--r--gnome-base/gnome-flashback/gnome-flashback-3.36.4.ebuild84
-rw-r--r--gnome-base/gnome-keyring/gnome-keyring-40.0-r1.ebuild79
-rw-r--r--gnome-base/gnome-panel/Manifest1
-rw-r--r--gnome-base/gnome-panel/gnome-panel-3.36.2.ebuild72
-rw-r--r--gnome-base/gnome-shell/Manifest4
-rw-r--r--gnome-base/gnome-shell/gnome-shell-40.4.ebuild2
-rw-r--r--gnome-base/gnome-shell/gnome-shell-40.5.ebuild (renamed from gnome-base/gnome-shell/gnome-shell-40.2.ebuild)43
-rw-r--r--gnome-base/gnome-shell/gnome-shell-41.0-r1.ebuild203
-rw-r--r--gnome-base/gsettings-desktop-schemas/Manifest1
-rw-r--r--gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-41.0.ebuild48
-rw-r--r--gnome-base/nautilus/nautilus-40.2.ebuild3
19 files changed, 584 insertions, 294 deletions
diff --git a/gnome-base/gdm/Manifest b/gnome-base/gdm/Manifest
index d486cfd45a5..55705914eaf 100644
--- a/gnome-base/gdm/Manifest
+++ b/gnome-base/gdm/Manifest
@@ -1,3 +1,5 @@
DIST gdm-40.0.tar.xz 800296 BLAKE2B 9c2038758cec09f13c18bd79d431e82a29fb1a2b8ab099498a0b8d920cb93896abceab9157edae8cc15312e03d21eb36b649c2cc8761f9af5fec387c5f28a261 SHA512 b20d02f8a80f6aff8909a69c6c621c20c5aa1b25cfedd68bf95faaaa56d5f7cd5d607d1a7388b97aa06510684f1e9e474248042a00203f496c39930e001bb64c
DIST gdm-40.1.tar.xz 803488 BLAKE2B a0f5349c15c281b666e2e1eb35b81bd4fe3561d7dfa48e43fab7b6ac5c6f9f187f3907fc88eb169ef5e7951c815dec849f64ff2a2b630742b47521bc5c33f618 SHA512 34e3d905195c9d44f3681fcf8170b67e739cef60fe3987802b7006e5063b9cdf5ca047470d0aebd6e9b47dbbb660040648a647ed8d3186a3099b8c6532c5ded7
+DIST gdm-41.0-patchset.tar.xz 12076 BLAKE2B 900ad267bdbb0c189ba36c215aa4bd18f170efd4df02341b1b6f98bdb09b4bbcfcf795ec5a63b5364f47486767a347f60193168749f10823fa816f9500cd3073 SHA512 6c7940ec9c91d0e28f5e9d728abd49814d4d9c7b964e753436f0ceaa11f6c58a559ac3ef0d2e14bf5410a097abdf72cf16dad191017c9ee5c59e6f68de8f2ca8
+DIST gdm-41.0.tar.xz 806668 BLAKE2B 12bd10ff4c5799683665127e5ff543e07f13cffde1d668213b43d6471812c727cb18e93c3305923019c3f522aa0484779dd861afc7ac939115b5f169657722e8 SHA512 b1dd99beb8339c6cf93f10e0aec1c946c615b4efaf1724392585985fb32cee156a9e44fd3041ab87ab9ba6a6bd6c9a9d0ecf8b40dc9c098b3c7ee47f7a7e9a97
DIST tango-gentoo-v1.1.tar.gz 29322 BLAKE2B 83fa2bf37727e60851dd679054fe1b153ebfea58c9a9a40f891f7d68d3b047b02e8effa1d1b4e08d64500a2072ce7200f159c92a352da7124de27e1b05bb6027 SHA512 87d47ddab68361db6d99866c51705dcb3e198f8345a1096859acf2c6cca5099dd23c7fb30d124f52c4933ea38fd45fadffbbe6ecbdfa84f5b60938a4824f9045
diff --git a/gnome-base/gdm/gdm-41.0.ebuild b/gnome-base/gdm/gdm-41.0.ebuild
new file mode 100644
index 00000000000..26502e30286
--- /dev/null
+++ b/gnome-base/gdm/gdm-41.0.ebuild
@@ -0,0 +1,216 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop gnome2 meson pam readme.gentoo-r1 systemd toolchain-funcs udev
+
+DESCRIPTION="GNOME Display Manager for managing graphical display servers and user logins"
+HOMEPAGE="https://wiki.gnome.org/Projects/GDM"
+
+SRC_URI="${SRC_URI}
+ https://dev.gentoo.org/~leio/distfiles/${PF}-patchset.tar.xz
+ branding? ( https://www.mail-archive.com/tango-artists@lists.freedesktop.org/msg00043/tango-gentoo-v1.1.tar.gz )
+"
+
+LICENSE="
+ GPL-2+
+ branding? ( CC-BY-SA-4.0 )
+"
+
+SLOT="0"
+
+IUSE="accessibility audit bluetooth-sound branding elogind fprint ipv6 plymouth selinux systemd tcpd test wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="^^ ( elogind systemd )"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+# dconf, dbus and g-s-d are needed at install time for dconf update
+# keyutils is automagic dep that makes autologin unlock login keyring when all the passwords match (disk encryption, user pw and login keyring)
+# dbus-run-session used at runtime
+COMMON_DEPEND="
+ virtual/udev
+ >=dev-libs/glib-2.56:2
+ >=x11-libs/gtk+-2.91.1:3
+ >=media-libs/libcanberra-0.4[gtk3]
+ >=sys-apps/accountsservice-0.6.35
+ x11-libs/libxcb
+ sys-apps/keyutils:=
+ selinux? ( sys-libs/libselinux )
+
+ x11-libs/libX11
+ x11-libs/libXau
+ x11-base/xorg-server[-minimal]
+ x11-libs/libXdmcp
+ tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
+
+ systemd? ( >=sys-apps/systemd-186:0=[pam] )
+ elogind? ( >=sys-auth/elogind-239.3[pam] )
+
+ plymouth? ( sys-boot/plymouth )
+ audit? ( sys-process/audit )
+
+ sys-libs/pam
+ sys-auth/pambase[elogind?,systemd?]
+
+ >=gnome-base/dconf-0.20
+ >=gnome-base/gnome-settings-daemon-3.1.4
+ gnome-base/gsettings-desktop-schemas
+ sys-apps/dbus
+
+ >=x11-misc/xdg-utils-1.0.2-r3
+
+ >=dev-libs/gobject-introspection-0.9.12:=
+"
+# XXX: These deps are from session and desktop files in data/ directory
+# fprintd is used via dbus by gdm-fingerprint-extension
+RDEPEND="${COMMON_DEPEND}
+ acct-group/gdm
+ acct-user/gdm
+ >=gnome-base/gnome-session-3.6
+ >=gnome-base/gnome-shell-3.1.90
+ x11-apps/xhost
+
+ accessibility? (
+ >=app-accessibility/orca-3.10
+ gnome-extra/mousetweaks
+ )
+ fprint? ( sys-auth/fprintd[pam] )
+"
+DEPEND="${COMMON_DEPEND}
+ x11-base/xorg-proto
+"
+BDEPEND="
+ app-text/docbook-xml-dtd:4.1.2
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ dev-util/itstool
+ >=gnome-base/dconf-0.20
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ test? ( >=dev-libs/check-0.9.4 )
+ app-text/yelp-tools
+"
+
+DOC_CONTENTS="
+ To make GDM start at boot with systemd, run:\n
+ # systemctl enable gdm.service\n
+ \n
+ To make GDM start at boot with OpenRC, edit /etc/conf.d to have
+ DISPLAYMANAGER=\"gdm\" and enable the xdm service:\n
+ # rc-update add xdm
+ \n
+ For passwordless login to unlock your keyring, you need to install
+ sys-auth/pambase with USE=gnome-keyring and set an empty password
+ on your keyring. Use app-crypt/seahorse for that.\n
+ \n
+ You may need to install app-crypt/coolkey and sys-auth/pam_pkcs11
+ for smartcard support
+"
+
+PATCHES=(
+ "${WORKDIR}"/patches/
+
+ # Gentoo does not have a fingerprint-auth pam stack
+ "${FILESDIR}/${PN}-3.8.4-fingerprint-auth.patch"
+
+ # Add elogind support
+ "${FILESDIR}/${PN}-40.0-meson-allow-building-with-elogind.patch"
+
+ # Support pam_elogind.so in gdm-launch-environment.pam
+ "${FILESDIR}/pam-elogind.patch"
+)
+
+src_prepare() {
+ default
+
+ # Show logo when branding is enabled
+ use branding && eapply "${FILESDIR}/${PN}-3.30.3-logo.patch"
+}
+
+src_configure() {
+ # --with-initial-vt=7 conflicts with plymouth, bug #453392
+ # gdm-3.30 now reaps (stops) the login screen when the login VT isn't active, which
+ # saves on memory. However this means if we don't start on VT1, gdm doesn't start up
+ # before user manually goes to VT7. Thus as-is we can not keep gdm away from VT1,
+ # so lets try always having it in VT1 and see if that is an issue for people before
+ # hacking up workarounds for the initial start case.
+ local emesonargs=(
+ --localstatedir /var
+
+ -Ddefault-pam-config=exherbo
+ -Dgdm-xsession=true
+ -Dgroup=gdm
+ $(meson_use ipv6)
+ $(meson_feature audit libaudit)
+ -Dlogind-provider=$(usex systemd systemd elogind)
+ -Dpam-mod-dir=$(getpam_mod_dir)
+ $(meson_feature plymouth)
+ -Drun-dir=/run/gdm
+ $(meson_feature selinux)
+ $(meson_use systemd systemd-journal)
+ $(meson_use tcpd tcp-wrappers)
+ -Dudev-dir=$(get_udevdir)/rules.d
+ -Duser=gdm
+ -Duser-display-server=true
+ $(meson_use wayland wayland-support)
+ -Dxdmcp=enabled
+ )
+
+ if use elogind; then
+ emesonargs+=(
+ -Dinitial-vt=7 # TODO: Revisit together with startDM.sh and other xinit talks; also ignores plymouth possibility
+ -Dsystemdsystemunitdir=no
+ -Dsystemduserunitdir=no
+ )
+ else
+ emesonargs+=(
+ -Dinitial-vt=1
+ -Dsystemdsystemunitdir="$(systemd_get_systemunitdir)"
+ -Dsystemduserunitdir="$(systemd_get_userunitdir)"
+ )
+ fi
+
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+
+ if ! use accessibility ; then
+ rm "${ED}"/usr/share/gdm/greeter/autostart/orca-autostart.desktop || die
+ fi
+
+ if ! use bluetooth-sound ; then
+ # Workaround https://gitlab.freedesktop.org/pulseaudio/pulseaudio/merge_requests/10
+ # bug #679526
+ insinto /var/lib/gdm/.config/pulse
+ doins "${FILESDIR}"/default.pa
+ fi
+
+ # install XDG_DATA_DIRS gdm changes
+ echo 'XDG_DATA_DIRS="/usr/share/gdm"' > 99xdg-gdm
+ doenvd 99xdg-gdm
+
+ use branding && newicon "${WORKDIR}/tango-gentoo-v1.1/scalable/gentoo.svg" gentoo-gdm.svg
+
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ gnome2_pkg_postinst
+ local d ret
+
+ # bug #669146; gdm may crash if /var/lib/gdm subdirs are not owned by gdm:gdm
+ ret=0
+ ebegin "Fixing "${EROOT}"/var/lib/gdm ownership"
+ chown --no-dereference gdm:gdm "${EROOT}/var/lib/gdm" || ret=1
+ for d in "${EROOT}/var/lib/gdm/"{.cache,.color,.config,.dbus,.local}; do
+ [[ ! -e "${d}" ]] || chown --no-dereference -R gdm:gdm "${d}" || ret=1
+ done
+ eend ${ret}
+
+ systemd_reenable gdm.service
+ readme.gentoo_print_elog
+}
diff --git a/gnome-base/gnome-applets/Manifest b/gnome-base/gnome-applets/Manifest
index a2c328d0174..30901def6d3 100644
--- a/gnome-base/gnome-applets/Manifest
+++ b/gnome-base/gnome-applets/Manifest
@@ -1,2 +1 @@
-DIST gnome-applets-3.36.4.tar.xz 8638044 BLAKE2B 1ccf045c568ca2d4280eeeebbaec67b63f9c2f1edd3248ef89ff93ef7d468e6a581f3c678e93ff45662368b9ecd189aa38da2ca91a7b14ed3e7b2bd6aac8971f SHA512 6fd8f891358f02f40c8d6548b1680139f18cbbcd20d773798a998246b6431692ce8550e8652eaff09bde3651a4e5449779a0dc85b897345a22c17be2e386d2c7
DIST gnome-applets-3.40.0.tar.xz 9390340 BLAKE2B 0d8e76086e444789b7a327623db9b21ef0a51f071b67aa5d99dc3e7988be40ec353ced795aaa1acbbe8d1b303d3878e2a0589214dac10f35ab2e40381ee64978 SHA512 909a1e9ecbe6904537b7408239a17aad265890cf179c4b8929968fa4d8ba6f1ac1f6e98612eb9c54266d3abacaaa7ed0e218f41b081b7539532527a3234fc037
diff --git a/gnome-base/gnome-applets/gnome-applets-3.36.4.ebuild b/gnome-base/gnome-applets/gnome-applets-3.36.4.ebuild
deleted file mode 100644
index 91a8bbf9357..00000000000
--- a/gnome-base/gnome-applets/gnome-applets-3.36.4.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit gnome2
-
-DESCRIPTION="Applets for the GNOME Flashback Panel"
-HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-applets/"
-
-LICENSE="GPL-2+ FDL-1.1"
-SLOT="0"
-IUSE="ipv6 tracker upower"
-KEYWORDS="~amd64"
-
-# FIXME: automagic wireless-tools
-# TODO: gucharmap could be optional, but no knob
-# TODO: libgweather could be optional, but no knob
-RDEPEND="
- >=x11-libs/gtk+-3.20.0:3[X]
- >=dev-libs/glib-2.44.0:2
- >=gnome-base/gnome-panel-3.24.1
- >=gnome-base/libgtop-2.11.92:=
- >=x11-libs/libwnck-3.14.1:3
- >=x11-libs/libnotify-0.7
- upower? ( >=sys-power/upower-0.99.8:= )
- >=x11-themes/adwaita-icon-theme-3.14.0
- >=dev-libs/libxml2-2.5.0:2
- >=dev-libs/libgweather-3.28.0:2=
- >=gnome-extra/gucharmap-2.33.0:2.90
- >=sys-auth/polkit-0.97
- x11-libs/libX11
- tracker? ( app-misc/tracker:0/2.0 )
-"
-# app-text/docbook-sgml-utils for jw binary
-DEPEND="${RDEPEND}
- app-text/docbook-sgml-utils
- app-text/docbook-xml-dtd:4.1.2
- dev-libs/libxslt
- dev-util/gdbus-codegen
- dev-util/glib-utils
- >=dev-util/intltool-0.35.0
- dev-util/itstool
- sys-devel/gettext
- x11-base/xorg-proto
- virtual/pkgconfig
-" # yelp-tools and autoconf-archive for eautoreconf
-
-src_configure() {
- gnome2_src_configure \
- --disable-static \
- $(use_with upower) \
- --disable-battstat \
- --disable-cpufreq \
- $(use_enable tracker tracker-search-bar) \
- $(use_enable ipv6)
-}
diff --git a/gnome-base/gnome-applets/gnome-applets-3.40.0-r1.ebuild b/gnome-base/gnome-applets/gnome-applets-3.40.0-r2.ebuild
index 4320fd2e92f..0f434b492bc 100644
--- a/gnome-base/gnome-applets/gnome-applets-3.40.0-r1.ebuild
+++ b/gnome-base/gnome-applets/gnome-applets-3.40.0-r2.ebuild
@@ -22,9 +22,10 @@ RDEPEND="
>=gnome-base/libgtop-2.11.92:=
>=x11-libs/libwnck-3.14.1:3
>=x11-libs/libnotify-0.7
+ >=sys-power/upower-0.99.8:=
>=x11-themes/adwaita-icon-theme-3.14.0
>=dev-libs/libxml2-2.5.0:2
- >=dev-libs/libgweather-3.28.0:2=
+ >=dev-libs/libgweather-40.0:2=
>=gnome-extra/gucharmap-2.33.0:2.90
>=sys-auth/polkit-0.97
x11-libs/libX11
@@ -33,15 +34,13 @@ RDEPEND="
DEPEND="${RDEPEND}
x11-base/xorg-proto
"
-# app-text/docbook-sgml-utils for jw binary
BDEPEND="
- app-text/docbook-sgml-utils
app-text/docbook-xml-dtd:4.1.2
dev-libs/libxslt
dev-util/gdbus-codegen
dev-util/glib-utils
dev-util/itstool
- sys-devel/gettext
+ >=sys-devel/gettext-0.19.6
virtual/pkgconfig
" # yelp-tools and autoconf-archive for eautoreconf
diff --git a/gnome-base/gnome-applets/gnome-applets-3.40.0.ebuild b/gnome-base/gnome-applets/gnome-applets-3.40.0.ebuild
deleted file mode 100644
index 52182b3d367..00000000000
--- a/gnome-base/gnome-applets/gnome-applets-3.40.0.ebuild
+++ /dev/null
@@ -1,53 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-inherit gnome2
-
-DESCRIPTION="Applets for the GNOME Flashback Panel"
-HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-applets/"
-
-LICENSE="GPL-2+ FDL-1.1"
-SLOT="0"
-IUSE="tracker"
-KEYWORDS="~amd64"
-
-# FIXME: automagic wireless-tools
-# TODO: gucharmap could be optional, but no knob
-# TODO: libgweather could be optional, but no knob
-RDEPEND="
- >=x11-libs/gtk+-3.20.0:3[X]
- >=dev-libs/glib-2.44.0:2
- >=gnome-base/gnome-panel-3.37.0
- >=gnome-base/libgtop-2.11.92:=
- >=x11-libs/libwnck-3.14.1:3
- >=x11-libs/libnotify-0.7
- >=x11-themes/adwaita-icon-theme-3.14.0
- >=dev-libs/libxml2-2.5.0:2
- >=dev-libs/libgweather-3.28.0:2=
- >=gnome-extra/gucharmap-2.33.0:2.90
- >=sys-auth/polkit-0.97
- x11-libs/libX11
- tracker? ( app-misc/tracker:0/2.0 )
-"
-DEPEND="${RDEPEND}
- x11-base/xorg-proto
-"
-# app-text/docbook-sgml-utils for jw binary
-BDEPEND="
- app-text/docbook-sgml-utils
- app-text/docbook-xml-dtd:4.1.2
- dev-libs/libxslt
- dev-util/gdbus-codegen
- dev-util/glib-utils
- dev-util/itstool
- sys-devel/gettext
- virtual/pkgconfig
-" # yelp-tools and autoconf-archive for eautoreconf
-
-src_configure() {
- gnome2_src_configure \
- --disable-static \
- --disable-cpufreq \
- $(use_enable tracker tracker-search-bar)
-}
diff --git a/gnome-base/gnome-desktop/gnome-desktop-40.4.ebuild b/gnome-base/gnome-desktop/gnome-desktop-40.4.ebuild
index 2df7a40bf2c..1aa9edcde38 100644
--- a/gnome-base/gnome-desktop/gnome-desktop-40.4.ebuild
+++ b/gnome-base/gnome-desktop/gnome-desktop-40.4.ebuild
@@ -10,7 +10,7 @@ HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
SLOT="3/19" # subslot = libgnome-desktop-3 soname version
IUSE="debug gtk-doc +introspection seccomp systemd udev"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
COMMON_DEPEND="
>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
diff --git a/gnome-base/gnome-flashback/Manifest b/gnome-base/gnome-flashback/Manifest
index 433946dd177..1acec1f08c2 100644
--- a/gnome-base/gnome-flashback/Manifest
+++ b/gnome-base/gnome-flashback/Manifest
@@ -1,2 +1 @@
-DIST gnome-flashback-3.36.4.tar.xz 826568 BLAKE2B 6625b3a2d90649b9476d6340295b3cf8960f76908c23d75fe7b2a886d1a5c6a587bc8cb31ab866a40f2250b67d154a080f27534aaa11e822d901fc1cac0687af SHA512 6c1b910872530a86d6fb477ad55c8c44cbe5ef958073e2c675d95b9b4dbf9aab0d0a3b3cdae2daebbe3dad8a83c53ffe0604e12282864bfdee33402e119eff32
DIST gnome-flashback-3.40.0.tar.xz 857104 BLAKE2B 41711edc4687682dd48134e452297bef7d0c4db93532bfd4bd49f19f2f01eab7c887b584f412384057e8a2b65a937446a108df0c4cfd811085c161a212e19355 SHA512 b938d12c437926e64567388b1a97350b76883cf91c009c1f57d4963321497ebdf69b094c7d88a86e5bf805930b88ff2637e522ac4f9981a391206a03d23a521e
diff --git a/gnome-base/gnome-flashback/gnome-flashback-3.36.4.ebuild b/gnome-base/gnome-flashback/gnome-flashback-3.36.4.ebuild
deleted file mode 100644
index b0eb921b559..00000000000
--- a/gnome-base/gnome-flashback/gnome-flashback-3.36.4.ebuild
+++ /dev/null
@@ -1,84 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit gnome2 toolchain-funcs
-
-DESCRIPTION="GNOME Flashback session"
-HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-flashback/"
-
-LICENSE="GPL-3+"
-SLOT="0"
-IUSE="elogind systemd"
-REQUIRED_USE="^^ ( elogind systemd )"
-KEYWORDS="~amd64"
-
-RDEPEND="
- >=x11-libs/gdk-pixbuf-2.32.2:2
- >=x11-libs/gtk+-3.22.0:3[X]
- >=gnome-base/gnome-desktop-3.12.0:3=
- >=gnome-base/gnome-panel-3.35.2
- >=media-libs/libcanberra-0.13[gtk3]
- >=dev-libs/glib-2.44.0:2
- >=gnome-base/gsettings-desktop-schemas-3.31.0
- >=sys-auth/polkit-0.97
- >=app-i18n/ibus-1.5.2
- >=sys-power/upower-0.99.0:=
- >=x11-libs/libXrandr-1.5.0
- >=x11-libs/libXxf86vm-1.1.4
- x11-libs/libxcb
- x11-libs/libX11
- gnome-base/gdm
- elogind? ( >=sys-auth/elogind-230 )
- systemd? ( >=sys-apps/systemd-230:= )
- net-wireless/gnome-bluetooth
- x11-libs/libXext
- >=x11-libs/libXi-1.6.0
- x11-libs/pango
- x11-libs/libxkbfile
- x11-misc/xkeyboard-config
- x11-libs/libXfixes
- media-sound/pulseaudio[glib]
- sys-libs/pam
-"
-DEPEND="${RDEPEND}
- dev-util/gdbus-codegen
- dev-util/glib-utils
- >=sys-devel/gettext-0.19.8
- x11-base/xorg-proto
- virtual/pkgconfig
-" # autoconf-archive for eautoreconf
-RDEPEND="${RDEPEND}
- x11-wm/metacity
- gnome-base/gnome-panel
- gnome-base/gnome-settings-daemon
-"
-
-src_configure() {
- local myconf=(
- --disable-static
- --without-compiz-session
- $(use_enable systemd systemd-session)
- )
-
- # Below elogind DESKTOP_* and SCREENSAVER_* pkg-config calls need to match up with
- # what upstream has each version (libsystemd replaced with libelogind). Explicit
- # per-version die to force a manual recheck. Only update the explicit version if the
- # "PKG_CHECK_MODULES([MENU/SCREENSAVER], ...)" blocks did not change; otherwise adjust
- # elogind conditional block below accordingly first.
- if ver_test ${PV} -ne 3.36.4; then
- die "Maintainer has not checked over packages MENU pkg-config deps for elogind support"
- fi
-
- if use elogind; then
- local pkgconfig="$(tc-getPKG_CONFIG)"
- myconf+=(
- DESKTOP_CFLAGS="$(${pkgconfig} --cflags glib-2.0 gio-2.0 gio-unix-2.0 gnome-desktop-3.0 gtk+-3.0 libelogind x11)"
- DESKTOP_LIBS="$(${pkgconfig} --libs glib-2.0 gio-2.0 gio-unix-2.0 gnome-desktop-3.0 gtk+-3.0 libelogind x11)"
- SCREENSAVER_CFLAGS="$(${pkgconfig} --cflags gdm gio-unix-2.0 glib-2.0 gnome-desktop-3.0 gtk+-3.0 libelogind xxf86vm)"
- SCREENSAVER_LIBS="$(${pkgconfig} --libs gdm gio-unix-2.0 glib-2.0 gnome-desktop-3.0 gtk+-3.0 libelogind xxf86vm)"
- )
- fi
-
- gnome2_src_configure "${myconf[@]}"
-}
diff --git a/gnome-base/gnome-keyring/gnome-keyring-40.0-r1.ebuild b/gnome-base/gnome-keyring/gnome-keyring-40.0-r1.ebuild
new file mode 100644
index 00000000000..a6174f16178
--- /dev/null
+++ b/gnome-base/gnome-keyring/gnome-keyring-40.0-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit gnome2 pam python-any-r1 virtualx
+
+DESCRIPTION="Password and keyring managing daemon"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeKeyring"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="pam selinux +ssh-agent test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+# Replace gkd gpg-agent with pinentry[gnome-keyring] one, bug #547456
+RDEPEND="
+ >=app-crypt/gcr-3.27.90:=[gtk]
+ >=app-crypt/gnupg-2.0.28:=
+ >=app-eselect/eselect-pinentry-0.5
+ app-misc/ca-certificates
+ >=dev-libs/glib-2.44:2
+ >=dev-libs/libgcrypt-1.2.2:0=
+ pam? ( sys-libs/pam )
+ selinux? ( sec-policy/selinux-gnome )
+ ssh-agent? ( net-misc/openssh )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ >=app-eselect/eselect-pinentry-0.5
+ app-text/docbook-xml-dtd:4.3
+ dev-libs/libxslt
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ test? ( ${PYTHON_DEPS} )
+"
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ # Disable stupid CFLAGS with debug enabled
+ sed -e 's/CFLAGS="$CFLAGS -g"//' \
+ -e 's/CFLAGS="$CFLAGS -O0"//' \
+ -i configure.ac configure || die
+
+ gnome2_src_prepare
+}
+
+src_configure() {
+ gnome2_src_configure \
+ --without-libcap-ng \
+ $(use_enable pam) \
+ $(use_with pam pam-dir $(getpam_mod_dir)) \
+ $(use_enable selinux) \
+ $(use_enable ssh-agent) \
+ --enable-doc
+}
+
+src_test() {
+ # Needs dbus-run-session to not get:
+ # ERROR: test-dbus-search process failed: -6
+ "${BROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/schema" || die
+ GSETTINGS_SCHEMA_DIR="${S}/schema" virtx dbus-run-session emake check
+}
+
+pkg_postinst() {
+ # cap_ipc_lock only needed if building --with-libcap-ng, but that breaks with glib-2.70
+ # Never install as suid root, this breaks dbus activation, see bug #513870
+ gnome2_pkg_postinst
+
+ if ! [[ $(eselect pinentry show | grep "pinentry-gnome3") ]] ; then
+ ewarn "Please select pinentry-gnome3 as default pinentry provider:"
+ ewarn " # eselect pinentry set pinentry-gnome3"
+ fi
+}
diff --git a/gnome-base/gnome-panel/Manifest b/gnome-base/gnome-panel/Manifest
index b244c2a9a8f..e262f5f7346 100644
--- a/gnome-base/gnome-panel/Manifest
+++ b/gnome-base/gnome-panel/Manifest
@@ -1,2 +1 @@
-DIST gnome-panel-3.36.2.tar.xz 3033016 BLAKE2B faf5b81c07eccca9d78ed56be9e124e8f909bb577739810a059135cd6afc9cd293b5a023a129063c48168029a1f9a2dd6fd9c714f80e0c566f820291dd15217f SHA512 cbd7eaf1778dd3f6751c020540c243b02787feb5781195fd5db008fc66683ea5330d89ab0f2c740020695c4da7856b5678491ec3e711d6ce41e884a0374e937b
DIST gnome-panel-3.40.0.tar.xz 2924776 BLAKE2B fb7d3b85c0eb7509810b1c3730f27479516b104ded31127c9fb2d2852277e62270b300d238b0e2de944d571c68db9ac2b35ed323ddd709e6a4b669089f09bae2 SHA512 49d8fde009ccf139dcc1412863432e642c11e3c149c6f39ab8f51d8027880654625a997f58efe03234ea2716ad0316f7d5f60fb493e7e6cea366611b975effe6
diff --git a/gnome-base/gnome-panel/gnome-panel-3.36.2.ebuild b/gnome-base/gnome-panel/gnome-panel-3.36.2.ebuild
deleted file mode 100644
index c33ffe3fbb7..00000000000
--- a/gnome-base/gnome-panel/gnome-panel-3.36.2.ebuild
+++ /dev/null
@@ -1,72 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit eapi7-ver gnome2 toolchain-funcs
-
-DESCRIPTION="The GNOME Flashback Panel"
-HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-panel/"
-
-LICENSE="GPL-2+ FDL-1.1 LGPL-2.1+"
-SLOT="0"
-IUSE="eds elogind systemd"
-REQUIRED_USE="^^ ( elogind systemd )"
-KEYWORDS="~amd64"
-
-RDEPEND="
- >=gnome-base/gnome-desktop-2.91.0:3=
- >=x11-libs/gdk-pixbuf-2.26.0:2
- >=x11-libs/pango-1.15.4
- >=dev-libs/glib-2.45.3:2
- >=x11-libs/gtk+-3.22.0:3[X]
- >=x11-libs/libwnck-3.4.6:3
- >=gnome-base/gnome-menus-3.7.90:3
- eds? ( >=gnome-extra/evolution-data-server-3.33.2:=
- )
- elogind? ( >=sys-auth/elogind-230 )
- systemd? ( >=sys-apps/systemd-230:= )
- >=x11-libs/cairo-1.0.0[X,glib]
- >=dev-libs/libgweather-3.28.0:2=
- >=gnome-base/dconf-0.13.4
- >=x11-libs/libXrandr-1.3.0
- gnome-base/gdm
- x11-libs/libX11
- x11-libs/libXi
- sys-auth/polkit
- x11-libs/libXi
-"
-DEPEND="${RDEPEND}
- app-text/docbook-xml-dtd:4.1.2
- dev-util/gdbus-codegen
- dev-util/glib-utils
- dev-util/itstool
- >=sys-devel/gettext-0.19.8
- virtual/pkgconfig
- x11-base/xorg-proto
-" # yelp-tools and autoconf-archive for eautoreconf
-
-src_configure() {
- local myconf=(
- --disable-static
- $(use_enable eds)
- )
-
- # Below elogind MENU_* pkg-config calls need to match up with what upstream has
- # each version (libsystemd replaced with libelogind). Explicit per-version die
- # to force a manual recheck. Only update the explicit version if the
- # "PKG_CHECK_MODULES([MENU], ...)" block did not change; otherwise adjust
- # elogind conditional block below accordingly first.
- if ver_test ${PV} -ne 3.36.2; then
- die "Maintainer has not checked over packages MENU pkg-config deps for elogind support"
- fi
-
- if use elogind; then
- local pkgconfig="$(tc-getPKG_CONFIG)"
- myconf+=(
- MENU_CFLAGS="$(${pkgconfig} --cflags gdm gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind)"
- MENU_LIBS="$(${pkgconfig} --libs gdm gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind)"
- )
- fi
-
- gnome2_src_configure "${myconf[@]}"
-}
diff --git a/gnome-base/gnome-shell/Manifest b/gnome-base/gnome-shell/Manifest
index 7698c830a94..228ac9d9c02 100644
--- a/gnome-base/gnome-shell/Manifest
+++ b/gnome-base/gnome-shell/Manifest
@@ -1,3 +1,5 @@
-DIST gnome-shell-40.2.tar.xz 1869600 BLAKE2B 6081930c4fe564980659bfeb7f7f59c5b95ce56e158096f14d8f85b28f4b45b1697eebdd88f7daf331aa1f7d087ec3dab55543d9a82d9d26bc5d8aee7e7c0085 SHA512 0df0a68a0e2440f73dfc147045ac2f003e5f133950cdbec7fb07b92e71aa53e2e4f3ce75510552f1043404850623fc84c08aad215b39ce9d33862994ae35ba87
DIST gnome-shell-40.3.tar.xz 1869724 BLAKE2B b6a663c97f5ad9239e608e16805074f9695f90b110514d202cc799818321d258417ce4e7841fa3256ae664e2bcba12201ac035737720a37f4eb3e84a26418ad9 SHA512 05d47e1b0f8ec27f0ae7564476012f21dcb2ec8e6da61a589b7fe17df1a23035cb6e261805250a410737502b9bdbb25f56432a618de88881d7e15b6432e52770
DIST gnome-shell-40.4.tar.xz 1870468 BLAKE2B 78b0a749850e5df18beabd25cc35214b2d1f9a254dd095b9e783b2acdc9bac30edd7ffae3e6b15dd14d5b0877e8453c17548298e29b57642353e80ed505e556d SHA512 305d12cc7273f23e4a0c294f532cbf951816fd2de81959bef769048f4d5717e9e1886b64fe17b2f5ef6ee216ea67a6b913293a8903ec5dc5214bd29fbb1d3b32
+DIST gnome-shell-40.5.tar.xz 1871284 BLAKE2B 39c7392541af8a043627fb7aa19b723ee3b36e3d8001a64f34b14a6f23d68d3b160a0abe0f90659c55b99bf898cfdf30d88f62b8e113fc47814a55ef37c58725 SHA512 98bb0321aa9bc9da10ff6262cac802f575e2958600f429d446f3f87ec1ea40c837dd6e2fecae9dab0c2e224d2bf8b434a188ade84d4f480260102dcc80fdc5c9
+DIST gnome-shell-41.0-r1-patchset.tar.xz 46860 BLAKE2B 7c2204855ceb41a455cf4e92af81cb7f8d1eff027c1f70b5171218a6ec880332902f34bc96fcdaefba48daf4dc2e9f8a2486abfefba574aba408dc45ff73d228 SHA512 72c91ba7913f0e64f9babcbea7f438260ae3795b5f82ef9a5158de50d3c54d31d47492df8539663d611dfa3dc4ead640164f5f26d671a18b3946472688926920
+DIST gnome-shell-41.0.tar.xz 1893676 BLAKE2B 500c22a2eafb86a5717794f8da9de49c633c568e917b7116a8ecae0e62a3769a21e0b591d1147d6bed59b8350394e8ff157c184486c4f97e59e0f9dc202492b8 SHA512 2d2a2dd4ecf315776c10949b00f10dbbd77f495542bb7ca8cdb95047998942433c5c4cad818fe729681f888f74038d51c3d5903f1a0861a66147dbf668231824
diff --git a/gnome-base/gnome-shell/gnome-shell-40.4.ebuild b/gnome-base/gnome-shell/gnome-shell-40.4.ebuild
index 9273794623b..17352799055 100644
--- a/gnome-base/gnome-shell/gnome-shell-40.4.ebuild
+++ b/gnome-base/gnome-shell/gnome-shell-40.4.ebuild
@@ -15,7 +15,7 @@ IUSE="+bluetooth +browser-extension elogind gtk-doc +ibus +networkmanager system
REQUIRED_USE="${PYTHON_REQUIRED_USE}
?? ( elogind systemd )"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+KEYWORDS="~amd64 ~arm arm64 ~ppc64 ~riscv ~x86"
# libXfixes-5.0 needed for pointer barriers and #include <X11/extensions/Xfixes.h>
# FIXME:
diff --git a/gnome-base/gnome-shell/gnome-shell-40.2.ebuild b/gnome-base/gnome-shell/gnome-shell-40.5.ebuild
index dfb141f86a4..9273794623b 100644
--- a/gnome-base/gnome-shell/gnome-shell-40.2.ebuild
+++ b/gnome-base/gnome-shell/gnome-shell-40.5.ebuild
@@ -2,7 +2,7 @@
# Distributed under the terms of the GNU General Public License v2
EAPI=7
-PYTHON_COMPAT=( python3_{8,9} )
+PYTHON_COMPAT=( python3_{8..10} )
inherit gnome.org gnome2-utils meson python-single-r1 virtualx xdg
@@ -15,7 +15,7 @@ IUSE="+bluetooth +browser-extension elogind gtk-doc +ibus +networkmanager system
REQUIRED_USE="${PYTHON_REQUIRED_USE}
?? ( elogind systemd )"
-KEYWORDS="amd64 ~arm arm64 ~ppc64 x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
# libXfixes-5.0 needed for pointer barriers and #include <X11/extensions/Xfixes.h>
# FIXME:
@@ -23,13 +23,13 @@ KEYWORDS="amd64 ~arm arm64 ~ppc64 x86"
DEPEND="
>=gnome-extra/evolution-data-server-3.33.1:=
>=app-crypt/gcr-3.7.5[introspection]
- >=dev-libs/glib-2.57.2:2
+ >=dev-libs/glib-2.68:2
>=dev-libs/gobject-introspection-1.49.1:=
>=dev-libs/gjs-1.65.1
>=x11-libs/gtk+-3.15.0:3[introspection]
>=x11-wm/mutter-40.0:0/8[introspection]
>=sys-auth/polkit-0.100[introspection]
- >=gnome-base/gsettings-desktop-schemas-3.33.1
+ >=gnome-base/gsettings-desktop-schemas-3.33.1[introspection]
>=x11-libs/startup-notification-0.11
>=app-i18n/ibus-1.5.2
>=gnome-base/gnome-desktop-3.35.90:3=[introspection]
@@ -68,27 +68,33 @@ DEPEND="
media-libs/mesa[X(+)]
"
# Runtime-only deps are probably incomplete and approximate.
-# Introspection deps generated using:
-# grep -roe "imports.gi.*" gnome-shell-* | cut -f2 -d: | sort | uniq
+# Introspection deps generated from inspection of the output of:
+# for i in `rg -INUo 'const(?s).*imports.gi' |cut -d= -f1 |cut -c7- |sort -u`; do echo $i ;done |cut -d, -f1 |sort -u
+# or
+# rg -INUo 'const(?s).*imports.gi' |cut -d= -f1 |cut -c7- | sed -e 's:[{}]::g' | awk '{$1=$1; print}' | awk -F',' '{$1=$1;print}' | tr ' ' '\n' | sort -u | sed -e 's/://g'
+# These will give a lot of unnecessary things due to greey matching (TODO), and `(?s).*?` doesn't seem to work as desired.
+# Compare with `grep -rhI 'imports.gi.versions' |sort -u` for any SLOT requirements
# Each block:
-# 1. Introspection stuff needed via imports.gi.*
+# 1. Introspection stuff needed via imports.gi (those that build time check may be listed above already)
# 2. gnome-session needed for shutdown/reboot/inhibitors/etc
# 3. Control shell settings
-# 4. logind interface needed for suspending support
-# 5. xdg-utils needed for xdg-open, used by extension tool
-# 6. adwaita-icon-theme needed for various icons & arrows (3.26 for new video-joined-displays-symbolic and co icons; review for 3.28+)
-# 7. mobile-broadband-provider-info, timezone-data for shell-mobile-providers.c # TODO: Review
-# 8. IBus is needed for nls integration
-# 9. Optional telepathy chat integration
-# 10. Cantarell font used in gnome-shell global CSS (if removing this for some reason, make sure it's pulled in somehow for non-meta users still too)
+# 4. xdg-utils needed for xdg-open, used by extension tool
+# 5. adwaita-icon-theme needed for various icons & arrows (3.26 for new video-joined-displays-symbolic and co icons; review for 3.28+)
+# 6. mobile-broadband-provider-info, timezone-data for shell-mobile-providers.c # TODO: Review
+# 7. IBus is needed for nls integration
+# 8. Optional telepathy chat integration
+# 9. Cantarell font used in gnome-shell global CSS (if removing this for some reason, make sure it's pulled in somehow for non-meta users still too)
+# 10. xdg-desktop-portal-gtk for various integration, e.g. #764632
# 11. TODO: semi-optional webkit-gtk[introspection] for captive portal helper
RDEPEND="${DEPEND}
>=sys-apps/accountsservice-0.6.14[introspection]
app-accessibility/at-spi2-core:2[introspection]
app-misc/geoclue[introspection]
+ media-libs/graphene[introspection]
>=dev-libs/libgweather-3.26:2[introspection]
- >=sys-power/upower-0.99:=[introspection]
x11-libs/pango[introspection]
+ net-libs/libsoup:2.4[introspection]
+ >=sys-power/upower-0.99:=[introspection]
gnome-base/librsvg:2[introspection]
>=gnome-base/gnome-session-2.91.91
@@ -116,16 +122,17 @@ PDEPEND="
browser-extension? ( gnome-extra/chrome-gnome-shell )
"
BDEPEND="
- dev-lang/sassc
dev-libs/libxslt
- app-text/asciidoc
>=dev-util/gdbus-codegen-2.45.3
dev-util/glib-utils
gtk-doc? ( >=dev-util/gtk-doc-1.17
- app-text/docbook-xml-dtd:4.3 )
+ app-text/docbook-xml-dtd:4.5 )
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
+# These are not needed from tarballs, unless stylesheets or manpage get patched with patchset:
+# dev-lang/sassc
+# app-text/asciidoc
PATCHES=(
# Fix automagic gnome-bluetooth dep, bug #398145
diff --git a/gnome-base/gnome-shell/gnome-shell-41.0-r1.ebuild b/gnome-base/gnome-shell/gnome-shell-41.0-r1.ebuild
new file mode 100644
index 00000000000..23f7b697c68
--- /dev/null
+++ b/gnome-base/gnome-shell/gnome-shell-41.0-r1.ebuild
@@ -0,0 +1,203 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 virtualx xdg
+
+DESCRIPTION="Provides core UI functions for the GNOME desktop"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeShell"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${PF}-patchset.tar.xz"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="+bluetooth +browser-extension elogind gtk-doc +ibus +networkmanager systemd telepathy"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ ?? ( elogind systemd )"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+# libXfixes-5.0 needed for pointer barriers and #include <X11/extensions/Xfixes.h>
+# FIXME:
+# * gstreamer/pipewire support is currently automagic
+DEPEND="
+ >=gnome-extra/evolution-data-server-3.33.1:=
+ >=app-crypt/gcr-3.7.5[introspection]
+ >=dev-libs/glib-2.68:2
+ >=dev-libs/gobject-introspection-1.49.1:=
+ >=dev-libs/gjs-1.69.2
+ >=x11-libs/gtk+-3.15.0:3[introspection]
+ >=x11-wm/mutter-41.0:0/9[introspection]
+ >=sys-auth/polkit-0.100[introspection]
+ >=gnome-base/gsettings-desktop-schemas-41_alpha[introspection]
+ >=x11-libs/startup-notification-0.11
+ >=app-i18n/ibus-1.5.19
+ >=gnome-base/gnome-desktop-3.35.90:3=[introspection]
+ bluetooth? ( >=net-wireless/gnome-bluetooth-3.9[introspection] )
+ >=media-libs/gstreamer-0.11.92:1.0
+ media-libs/gst-plugins-base:1.0
+ >=media-video/pipewire-0.3.0:0/0.3
+ networkmanager? (
+ >=net-misc/networkmanager-1.10.4:=[introspection]
+ net-libs/libnma[introspection]
+ >=app-crypt/libsecret-0.18
+ dev-libs/dbus-glib )
+ systemd? ( >=sys-apps/systemd-242
+ >=gnome-base/gnome-desktop-3.34.2:3=[systemd] )
+ elogind? ( >=sys-auth/elogind-237 )
+
+ app-arch/gnome-autoar
+ dev-libs/json-glib
+
+ >=app-accessibility/at-spi2-atk-2.5.3
+ x11-libs/gdk-pixbuf:2[introspection]
+ dev-libs/libxml2:2
+ x11-libs/libX11
+
+ >=media-sound/pulseaudio-2[glib]
+ >=dev-libs/atk-2[introspection]
+ dev-libs/libical:=
+ >=x11-libs/libXfixes-5.0
+
+ gui-libs/gtk:4[introspection]
+
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep '
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ ')
+ media-libs/mesa[X(+)]
+"
+# Runtime-only deps are probably incomplete and approximate.
+# Introspection deps generated from inspection of the output of:
+# for i in `rg -INUo 'const(?s).*imports.gi' |cut -d= -f1 |cut -c7- |sort -u`; do echo $i ;done |cut -d, -f1 |sort -u
+# or
+# rg -INUo 'const(?s).*imports.gi' |cut -d= -f1 |cut -c7- | sed -e 's:[{}]::g' | awk '{$1=$1; print}' | awk -F',' '{$1=$1;print}' | tr ' ' '\n' | sort -u | sed -e 's/://g'
+# These will give a lot of unnecessary things due to greedy matching (TODO), and `(?s).*?` doesn't seem to work as desired.
+# Compare with `grep -rhI 'imports.gi.versions' |sort -u` for any SLOT requirements
+# Each block:
+# 1. Introspection stuff needed via imports.gi (those that build time check may be listed above already)
+# 2. gnome-session needed for shutdown/reboot/inhibitors/etc
+# 3. Control shell settings
+# 4. xdg-utils needed for xdg-open, used by extension tool
+# 5. adwaita-icon-theme needed for various icons & arrows (3.26 for new video-joined-displays-symbolic and co icons; review for 3.28+)
+# 6. mobile-broadband-provider-info, timezone-data for shell-mobile-providers.c # TODO: Review
+# 7. IBus is needed for nls integration
+# 8. Optional telepathy chat integration
+# 9. Cantarell font used in gnome-shell global CSS (if removing this for some reason, make sure it's pulled in somehow for non-meta users still too)
+# 10. xdg-desktop-portal-gtk for various integration, e.g. #764632
+# 11. TODO: semi-optional webkit-gtk[introspection] for captive portal helper
+RDEPEND="${DEPEND}
+ >=sys-apps/accountsservice-0.6.14[introspection]
+ app-accessibility/at-spi2-core:2[introspection]
+ app-misc/geoclue[introspection]
+ media-libs/graphene[introspection]
+ >=dev-libs/libgweather-3.26:2[introspection]
+ x11-libs/pango[introspection]
+ net-libs/libsoup:2.4[introspection]
+ >=sys-power/upower-0.99:=[introspection]
+ gnome-base/librsvg:2[introspection]
+
+ >=gnome-base/gnome-session-2.91.91
+ >=gnome-base/gnome-settings-daemon-3.8.3
+
+ x11-misc/xdg-utils
+
+ >=x11-themes/adwaita-icon-theme-3.26
+
+ networkmanager? (
+ net-misc/mobile-broadband-provider-info
+ sys-libs/timezone-data )
+ ibus? ( >=app-i18n/ibus-1.4.99[dconf(+),gtk,introspection] )
+ telepathy? (
+ >=net-im/telepathy-logger-0.2.4[introspection]
+ >=net-libs/telepathy-glib-0.19[introspection] )
+ media-fonts/cantarell
+
+ sys-apps/xdg-desktop-portal-gtk
+"
+# avoid circular dependency, see bug #546134
+PDEPEND="
+ >=gnome-base/gdm-3.5[introspection(+)]
+ >=gnome-base/gnome-control-center-3.26[bluetooth(+)?,networkmanager(+)?]
+ browser-extension? ( gnome-extra/chrome-gnome-shell )
+"
+BDEPEND="
+ dev-libs/libxslt
+ >=dev-util/gdbus-codegen-2.45.3
+ dev-util/glib-utils
+ gtk-doc? ( >=dev-util/gtk-doc-1.17
+ app-text/docbook-xml-dtd:4.5 )
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+"
+# These are not needed from tarballs, unless stylesheets or manpage get patched with patchset:
+# dev-lang/sassc
+# app-text/asciidoc
+
+PATCHES=(
+ "${WORKDIR}"/patches/
+ # Fix automagic gnome-bluetooth dep, bug #398145
+ "${FILESDIR}"/40.0-optional-bluetooth.patch
+ # Change favorites defaults, bug #479918
+ "${FILESDIR}"/40.0-defaults.patch
+)
+
+src_prepare() {
+ xdg_src_prepare
+ # Hack in correct python shebang
+ sed -e "s:python\.path():'/usr/bin/env ${EPYTHON}':" -i src/meson.build || die
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use bluetooth)
+ -Dextensions_tool=true
+ -Dextensions_app=true
+ $(meson_use gtk-doc gtk_doc)
+ -Dman=true
+ $(meson_use test tests)
+ $(meson_use networkmanager)
+ $(meson_use systemd) # this controls journald integration and desktop file user services related property only as of 3.34.4
+ # (structured logging and having gnome-shell launched apps use its own identifier instead of gnome-session)
+ # suspend support is runtime optional via /run/systemd/seats presence and org.freedesktop.login1.Manager dbus interface; elogind should provide what's necessary
+ -Dsoup2=true # libslot SLOT needs to match with what libgweather is using
+ )
+ meson_src_configure
+}
+
+src_test() {
+ gnome2_environment_reset # Avoid dconf that looks at XDG_DATA_DIRS, which can sandbox fail if flatpak is installed
+ virtx meson_src_test
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+
+ if ! has_version 'media-libs/gst-plugins-good:1.0' || \
+ ! has_version 'media-plugins/gst-plugins-vpx:1.0'; then
+ ewarn "To make use of GNOME Shell's built-in screen recording utility,"
+ ewarn "you need to either install media-libs/gst-plugins-good:1.0"
+ ewarn "and media-plugins/gst-plugins-vpx:1.0, or use dconf-editor to change"
+ ewarn "apps.gnome-shell.recorder/pipeline to what you want to use."
+ fi
+
+ if ! has_version "media-libs/mesa[llvm]"; then
+ elog "llvmpipe is used as fallback when no 3D acceleration"
+ elog "is available. You will need to enable llvm USE for"
+ elog "media-libs/mesa if you do not have hardware 3D setup."
+ fi
+
+ # https://bugs.gentoo.org/show_bug.cgi?id=563084
+ # TODO: Is this still the case after various fixed in 3.28 for detecting non-working KMS for wayland (to fall back to X)?
+ if has_version "x11-drivers/nvidia-drivers[-kms]"; then
+ ewarn "You will need to enable kms support in x11-drivers/nvidia-drivers,"
+ ewarn "otherwise Gnome will fail to start"
+ fi
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
diff --git a/gnome-base/gsettings-desktop-schemas/Manifest b/gnome-base/gsettings-desktop-schemas/Manifest
index 3e57fe8a175..12d1c67bbec 100644
--- a/gnome-base/gsettings-desktop-schemas/Manifest
+++ b/gnome-base/gsettings-desktop-schemas/Manifest
@@ -1,2 +1,3 @@
DIST gsettings-desktop-schemas-3.38.0.tar.xz 685868 BLAKE2B a5fe8baf6d7178cfba74c82974dfb854fbc2accfb9c98db2edbf46271b54626150a570fb3b578cdd86acfd1b21b432da0947e273c3ab94ec3f416c4a51b44e4a SHA512 5af7da90b8e7eec1c98e9e44653955f2882961dd9b5e2bf00e4eeb9f4f1149ae5171c600d457c6ab9c7482471c1a0e98f92f645a7ee7298e1b843c608f660756
DIST gsettings-desktop-schemas-40.0.tar.xz 700672 BLAKE2B 5cc19d23e31a8ca7bd2344fa9392f11588b84c2641a6c0c2f184e733248d22c5603978408ccb13e58efac241beac8780c4a4f8c527b59fa3646cc18a18b09b90 SHA512 6b7f9b3095706b287254bd21d54311d6048e87340462e75848f05f7d7ded09da766cec7159fb6d889405ecfb4fdfe2243197989afeb21678fe4048783ae16424
+DIST gsettings-desktop-schemas-41.0.tar.xz 705240 BLAKE2B 2f2eb797fbdb7317666839a4ddffd65405ddcca80724a480bd1decfc164acc4c0db193ca6a3e3bcd71fbeb479fe51c5262c0bcf40fe85cfb2d6bda5b47d5b6e5 SHA512 58f9f60d818f0ddce20ad70e6ca64d3e1fb5a5dfd45b737cc055901f7dd5f1625902451e765a26969bdd72e3b37300dacbd3555a4bc3f33c6667dbf9b1869739
diff --git a/gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-41.0.ebuild b/gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-41.0.ebuild
new file mode 100644
index 00000000000..a5545f400e7
--- /dev/null
+++ b/gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-41.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=(python3_{6..9})
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="Collection of GSettings schemas for GNOME desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gsettings-desktop-schemas"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="+introspection"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris ~x86-solaris"
+
+BDEPEND="
+ introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+ dev-util/glib-utils
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ ${PYTHON_DEPS}
+"
+
+PATCHES=(
+ # Revert change to 'Source Code Pro 10' and 'Cantarell 11' fonts back to generic sans and monospace aliases
+ "${FILESDIR}"/3.32.0-default-fonts.patch
+)
+
+src_prepare() {
+ default
+
+ python_fix_shebang build-aux/meson/post-install.py
+}
+
+src_configure() {
+ meson_src_configure $(meson_use introspection)
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
diff --git a/gnome-base/nautilus/nautilus-40.2.ebuild b/gnome-base/nautilus/nautilus-40.2.ebuild
index 60b6475d503..0ed580949d0 100644
--- a/gnome-base/nautilus/nautilus-40.2.ebuild
+++ b/gnome-base/nautilus/nautilus-40.2.ebuild
@@ -72,7 +72,7 @@ src_configure() {
-Dextensions=true # image file properties, sendto support; also required for -Dgstreamer=true
$(meson_use gstreamer) # gstreamer audio-video-properties extension
$(meson_use introspection)
- -Dlibportal=false
+ -Dlibportal=false # As of 40.2, all libportal usages are flatpak-specific
-Dpackagekit=false
$(meson_use selinux)
-Dprofiling=false
@@ -87,6 +87,7 @@ src_install() {
}
src_test() {
+ gnome2_environment_reset # Avoid dconf that looks at XDG_DATA_DIRS, which can sandbox fail if flatpak is installed
virtx meson_src_test
}