From a31ca4b6c6a547a458dfa607b58c5ff4c28c2dfb Mon Sep 17 00:00:00 2001
From: Mikle Kolyada <zlogene@gentoo.org>
Date: Sat, 3 Nov 2018 18:52:32 +0300
Subject: media-sound/mpd: Drop old

Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11
---
 media-sound/mpd/Manifest           |   1 -
 media-sound/mpd/mpd-0.20.23.ebuild | 270 -------------------------------------
 2 files changed, 271 deletions(-)
 delete mode 100644 media-sound/mpd/mpd-0.20.23.ebuild

diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index 76925861083f..148679eb3e5c 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -1,4 +1,3 @@
 DIST mpd-0.20.10.tar.xz 778828 BLAKE2B c16b955ace770cf3d5da2ccad81fd3089cf2e60bf47774745d75babcff38fa344646b26dd32617fa2fe86ee0c785b9c8272ea6c90f77266b1a0cba2d48145236 SHA512 bac6a71e5b85600c590eae6b785474574cf0d7b03d9add537161b968a2997a975a597639a9fece119a01a7e27b5207523e4ae30b2f4f35791eff8c3ff26d107c
 DIST mpd-0.20.21.tar.xz 800476 BLAKE2B 0c807ae8d79abd9400aa417b516c709073b23390aeed2b385c716e20f8c4f93376a235b54fe5f5cfcd451b04c76e105b41acbd180d294281432d4d1b6a427a15 SHA512 d44fb326ea6213ecf46721ca81efdfffaec4faa5a66e627185fd5ab7c4f0c5a380f4d04aed5c2909746a37b33987cb61f62dc2d747365da06629fbb78bf7c7d6
-DIST mpd-0.20.23.tar.xz 806784 BLAKE2B 859edfe37b355ce8b64a9dc22dd0c13891d9154b5d07299ec1655757b02df3900af0d7fea7e7cbdcccc8d82d61a4c9c05a145fc2b23c471fefd1cb9d95043356 SHA512 9875f5b7d7eb7d51fa135249954fbaa2b300ecd539e15aee1a090f14c7a340f328c2f910aeb641ce32af2df21d0e56725ad1a3f957339b0a9c051a02ea0b8a05
 DIST mpd-0.21.tar.xz 662100 BLAKE2B 3c47e9af643000f45d1f197806b857a12c1ae616134350a6ca968bf51c266f40b79e34e22bbbea63089a4563b22998560460e858e7a6be99789d695f68e5eeb3 SHA512 ff9bb7b0969190f2d679895ae16ac910e239a1b37f3b1745755c061917d0a3a299bbcde29bd0ed99e59aca512709965e1846b925a6c978c39a9f2c2e8876e85f
