summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'net-mail/mailutils/mailutils-3.5.ebuild')
-rw-r--r--net-mail/mailutils/mailutils-3.5.ebuild131
1 files changed, 131 insertions, 0 deletions
diff --git a/net-mail/mailutils/mailutils-3.5.ebuild b/net-mail/mailutils/mailutils-3.5.ebuild
new file mode 100644
index 000000000000..f09fc7f30b0d
--- /dev/null
+++ b/net-mail/mailutils/mailutils-3.5.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+
+inherit autotools elisp-common eutils flag-o-matic python-single-r1 toolchain-funcs
+
+DESCRIPTION="A useful collection of mail servers, clients, and filters"
+HOMEPAGE="https://www.gnu.org/software/mailutils/mailutils.html"
+SRC_URI="mirror://gnu/mailutils/${P}.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="berkdb bidi +clients emacs gdbm sasl guile ipv6 kerberos kyotocabinet \
+ ldap mysql nls pam postgres python servers ssl static-libs +threads tcpd \
+ tokyocabinet"
+
+RDEPEND="!mail-client/nmh
+ !mail-filter/libsieve
+ !mail-client/mailx
+ !mail-client/nail
+ sys-libs/ncurses:=
+ sys-libs/readline:=
+ dev-libs/libltdl:0
+ virtual/mta
+ berkdb? ( sys-libs/db:= )
+ bidi? ( dev-libs/fribidi )
+ emacs? ( virtual/emacs )
+ gdbm? ( sys-libs/gdbm )
+ guile? ( dev-scheme/guile:12/2.2-1 )
+ kerberos? ( virtual/krb5 )
+ kyotocabinet? ( dev-db/kyotocabinet )
+ ldap? ( net-nds/openldap )
+ mysql? ( virtual/mysql )
+ nls? ( sys-devel/gettext )
+ pam? ( virtual/pam )
+ postgres? ( dev-db/postgresql:= )
+ python? ( ${PYTHON_DEPS} )
+ sasl? ( virtual/gsasl )
+ ssl? ( net-libs/gnutls:= )
+ tcpd? ( sys-apps/tcp-wrappers )
+ tokyocabinet? ( dev-db/tokyocabinet )"
+
+DEPEND="${RDEPEND}
+ virtual/pkgconfig"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+ servers? ( tcpd )"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ if use mysql; then
+ sed -i -e /^INCLUDES/"s:$:$(mysql_config --include):" \
+ sql/Makefile.am || die
+ fi
+ # bug 669946
+ eapply "${FILESDIR}/${PN}-3.5-add-include.patch"
+ eapply_user
+ eautoreconf
+}
+
+src_configure() {
+ append-flags -fno-strict-aliasing
+
+ # maildir is the Gentoo default
+ econf MU_DEFAULT_SCHEME=maildir \
+ CURSES_LIBS="$($(tc-getPKG_CONFIG) --libs ncurses)" \
+ $(use_with berkdb berkeley-db) \
+ $(use_with bidi fribidi) \
+ $(use_enable ipv6) \
+ $(use_with gdbm) \
+ $(use_with sasl gsasl) \
+ $(use_with guile) \
+ $(use_with kerberos gssapi) \
+ $(use_with ldap) \
+ $(use_with mysql) \
+ $(use_enable nls) \
+ $(use_enable pam) \
+ $(use_with postgres) \
+ $(use_enable python) \
+ $(use_with ssl gnutls) \
+ $(use_enable static-libs static) \
+ $(use_enable threads pthread) \
+ $(use_with tokyocabinet) \
+ $(use_with kyotocabinet) \
+ $(use_with tcpd tcp-wrappers) \
+ $(use_enable servers build-servers) \
+ $(use_enable clients build-clients) \
+ EMACS=$(usex emacs emacs no) \
+ --with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
+ --with-mail-spool=/var/spool/mail \
+ --with-readline \
+ --enable-sendmail \
+ --disable-debug
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+
+ insinto /etc
+ # bug 613112
+ newins "${FILESDIR}/mailutils.rc" mailutils.conf
+ keepdir /etc/mailutils.d/
+ insinto /etc/mailutils.d
+ doins "${FILESDIR}/mail"
+
+ if use python; then
+ python_optimize
+ if use static-libs; then
+ rm -r "${D}$(python_get_sitedir)/mailutils"/*.{a,la} || die
+ fi
+ fi
+
+ if use servers; then
+ newinitd "${FILESDIR}"/imap4d.initd imap4d
+ newinitd "${FILESDIR}"/pop3d.initd pop3d
+ newinitd "${FILESDIR}"/comsatd.initd comsatd
+ fi
+
+ dodoc AUTHORS ChangeLog NEWS README* THANKS TODO
+
+ # compatibility link
+ use clients && dosym /usr/bin/mail /bin/mail
+
+ use static-libs || find "${D}" -name "*.la" -delete
+}