summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'mate-extra/caja-extensions/caja-extensions-1.24.1.ebuild')
-rw-r--r--mate-extra/caja-extensions/caja-extensions-1.24.1.ebuild77
1 files changed, 77 insertions, 0 deletions
diff --git a/mate-extra/caja-extensions/caja-extensions-1.24.1.ebuild b/mate-extra/caja-extensions/caja-extensions-1.24.1.ebuild
new file mode 100644
index 00000000000..d31c92bc108
--- /dev/null
+++ b/mate-extra/caja-extensions/caja-extensions-1.24.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MATE_LA_PUNT="yes"
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Several Caja extensions"
+LICENSE="GPL-2+"
+SLOT="0"
+
+SENDTO="cdr gajim +mail pidgin upnp"
+IUSE="image-converter +open-terminal share +wallpaper xattr ${SENDTO}"
+
+COMMON_DEPEND=">=dev-libs/glib-2.50:2
+ >=mate-base/caja-1.21.3
+ x11-libs/gdk-pixbuf:2
+ >=x11-libs/gtk+-3.22:3
+ gajim? (
+ >=dev-libs/dbus-glib-0.60
+ >=sys-apps/dbus-1
+ )
+ open-terminal? ( >=mate-base/mate-desktop-1.17.0 )
+ pidgin? ( >=dev-libs/dbus-glib-0.60 )
+ upnp? ( >=net-libs/gupnp-0.13:0= )
+ xattr? ( sys-apps/attr )
+"
+
+RDEPEND="${COMMON_DEPEND}
+ mate-base/mate-desktop
+ cdr? ( >=app-cdr/brasero-2.32.1:= )
+ gajim? ( net-im/gajim )
+ image-converter? (
+ || (
+ media-gfx/imagemagick
+ media-gfx/graphicsmagick[imagemagick]
+ )
+ )
+ pidgin? ( net-im/pidgin )
+"
+
+DEPEND="${COMMON_DEPEND}
+ dev-libs/libxml2
+ dev-util/gtk-doc
+ dev-util/gtk-doc-am
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ !!mate-extra/mate-file-manager-open-terminal
+ !!mate-extra/mate-file-manager-sendto
+ !!mate-extra/mate-file-manager-image-converter
+ !!mate-extra/mate-file-manager-share
+"
+
+src_configure() {
+ local sendto_plugins="removable-devices"
+ use cdr && sendto_plugins+=",caja-burn"
+ use mail && sendto_plugins+=",emailclient"
+ use pidgin && sendto_plugins+=",pidgin"
+ use gajim && sendto_plugins+=",gajim"
+ use upnp && sendto_plugins+=",upnp"
+
+ mate_src_configure \
+ --enable-sendto \
+ --with-sendto-plugins=${sendto_plugins}\
+ --disable-gksu \
+ $(use_enable image-converter) \
+ $(use_enable open-terminal) \
+ $(use_enable share) \
+ $(use_enable wallpaper) \
+ $(use_enable xattr xattr-tags)
+}