diff --git a/media-sound/mpd/mpd-0.20.23.ebuild b/media-sound/mpd/mpd-0.20.23.ebuild
deleted file mode 100644
index 0e22d8297530..000000000000
--- a/media-sound/mpd/mpd-0.20.23.ebuild
+++ /dev/null
@@ -1,270 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools flag-o-matic linux-info systemd user
-
-DESCRIPTION="The Music Player Daemon (mpd)"
-HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
-SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~x86 ~x86-fbsd ~x64-macos"
-IUSE="adplug +alsa ao audiofile bzip2 cdio +curl debug +eventfd expat faad
-	+fifo +ffmpeg flac fluidsynth gme +icu +id3tag +inotify +ipv6 jack
-	lame mms libav libmpdclient libsamplerate libsoxr +mad mikmod modplug
-	mpg123 musepack +network nfs ogg openal opus oss pipe pulseaudio recorder
-	samba selinux sid +signalfd sndfile soundcloud sqlite systemd tcpd twolame
-	unicode upnp vorbis wavpack wildmidi zeroconf zip zlib webdav"
-
-OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
-DECODER_PLUGINS="adplug audiofile faad ffmpeg flac fluidsynth mad mikmod
-	modplug mpg123 musepack ogg flac sid vorbis wavpack wildmidi"
-ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
-
-REQUIRED_USE="
-	|| ( ${OUTPUT_PLUGINS} )
-	|| ( ${DECODER_PLUGINS} )
-	network? ( || ( ${ENCODER_PLUGINS} ) )
-	recorder? ( || ( ${ENCODER_PLUGINS} ) )
-	opus? ( ogg )
-	upnp? ( expat )
-	webdav? ( curl expat )
-"
-
-COMMON_DEPEND="
-	adplug? ( media-libs/adplug )
-	alsa? (
-		media-libs/alsa-lib
-		media-sound/alsa-utils
-	)
-	ao? ( media-libs/libao[alsa?,pulseaudio?] )
-	audiofile? ( media-libs/audiofile )
-	bzip2? ( app-arch/bzip2 )
-	cdio? (
-		dev-libs/libcdio:=
-		dev-libs/libcdio-paranoia
-	)
-	curl? ( net-misc/curl )
-	expat? ( dev-libs/expat )
-	faad? ( media-libs/faad2 )
-	ffmpeg? (
-		libav? ( media-video/libav:0= )
-		!libav? ( media-video/ffmpeg:0= )
-	)
-	flac? ( media-libs/flac[ogg?] )
-	fluidsynth? ( media-sound/fluidsynth )
-	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
-	icu? ( dev-libs/icu:= )
-	id3tag? ( media-libs/libid3tag )
-	jack? ( virtual/jack )
-	lame? ( network? ( media-sound/lame ) )
-	libmpdclient? ( media-libs/libmpdclient )
-	libsamplerate? ( media-libs/libsamplerate )
-	libsoxr? ( media-libs/soxr )
-	mad? ( media-libs/libmad )
-	mikmod? ( media-libs/libmikmod:0 )
-	mms? ( media-libs/libmms )
-	modplug? ( media-libs/libmodplug )
-	mpg123? ( >=media-sound/mpg123-1.12.2 )
-	musepack? ( media-sound/musepack-tools )
-	network? (
-		>=media-libs/libshout-2
-		!lame? ( !vorbis? ( media-libs/libvorbis ) )
-	)
-	nfs? ( net-fs/libnfs )
-	ogg? ( media-libs/libogg )
-	openal? ( media-libs/openal )
-	opus? ( media-libs/opus )
-	pulseaudio? ( media-sound/pulseaudio )
-	samba? ( >=net-fs/samba-4.0.25 )
-	sid? ( || (
-		media-libs/libsidplay:2
-		media-libs/libsidplayfp
-	) )
-	sndfile? ( media-libs/libsndfile )
-	soundcloud? ( >=dev-libs/yajl-2:= )
-	sqlite? ( dev-db/sqlite:3 )
-	systemd? ( sys-apps/systemd )
-	tcpd? ( sys-apps/tcp-wrappers )
-	twolame? ( media-sound/twolame )
-	upnp? ( net-libs/libupnp:0= )
-	vorbis? ( media-libs/libvorbis )
-	wavpack? ( media-sound/wavpack )
-	wildmidi? ( media-sound/wildmidi )
-	zeroconf? ( net-dns/avahi[dbus] )
-	zip? ( dev-libs/zziplib )
-	zlib? ( sys-libs/zlib )"
-DEPEND="${COMMON_DEPEND}
-	dev-libs/boost
-	virtual/pkgconfig"
-RDEPEND="${COMMON_DEPEND}
-	!<sys-cluster/mpich2-1.4_rc2
-	selinux? ( sec-policy/selinux-mpd )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.18.conf.patch
-)
-
-pkg_setup() {
-	use network || ewarn "Icecast and Shoutcast streaming needs networking."
-	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
-
-	enewuser mpd "" "" "/var/lib/mpd" audio
-
-	if use eventfd; then
-		CONFIG_CHECK+=" ~EVENTFD"
-		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
-	fi
-	if use signalfd; then
-		CONFIG_CHECK+=" ~SIGNALFD"
-		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
-	fi
-	if use inotify; then
-		CONFIG_CHECK+=" ~INOTIFY_USER"
-		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
-	fi
-	if use eventfd || use signalfd || use inotify; then
-		linux-info_pkg_setup
-	fi
-
-	elog "If you will be starting mpd via /etc/init.d/mpd, please make
-		sure that MPD's pid_file is _set_."
-}
-
-src_prepare() {
-	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
-	default
-	eautoreconf
-}
-
-src_configure() {
-	local myeconfargs=(
-		--enable-database --disable-roar --disable-documentation
-		--enable-dsd --enable-largefile --disable-osx --disable-shine-encoder
-		--disable-solaris-output --enable-tcp --enable-un --disable-werror
-		--docdir="${EPREFIX}"/usr/share/doc/${PF}
-	)
-
-	if use network; then
-		myeconfargs+=(
-			--enable-shout
-			$(use_enable vorbis vorbis-encoder)
-			--enable-httpd-output
-			$(use_enable lame lame-encoder)
-			$(use_enable twolame twolame-encoder)
-			$(use_enable audiofile wave-encoder)
-		)
-	else
-		myeconfargs+=(
-			--disable-shout
-			--disable-vorbis-encoder
-			--disable-httpd-output
-			--disable-lame-encoder
-			--disable-twolame-encoder
-			--disable-wave-encoder
-		)
-	fi
-
-	if use samba || use upnp; then
-		myeconfargs+=( --enable-neighbor-plugins )
-	fi
-
-	append-lfs-flags
-	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
-
-	myeconfargs+=(
-		$(use_enable eventfd)
-		$(use_enable signalfd)
-		$(use_enable libmpdclient)
-		$(use_enable expat)
-		$(use_enable upnp)
-		$(use_enable adplug)
-		$(use_enable alsa)
-		$(use_enable ao)
-		$(use_enable audiofile)
-		$(use_enable zlib)
-		$(use_enable bzip2)
-		$(use_enable cdio cdio-paranoia)
-		$(use_enable curl)
-		$(use_enable samba smbclient)
-		$(use_enable nfs)
-		$(use_enable debug)
-		$(use_enable ffmpeg)
-		$(use_enable fifo)
-		$(use_enable flac)
-		$(use_enable fluidsynth)
-		$(use_enable gme)
-		$(use_enable id3tag id3)
-		$(use_enable inotify)
-		$(use_enable ipv6)
-		$(use_enable cdio iso9660)
-		$(use_enable jack)
-		$(use_enable soundcloud)
-		$(use_enable tcpd libwrap)
-		$(use_enable libsamplerate lsr)
-		$(use_enable libsoxr soxr)
-		$(use_enable mad)
-		$(use_enable mikmod)
-		$(use_enable mms)
-		$(use_enable modplug)
-		$(use_enable musepack mpc)
-		$(use_enable mpg123)
-		$(use_enable openal)
-		$(use_enable opus)
-		$(use_enable oss)
-		$(use_enable pipe pipe-output)
-		$(use_enable pulseaudio pulse)
-		$(use_enable recorder recorder-output)
-		$(use_enable sid sidplay)
-		$(use_enable sndfile sndfile)
-		$(use_enable sqlite)
-		$(use_enable systemd systemd_daemon)
-		$(use_enable vorbis)
-		$(use_enable wavpack)
-		$(use_enable wildmidi)
-		$(use_enable zip zzip)
-		$(use_enable icu)
-		$(use_enable webdav)
-		$(use_enable faad aac)
-		$(use_with zeroconf zeroconf avahi)
-		--with-boost="${EPREFIX}"/usr
-		--with-systemdsystemunitdir=$(systemd_get_systemunitdir)
-		--with-systemduserunitdir=$(systemd_get_userunitdir)
-	)
-
-	econf "${myeconfargs[@]}"
-}
-
-src_install() {
-	default
-
-	insinto /etc
-	newins doc/mpdconf.dist mpd.conf
-
-	newinitd "${FILESDIR}"/${PN}-0.20.4.init ${PN}
-
-	if use unicode; then
-		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
-			"${ED}"/etc/mpd.conf || die "sed failed"
-	fi
-
-	insinto /etc/logrotate.d
-	newins "${FILESDIR}"/${PN}-0.20.21.logrotate ${PN}
-
-	use prefix || diropts -m0755 -o mpd -g audio
-	dodir /var/lib/mpd
-	keepdir /var/lib/mpd
-	dodir /var/lib/mpd/music
-	keepdir /var/lib/mpd/music
-	dodir /var/lib/mpd/playlists
-	keepdir /var/lib/mpd/playlists
-}
-
-pkg_postinst() {
-	# also change the homedir if the user has existed before
-	usermod -d "/var/lib/mpd" mpd
-}
-- 
cgit v1.2.3-65-gdbad