From 35a0219041eb9f94e6a183dc634b5e7bf6604769 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sat, 29 Jun 2019 08:05:44 +0200
Subject: xfce-base/thunar: Bump to 1.8.7
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 xfce-base/thunar/Manifest            |  1 +
 xfce-base/thunar/thunar-1.8.7.ebuild | 76 ++++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)
 create mode 100644 xfce-base/thunar/thunar-1.8.7.ebuild

diff --git a/xfce-base/thunar/Manifest b/xfce-base/thunar/Manifest
index f8cacb6267b9..71969e8ea5a8 100644
--- a/xfce-base/thunar/Manifest
+++ b/xfce-base/thunar/Manifest
@@ -1,3 +1,4 @@
 DIST Thunar-1.6.16.tar.bz2 1977562 BLAKE2B efad6b45a64c5c80bff3d829207a1a0b45b4b48ab168c38bbcd263445a16dc230b0c5ea7515b65d686cbf256d294bcced19b248c252478a6a1cecb393d71a7f6 SHA512 6c7b8b88e01762e606bfd9e3848a98ae5825ff431f0686dd7bbcb987e448aa4c20d7cca3fb6b7c5d5dfde91ae6f8a16e674769d168f6f875e2efe519f4cdfd1b
 DIST Thunar-1.6.17.tar.bz2 1995398 BLAKE2B c6bc0ebc29cdf8b0d3d184fd5b5019bb6f4caa4e43e16237325ae938e95c077198801e7f0d5210c458e316e0c7f35aa735f8e5bca61372c3cb2f5cf40b78c59a SHA512 2ace85994af51e1651b1e58c4436b5d4a986e75ef56f85c765e7dad8698681a73e009feafff0c9e056153b13c37b915a43529451960a209ae7e0bc23544492b8
 DIST Thunar-1.8.6.tar.bz2 2317253 BLAKE2B ee992640e1c3df64f7aad13390a263e4599c9f0a19640b77bf5383ab6f93898f8785c86bbe307da9158390aa435699eb9a70ea3a96fb82d3b726db657436ce52 SHA512 086dc139627d8f11341b2db91358ef1831d2b8494d34abac49355dbaf850a21c30f979294f9adf2bc8548e5f817a4e165803a3db74cd989cd3867a4e228d74db
+DIST Thunar-1.8.7.tar.bz2 2326995 BLAKE2B 2eceeedabc66ced9ced70089b2ce66932a2223f4c4f6a6ae624199c00552d3d0fbb98f1c67bb0408d99d4167172698ecc9d020117d7c5fd41363b543b768ef69 SHA512 d4faf28857ee7c29c799bec9c5d7c639596b213f2aeb1089125d074083a4a13e91425cf3f35c63ce313330ee9ef070653a868a1a4526dc443a5d603bd9dec588
diff --git a/xfce-base/thunar/thunar-1.8.7.ebuild b/xfce-base/thunar/thunar-1.8.7.ebuild
new file mode 100644
index 000000000000..453b51539055
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.8.7.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit xdg-utils
+
+MY_P=${P^}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/ https://docs.xfce.org/xfce/thunar/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="exif introspection libnotify pcre test +trash-panel-plugin udisks"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.42:=
+	>=x11-libs/gdk-pixbuf-2.14:=
+	>=x11-libs/gtk+-3.22:3=
+	>=xfce-base/exo-0.12:=
+	>=xfce-base/libxfce4ui-4.12:=
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/xfconf-4.12:=
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	pcre? ( >=dev-libs/libpcre-6:= )
+	trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	udisks? ( virtual/libgudev:= )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	trash-panel-plugin? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre)
+		$(use_enable trash-panel-plugin tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3-65-gdbad