2 files changed, 91 insertions, 0 deletions
diff --git a/net-p2p/gtk-gnutella/Manifest b/net-p2p/gtk-gnutella/Manifest
index e635d3286ae9..c5848da4c376 100644
--- a/net-p2p/gtk-gnutella/Manifest
+++ b/net-p2p/gtk-gnutella/Manifest
@@ -1 +1,2 @@
 DIST gtk-gnutella-1.1.13.tar.xz 19207704 BLAKE2B 4a11fd3f8bd7554e78a75b51b818e2e863edc328d07d0da4fce07e9a6eca7307dd66082dc70caf96e9e85d1d68ee1ef253a47ffb58cc9f33358a5d71b10782cb SHA512 14ff19a3f0bf55101570b4268cdd422defd2ccd112d80e9bafe2f6eb019b94c3c72763e67e2853d4446e68943355093c1279c6d67c101ca6d9b7f05ddd9ac7e0
+DIST gtk-gnutella-1.1.14.tar.xz 19372716 BLAKE2B b9caf1eaa79ca9c9e4d6a036f438eabbbab59a2d94a5227aee17ef9e9551af8185c3049247ee2e53ed913cbb46fafc6841d84346928490b380e16ccf5d27cc4e SHA512 cf8d76a5d531ad26e6155aedc2099f86ff91f96c4587bd6910e844fb6d19d35b48e3d1c4df45b7c68b34f4afcf2ce507943d73a33d923a97f6c43dd9c9ce10c9
diff --git a/net-p2p/gtk-gnutella/gtk-gnutella-1.1.14.ebuild b/net-p2p/gtk-gnutella/gtk-gnutella-1.1.14.ebuild
new file mode 100644
index 000000000000..6a621c5cef73
--- /dev/null
+++ b/net-p2p/gtk-gnutella/gtk-gnutella-1.1.14.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# strip-linguas
+inherit eutils
+
+IUSE="nls dbus ssl +gtk"
+
+DESCRIPTION="A GTK+ Gnutella client"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+HOMEPAGE="http://gtk-gnutella.sourceforge.net/"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+
+RDEPEND="
+	sys-libs/binutils-libs:=
+	dev-libs/glib:2
+	sys-libs/zlib
+	gtk? ( >=x11-libs/gtk+-2.2.1:2 )
+	dbus? ( >=sys-apps/dbus-0.35.2 )
+	ssl? ( >=net-libs/gnutls-2.2.5 )
+	nls? ( >=sys-devel/gettext-0.11.5 )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+
+src_prepare() {
+	strip-linguas -i po
+
+	echo "# Gentoo-selected LINGUAS" > po/LINGUAS
+	for ling in ${LINGUAS}; do
+		echo $ling >> po/LINGUAS
+	done
+
+	default
+}
+
+src_configure() {
+	# There is no option to turn off optimization through the build.sh
+	# script.
+	sed -i -e "s/Configure -Oder/Configure -Oder -Doptimize=none/" build.sh || die
+
+	# The build script does not support the equivalent --enable
+	# options so we must construct the configuration by hand.
+
+	local myconf
+
+	if ! use nls; then
+		myconf="${myconf} --disable-nls"
+	fi
+
+	if ! use dbus; then
+		myconf="${myconf} --disable-dbus"
+	fi
+
+	if ! use ssl; then
+		myconf="${myconf} --disable-gnutls"
+	fi
+
+	if use gtk; then
+		myconf="${myconf} --gtk2"
+	else
+		myconf="${myconf} --topless"
+	fi
+
+	./build.sh \
+		--configure-only \
+		--prefix="/usr" \
+		--cc=$(tc-getCC) \
+		${myconf}
+}
+
+src_compile() {
+	# Build system is not parallel-safe, bug 500760
+	emake -j1
+}
+
+src_install() {
+	dodir /usr/bin
+	emake INSTALL_PREFIX="${D}" install || die "Install failed"
+	dodoc AUTHORS ChangeLog README TODO
+
+	# Touch the symbols file into the future to avoid warnings from
+	# gtk-gnutella later on, since we will most likely strip the binary.
+	touch --date="next minute" "${D}/usr/lib/gtk-gnutella/gtk-gnutella.nm" || die
+}