From 3499d8c61c220adedc8a37962a3bd1e2c607e1b8 Mon Sep 17 00:00:00 2001
From: Alexis Ballier <aballier@gentoo.org>
Date: Tue, 28 Jun 2016 13:04:16 +0200
Subject: media-sound/qtractor: bump to 0.7.8

Package-Manager: portage-2.3.0
---
 media-sound/qtractor/Manifest              |  1 +
 media-sound/qtractor/qtractor-0.7.8.ebuild | 77 ++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)
 create mode 100644 media-sound/qtractor/qtractor-0.7.8.ebuild

diff --git a/media-sound/qtractor/Manifest b/media-sound/qtractor/Manifest
index 731aa562a551..71dab2cd66ef 100644
--- a/media-sound/qtractor/Manifest
+++ b/media-sound/qtractor/Manifest
@@ -1 +1,2 @@
 DIST qtractor-0.7.7.tar.gz 1695946 SHA256 748b3c32124bb4ced762c88bf57a1497027c73e8b1cbc3c326e651eb83df1361 SHA512 cbc8419791764f886f5124a6eb937496ea8d0bd4f3ee75b7948dec59d55f830a07fd97bbc05ee4b59a743f7c244063bd6f80c01532c864f7606605e485cd9fe2 WHIRLPOOL b544d0991379783ab6b4472bef2a3aa47e4134dd3eb3837111b68f4a17405272934ea2e6231566361a9fc61ca92a9d692bd82b0f6831ebb42e0e19bcf0a6a4bf
+DIST qtractor-0.7.8.tar.gz 1705865 SHA256 b6a495e468e90870e4f0706a07dfbd6a3f368a62fe6b4e9b40caada8d7f0f501 SHA512 046cf24377b4da91ab724793b54b43ed06c7d3597746d974a17aafffc708d98692579ce087737c06522247e7edceea636791f1a25af2a4a8c814fbe22e5a686f WHIRLPOOL 1afb50e3b75d71921da5176acff260bda30d0cd76f10b5e21dca7ffc4fa4bdb07a4bd2383b8201e6e6548e4f62ababe4a42e2b9ff119c74798747e1871a71768
diff --git a/media-sound/qtractor/qtractor-0.7.8.ebuild b/media-sound/qtractor/qtractor-0.7.8.ebuild
new file mode 100644
index 000000000000..38d91b139e87
--- /dev/null
+++ b/media-sound/qtractor/qtractor-0.7.8.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit qmake-utils flag-o-matic eutils
+
+DESCRIPTION="Qtractor is an Audio/MIDI multi-track sequencer"
+HOMEPAGE="http://qtractor.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="debug dssi libsamplerate mad osc +qt5 rubberband vorbis cpu_flags_x86_sse zlib"
+
+RDEPEND="
+	!qt5? (
+		>=dev-qt/qtcore-4.2:4
+		>=dev-qt/qtgui-4.7:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+		dev-qt/qtx11extras:5
+	)
+	media-libs/alsa-lib
+	media-libs/libsndfile
+	media-sound/jack-audio-connection-kit
+	media-libs/ladspa-sdk
+	>=media-libs/lilv-0.16.0
+	media-libs/lv2
+	media-libs/suil
+	dssi? ( media-libs/dssi )
+	mad? ( media-libs/libmad )
+	libsamplerate? ( media-libs/libsamplerate )
+	osc? ( media-libs/liblo )
+	rubberband? ( media-libs/rubberband )
+	vorbis? ( media-libs/libvorbis )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	qt5? ( dev-qt/linguist-tools:5 )"
+
+DOCS="README ChangeLog TODO AUTHORS"
+
+src_configure() {
+	econf \
+		$(use_enable mad libmad) \
+		$(use_enable libsamplerate) \
+		$(use_enable vorbis libvorbis) \
+		$(use_enable osc liblo) \
+		--enable-ladspa \
+		$(use_enable dssi) \
+		--enable-lilv \
+		$(use_enable qt5) \
+		$(use_with qt5 qt5 "$(qt5_get_libdir)/qt5") \
+		$(use_enable rubberband librubberband) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable zlib libz) \
+		$(use_enable debug)
+
+	if use qt5 ; then
+		eqmake5 ${PN}.pro -o ${PN}.mak
+	else
+		eqmake4 ${PN}.pro -o ${PN}.mak
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	einstalldocs
+}
-- 
cgit v1.2.3-65-gdbad