From 1741e4cbe3bdd4d5cbeb5dcab4d7d8d62304a86c Mon Sep 17 00:00:00 2001
From: Conrad Kostecki <conikost@gentoo.org>
Date: Tue, 20 Jul 2021 23:28:16 +0200
Subject: net-misc/geomyidae: migrate to GLEP 81

Bug: https://bugs.gentoo.org/781410
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
---
 net-misc/geomyidae/geomyidae-0.34-r1.ebuild | 57 +++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 net-misc/geomyidae/geomyidae-0.34-r1.ebuild

diff --git a/net-misc/geomyidae/geomyidae-0.34-r1.ebuild b/net-misc/geomyidae/geomyidae-0.34-r1.ebuild
new file mode 100644
index 000000000000..36930da5891e
--- /dev/null
+++ b/net-misc/geomyidae/geomyidae-0.34-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="A daemon to serve the gopher protocol"
+HOMEPAGE="http://r-36.net/scm/geomyidae/"
+SRC_URI="ftp://bitreich.org/releases/geomyidae/${PN}-v${PV}.tgz"
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+RDEPEND="
+	acct-group/gopherd
+	acct-user/gopherd
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	# enable verbose build
+	# respect CFLAGS
+	# remove /usr/lib from LDFLAGS, bug #731672
+	sed -i \
+		-e 's/@${CC}/${CC}/g' \
+		-e '/CFLAGS/s/=/?=/' \
+		-e '/GEOM_LDFLAGS/s:-L/usr/lib ::' \
+		Makefile || die 'sed on Makefile failed'
+	# fix path for pid file
+	sed -i \
+		-e 's:/var/run:/run:g' \
+		rc.d/Gentoo.init.d || die
+
+	eapply_user
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	dosbin ${PN}
+
+	newinitd rc.d/Gentoo.init.d ${PN}
+	newconfd rc.d/Gentoo.conf.d ${PN}
+
+	insinto /var/gopher
+	doins index.gph
+	fowners -R root.gopherd /var/gopher
+	fperms -R g=rX,o=rX /var/gopher
+
+	doman ${PN}.8
+	dodoc CGI README
+}
-- 
cgit v1.2.3-65-gdbad