From 5a86c9be4dc6b4d59929af0242218fd80e143af0 Mon Sep 17 00:00:00 2001
From: NP-Hardass <NP-Hardass@gentoo.org>
Date: Fri, 12 Aug 2016 00:22:24 -0400
Subject: mate-base/mate-applets: 1.12.x vbump, add gtk3, import from project
 repo

Package-Manager: portage-2.3.0
---
 mate-base/mate-applets/Manifest                   |   1 +
 mate-base/mate-applets/mate-applets-1.12.1.ebuild | 101 ++++++++++++++++++++++
 mate-base/mate-applets/metadata.xml               |   3 +
 3 files changed, 105 insertions(+)
 create mode 100644 mate-base/mate-applets/mate-applets-1.12.1.ebuild

diff --git a/mate-base/mate-applets/Manifest b/mate-base/mate-applets/Manifest
index e658a4379bf2..6db9a60acfc3 100644
--- a/mate-base/mate-applets/Manifest
+++ b/mate-base/mate-applets/Manifest
@@ -1 +1,2 @@
 DIST mate-applets-1.10.4.tar.xz 6850348 SHA256 e713b4205a901048120d48578dc86e87d2f87a294484110a331acdf77f4f48c2 SHA512 4e1fd0523cb1f50bf056f6805b048137442360eb8ec8c05b02c3075e48acb79a5150056b1c815439659048958c11def8141fe3df917d5da8d608adfb6c330ee3 WHIRLPOOL ed0cfe389168f01b081852716a3df459bc6ee63de67cd802b56f42daf7a8447e5a524f5dfaf45cae8d7d553ee7bbf8ca3371bd77f174f27bb0b6d1377ad53298
+DIST mate-applets-1.12.1.tar.xz 6816716 SHA256 0a3bc19e59c69eccdcc2342f29b7837563e51fbefdb232ca1884ca23d8f69c99 SHA512 c9acac98df31386b4016d42d3d1fe0e9ddd5e8fccc291269cff73e2a4c0853fabb85a649ee14f4aef3200c0f731c1d95f48aefdb3d8baaf014ad8776c1e94234 WHIRLPOOL 9f3569fcdd610935689a54600153bbbb47ac46100b8689f74d0bc37ac227e129edbf06e6f86e3471f7f40454c37c00291382ccc51e95b3dd2fac008b4e865620
diff --git a/mate-base/mate-applets/mate-applets-1.12.1.ebuild b/mate-base/mate-applets/mate-applets-1.12.1.ebuild
new file mode 100644
index 000000000000..80d6f80bf4a3
--- /dev/null
+++ b/mate-base/mate-applets/mate-applets-1.12.1.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit mate python-single-r1
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="Applets for the MATE Desktop and Panel"
+LICENSE="GPL-2 FDL-1.1 LGPL-2"
+SLOT="0"
+
+IUSE="X gtk3 ipv6 policykit +upower"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	app-text/rarian:0
+	dev-libs/atk:0
+	>=dev-libs/dbus-glib-0.74:0
+	>=dev-libs/glib-2.36:2
+	>=dev-libs/libmateweather-1.6.1[gtk3(-)=]
+	>=dev-libs/libxml2-2.5:2
+	dev-python/pygobject:3
+	>=gnome-base/libgtop-2.11.92:2=
+	>=mate-base/mate-desktop-1.9[gtk3(-)=]
+	>=mate-base/mate-panel-1.7[gtk3(-)=]
+	>=mate-base/mate-settings-daemon-1.6[gtk3(-)=]
+	>=sys-apps/dbus-1.1.2:0
+	sys-power/cpupower
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/libnotify-0.7:0
+	x11-libs/libX11:0
+	x11-libs/pango:0
+	virtual/libintl:0
+	!gtk3? (
+		>=gnome-extra/gucharmap-2.32.1:0
+		>=x11-libs/gtk+-2.24:2
+		x11-libs/gtksourceview:2.0
+		>=x11-libs/libwnck-2.30:1
+	)
+	gtk3? (
+		>=gnome-extra/gucharmap-3.0:2.90
+		>=x11-libs/gtk+-3.0:3
+		x11-libs/gtksourceview:3.0
+		>=x11-libs/libwnck-3.0:3
+	)
+	policykit? ( >=sys-auth/polkit-0.92:0 )
+	upower? (
+		|| (
+			>=sys-power/upower-0.9.23
+			>=sys-power/upower-pm-utils-0.9.23
+		)
+	)"
+
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.3
+	>=app-text/scrollkeeper-dtd-1:1.0
+	app-text/yelp-tools:0
+	>=dev-util/intltool-0.50.1:*
+	dev-libs/libxslt:0
+	sys-devel/gettext:*
+	virtual/pkgconfig:*"
+
+src_configure() {
+	mate_src_configure \
+		--libexecdir=/usr/libexec/mate-applets \
+		--with-cpufreq-lib=cpupower \
+		--with-gtk=$(usex gtk3 3.0 2.0) \
+		$(use_with X x) \
+		$(use_with upower) \
+		$(use_enable ipv6) \
+		$(use_enable policykit polkit)
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	emake check
+}
+
+src_install() {
+	python_fix_shebang invest-applet
+	mate_src_install
+
+	local APPLETS="accessx-status battstat charpick command cpufreq drivemount
+			geyes invest-applet mateweather multiload null_applet stickynotes
+			timerapplet trashapplet"
+
+	for applet in ${APPLETS}; do
+		docinto ${applet}
+
+		for d in AUTHORS ChangeLog NEWS README README.themes TODO; do
+			[ -s ${applet}/${d} ] && dodoc ${applet}/${d}
+		done
+	done
+}
diff --git a/mate-base/mate-applets/metadata.xml b/mate-base/mate-applets/metadata.xml
index dbdbdf91b958..b42a07267e28 100644
--- a/mate-base/mate-applets/metadata.xml
+++ b/mate-base/mate-applets/metadata.xml
@@ -5,6 +5,9 @@
         <email>mate@gentoo.org</email>
         <name>Gentoo MATE Desktop</name>
     </maintainer>
+	<use>
+		<flag name="gtk3">Build with GTK+3 instead of GTK+2</flag>
+	</use>
     <upstream>
         <remote-id type="github">mate-desktop/mate-applets</remote-id>
     </upstream>
-- 
cgit v1.2.3