From 8a6369128f8f62e43e9eb663cd9e74ce9bab9e42 Mon Sep 17 00:00:00 2001
From: Andrey Grozin <grozin@gentoo.org>
Date: Wed, 26 Jul 2017 22:53:39 +0700
Subject: sci-mathematics/form: bump to 4.2.0

Package-Manager: Portage-2.3.6, Repoman-2.3.2
---
 sci-mathematics/form/Manifest          |  1 +
 sci-mathematics/form/form-4.2.0.ebuild | 81 ++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 sci-mathematics/form/form-4.2.0.ebuild

diff --git a/sci-mathematics/form/Manifest b/sci-mathematics/form/Manifest
index 93a5895b3d2a..a404018e2e63 100644
--- a/sci-mathematics/form/Manifest
+++ b/sci-mathematics/form/Manifest
@@ -1 +1,2 @@
 DIST form-4.1.tar.gz 1260530 SHA256 fb3470937d66ed5cb1af896b15058836d2c805d767adac1b9073ed2df731cbe9 SHA512 39ab2fa1e448d6d5e427cc2c92285cc27f84724addffc378f3b799fc2b3f6381b8dceb87cb980062b980885d8d81591c5c7ff7b0dbeae7b6d9a3cf0b03d58aae WHIRLPOOL 1950ebc2357a78bf7430dd35852ab538e14b2ec68df8e9d11d7adcc31c365c14175c91bee984458794346a3b66b0580bea8625eeeff8c9c0f2045bab2bb1b5f8
+DIST form-4.2.0.tar.gz 1386285 SHA256 55fb2f69b98e4bd48e365b2245f3d0e22ef0f969d07b1a4aa81b120baf42a2a4 SHA512 7566b89c1c1b74da58da92426f5e4beee271d4273df6cbe1d1de1a17377125b745103852c363dfe8ff1b0e9cb9ba4c84187406e8f77b23f5198fd592f5dfe341 WHIRLPOOL 149e94c0c551481d9d4f035b71c5255ad59a6568ebab9b94e146bfb050af9989bd7dd371bb15035eea4c589d736ee61bc903d0bb4383902c5c0605da606c0d75
diff --git a/sci-mathematics/form/form-4.2.0.ebuild b/sci-mathematics/form/form-4.2.0.ebuild
new file mode 100644
index 000000000000..8f30d5b663c9
--- /dev/null
+++ b/sci-mathematics/form/form-4.2.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit autotools
+
+DESCRIPTION="Symbolic Manipulation System"
+HOMEPAGE="http://www.nikhef.nl/~form/"
+SRC_URI="https://github.com/vermaseren/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="devref doc doxygen gmp mpi threads zlib"
+
+RDEPEND="
+	gmp? ( dev-libs/gmp:0= )
+	mpi? ( virtual/mpi )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	devref? ( dev-texlive/texlive-latex )
+	doc? ( dev-texlive/texlive-latex )
+	doxygen? ( app-doc/doxygen )"
+
+src_prepare() {
+	sed -i 's/LINKFLAGS = -s/LINKFLAGS =/' sources/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-scalar \
+		--enable-largefile \
+		--disable-debug \
+		--disable-static-link \
+		--with-api=posix \
+		$(use_with gmp ) \
+		$(use_enable mpi parform ) \
+		$(use_enable threads threaded ) \
+		$(use_with zlib ) \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		CXXFLAGS="${CXXFLAGS}"
+}
+
+src_compile() {
+	default
+	if use devref; then
+		pushd doc/devref > /dev/null || die "doc/devref does not exist"
+		LANG=C emake pdf
+		popd > /dev/null
+	fi
+	if use doc; then
+		pushd doc/manual > /dev/null || die "doc/manual does not exist"
+		LANG=C emake pdf
+		popd > /dev/null
+	fi
+	if use doxygen; then
+		pushd doc/doxygen > /dev/null || die "doc/doxygen does not exist"
+		emake html
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	default
+	if use devref; then
+		insinto /usr/share/doc/${PF}
+		doins doc/devref/devref.pdf
+	fi
+	if use doc; then
+		insinto /usr/share/doc/${PF}
+		doins doc/manual/manual.pdf
+	fi
+	if use doxygen; then
+		dohtml -r doc/doxygen/html/*
+	fi
+}
-- 
cgit v1.2.3-65-gdbad